SAFE public projects git trees. - safe/jmp/linux-2.6/blob - include/asm-generic/vmlinux.lds.h

   1 #ifndef LOAD_OFFSET
   2 #define LOAD_OFFSET 0
   3 #endif
   4
   5 #ifndef VMLINUX_SYMBOL
   6 #define VMLINUX_SYMBOL(_sym_) _sym_
   7 #endif
   8
   9 /* Align . to a 8 byte boundary equals to maximum function alignment. */
  10 #define ALIGN_FUNCTION()  . = ALIGN(8)
  11
  12 /* The actual configuration determine if the init/exit sections
  13  * are handled as text/data or they can be discarded (which
  14  * often happens at runtime)
  15  */
  16 #ifdef CONFIG_HOTPLUG
  17 #define DEV_KEEP(sec)    *(.dev##sec)
  18 #define DEV_DISCARD(sec)
  19 #else
  20 #define DEV_KEEP(sec)
  21 #define DEV_DISCARD(sec) *(.dev##sec)
  22 #endif
  23
  24 #ifdef CONFIG_HOTPLUG_CPU
  25 #define CPU_KEEP(sec)    *(.cpu##sec)
  26 #define CPU_DISCARD(sec)
  27 #else
  28 #define CPU_KEEP(sec)
  29 #define CPU_DISCARD(sec) *(.cpu##sec)
  30 #endif
  31
  32 #if defined(CONFIG_MEMORY_HOTPLUG)
  33 #define MEM_KEEP(sec)    *(.mem##sec)
  34 #define MEM_DISCARD(sec)
  35 #else
  36 #define MEM_KEEP(sec)
  37 #define MEM_DISCARD(sec) *(.mem##sec)
  38 #endif
  39
  40 #ifdef CONFIG_FTRACE_MCOUNT_RECORD
  41 #define MCOUNT_REC()    VMLINUX_SYMBOL(__start_mcount_loc) = .; \
  42                         *(__mcount_loc)                         \
  43                         VMLINUX_SYMBOL(__stop_mcount_loc) = .;
  44 #else
  45 #define MCOUNT_REC()
  46 #endif
  47
  48 #ifdef CONFIG_TRACE_BRANCH_PROFILING
  49 #define LIKELY_PROFILE()        VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
  50                                 *(_ftrace_annotated_branch)                           \
  51                                 VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
  52 #else
  53 #define LIKELY_PROFILE()
  54 #endif
  55
  56 #ifdef CONFIG_PROFILE_ALL_BRANCHES
  57 #define BRANCH_PROFILE()        VMLINUX_SYMBOL(__start_branch_profile) = .;   \
  58                                 *(_ftrace_branch)                             \
  59                                 VMLINUX_SYMBOL(__stop_branch_profile) = .;
  60 #else
  61 #define BRANCH_PROFILE()
  62 #endif
  63
  64 #ifdef CONFIG_EVENT_TRACER
  65 #define FTRACE_EVENTS() VMLINUX_SYMBOL(__start_ftrace_events) = .;      \
  66                         *(_ftrace_events)                               \
  67                         VMLINUX_SYMBOL(__stop_ftrace_events) = .;
  68 #else
  69 #define FTRACE_EVENTS()
  70 #endif
  71
  72 #ifdef CONFIG_TRACING
  73 #define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .;      \
  74                          *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
  75                          VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
  76 #else
  77 #define TRACE_PRINTKS()
  78 #endif
  79
  80 /* .data section */
  81 #define DATA_DATA                                                       \
  82         *(.data)                                                        \
  83         *(.data.init.refok)                                             \
  84         *(.ref.data)                                                    \
  85         DEV_KEEP(init.data)                                             \
  86         DEV_KEEP(exit.data)                                             \
  87         CPU_KEEP(init.data)                                             \
  88         CPU_KEEP(exit.data)                                             \
  89         MEM_KEEP(init.data)                                             \
  90         MEM_KEEP(exit.data)                                             \
  91         . = ALIGN(8);                                                   \
  92         VMLINUX_SYMBOL(__start___markers) = .;                          \
  93         *(__markers)                                                    \
  94         VMLINUX_SYMBOL(__stop___markers) = .;                           \
  95         . = ALIGN(32);                                                  \
  96         VMLINUX_SYMBOL(__start___tracepoints) = .;                      \
  97         *(__tracepoints)                                                \
  98         VMLINUX_SYMBOL(__stop___tracepoints) = .;                       \
  99         LIKELY_PROFILE()                                                \
 100         BRANCH_PROFILE()                                                \
 101         FTRACE_EVENTS()
 102
 103 #define RO_DATA(align)                                                  \
 104         . = ALIGN((align));                                             \
 105         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
 106                 VMLINUX_SYMBOL(__start_rodata) = .;                     \
 107                 *(.rodata) *(.rodata.*)                                 \
 108                 *(__vermagic)           /* Kernel version magic */      \
 109                 *(__markers_strings)    /* Markers: strings */          \
 110                 *(__tracepoints_strings)/* Tracepoints: strings */      \
 111                 TRACE_PRINTKS()                                 \
 112         }                                                               \
 113                                                                         \
 114         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
 115                 *(.rodata1)                                             \
 116         }                                                               \
 117                                                                         \
 118         BUG_TABLE                                                       \
 119                                                                         \
 120         /* PCI quirks */                                                \
 121         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
 122                 VMLINUX_SYMBOL(__start_pci_fixups_early) = .;           \
 123                 *(.pci_fixup_early)                                     \
 124                 VMLINUX_SYMBOL(__end_pci_fixups_early) = .;             \
 125                 VMLINUX_SYMBOL(__start_pci_fixups_header) = .;          \
 126                 *(.pci_fixup_header)                                    \
 127                 VMLINUX_SYMBOL(__end_pci_fixups_header) = .;            \
 128                 VMLINUX_SYMBOL(__start_pci_fixups_final) = .;           \
 129                 *(.pci_fixup_final)                                     \
 130                 VMLINUX_SYMBOL(__end_pci_fixups_final) = .;             \
 131                 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;          \
 132                 *(.pci_fixup_enable)                                    \
 133                 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;            \
 134                 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .;          \
 135                 *(.pci_fixup_resume)                                    \
 136                 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .;            \
 137                 VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .;    \
 138                 *(.pci_fixup_resume_early)                              \
 139                 VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .;      \
 140                 VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .;         \
 141                 *(.pci_fixup_suspend)                                   \
 142                 VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .;           \
 143         }                                                               \
 144                                                                         \
 145         /* Built-in firmware blobs */                                   \
 146         .builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {      \
 147                 VMLINUX_SYMBOL(__start_builtin_fw) = .;                 \
 148                 *(.builtin_fw)                                          \
 149                 VMLINUX_SYMBOL(__end_builtin_fw) = .;                   \
 150         }                                                               \
 151                                                                         \
 152         /* RapidIO route ops */                                         \
 153         .rio_route        : AT(ADDR(.rio_route) - LOAD_OFFSET) {        \
 154                 VMLINUX_SYMBOL(__start_rio_route_ops) = .;              \
 155                 *(.rio_route_ops)                                       \
 156                 VMLINUX_SYMBOL(__end_rio_route_ops) = .;                \
 157         }                                                               \
 158                                                                         \
 159         TRACEDATA                                                       \
 160                                                                         \
 161         /* Kernel symbol table: Normal symbols */                       \
 162         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
 163                 VMLINUX_SYMBOL(__start___ksymtab) = .;                  \
 164                 *(__ksymtab)                                            \
 165                 VMLINUX_SYMBOL(__stop___ksymtab) = .;                   \
 166         }                                                               \
 167                                                                         \
 168         /* Kernel symbol table: GPL-only symbols */                     \
 169         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
 170                 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;              \
 171                 *(__ksymtab_gpl)                                        \
 172                 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;               \
 173         }                                                               \
 174                                                                         \
 175         /* Kernel symbol table: Normal unused symbols */                \
 176         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
 177                 VMLINUX_SYMBOL(__start___ksymtab_unused) = .;           \
 178                 *(__ksymtab_unused)                                     \
 179                 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;            \
 180         }                                                               \
 181                                                                         \
 182         /* Kernel symbol table: GPL-only unused symbols */              \
 183         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
 184                 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;       \
 185                 *(__ksymtab_unused_gpl)                                 \
 186                 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;        \
 187         }                                                               \
 188                                                                         \
 189         /* Kernel symbol table: GPL-future-only symbols */              \
 190         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
 191                 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;       \
 192                 *(__ksymtab_gpl_future)                                 \
 193                 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;        \
 194         }                                                               \
 195                                                                         \
 196         /* Kernel symbol table: Normal symbols */                       \
 197         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
 198                 VMLINUX_SYMBOL(__start___kcrctab) = .;                  \
 199                 *(__kcrctab)                                            \
 200                 VMLINUX_SYMBOL(__stop___kcrctab) = .;                   \
 201         }                                                               \
 202                                                                         \
 203         /* Kernel symbol table: GPL-only symbols */                     \
 204         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
 205                 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;              \
 206                 *(__kcrctab_gpl)                                        \
 207                 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;               \
 208         }                                                               \
 209                                                                         \
 210         /* Kernel symbol table: Normal unused symbols */                \
 211         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
 212                 VMLINUX_SYMBOL(__start___kcrctab_unused) = .;           \
 213                 *(__kcrctab_unused)                                     \
 214                 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;            \
 215         }                                                               \
 216                                                                         \
 217         /* Kernel symbol table: GPL-only unused symbols */              \
 218         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
 219                 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;       \
 220                 *(__kcrctab_unused_gpl)                                 \
 221                 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;        \
 222         }                                                               \
 223                                                                         \
 224         /* Kernel symbol table: GPL-future-only symbols */              \
 225         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
 226                 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;       \
 227                 *(__kcrctab_gpl_future)                                 \
 228                 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;        \
 229         }                                                               \
 230                                                                         \
 231         /* Kernel symbol table: strings */                              \
 232         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
 233                 *(__ksymtab_strings)                                    \
 234         }                                                               \
 235                                                                         \
 236         /* __*init sections */                                          \
 237         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
 238                 *(.ref.rodata)                                          \
 239                 MCOUNT_REC()                                            \
 240                 DEV_KEEP(init.rodata)                                   \
 241                 DEV_KEEP(exit.rodata)                                   \
 242                 CPU_KEEP(init.rodata)                                   \
 243                 CPU_KEEP(exit.rodata)                                   \
 244                 MEM_KEEP(init.rodata)                                   \
 245                 MEM_KEEP(exit.rodata)                                   \
 246         }                                                               \
 247                                                                         \
 248         /* Built-in module parameters. */                               \
 249         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
 250                 VMLINUX_SYMBOL(__start___param) = .;                    \
 251                 *(__param)                                              \
 252                 VMLINUX_SYMBOL(__stop___param) = .;                     \
 253                 . = ALIGN((align));                                     \
 254                 VMLINUX_SYMBOL(__end_rodata) = .;                       \
 255         }                                                               \
 256         . = ALIGN((align));
 257
 258 /* RODATA provided for backward compatibility.
 259  * All archs are supposed to use RO_DATA() */
 260 #define RODATA RO_DATA(4096)
 261
 262 #define SECURITY_INIT                                                   \
 263         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
 264                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
 265                 *(.security_initcall.init)                              \
 266                 VMLINUX_SYMBOL(__security_initcall_end) = .;            \
 267         }
 268
 269 /* .text section. Map to function alignment to avoid address changes
 270  * during second ld run in second ld pass when generating System.map */
 271 #define TEXT_TEXT                                                       \
 272                 ALIGN_FUNCTION();                                       \
 273                 *(.text.hot)                                            \
 274                 *(.text)                                                \
 275                 *(.ref.text)                                            \
 276                 *(.text.init.refok)                                     \
 277                 *(.exit.text.refok)                                     \
 278         DEV_KEEP(init.text)                                             \
 279         DEV_KEEP(exit.text)                                             \
 280         CPU_KEEP(init.text)                                             \
 281         CPU_KEEP(exit.text)                                             \
 282         MEM_KEEP(init.text)                                             \
 283         MEM_KEEP(exit.text)                                             \
 284                 *(.text.unlikely)
 285
 286
 287 /* sched.text is aling to function alignment to secure we have same
 288  * address even at second ld pass when generating System.map */
 289 #define SCHED_TEXT                                                      \
 290                 ALIGN_FUNCTION();                                       \
 291                 VMLINUX_SYMBOL(__sched_text_start) = .;                 \
 292                 *(.sched.text)                                          \
 293                 VMLINUX_SYMBOL(__sched_text_end) = .;
 294
 295 /* spinlock.text is aling to function alignment to secure we have same
 296  * address even at second ld pass when generating System.map */
 297 #define LOCK_TEXT                                                       \
 298                 ALIGN_FUNCTION();                                       \
 299                 VMLINUX_SYMBOL(__lock_text_start) = .;                  \
 300                 *(.spinlock.text)                                       \
 301                 VMLINUX_SYMBOL(__lock_text_end) = .;
 302
 303 #define KPROBES_TEXT                                                    \
 304                 ALIGN_FUNCTION();                                       \
 305                 VMLINUX_SYMBOL(__kprobes_text_start) = .;               \
 306                 *(.kprobes.text)                                        \
 307                 VMLINUX_SYMBOL(__kprobes_text_end) = .;
 308
 309 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 310 #define IRQENTRY_TEXT                                                   \
 311                 ALIGN_FUNCTION();                                       \
 312                 VMLINUX_SYMBOL(__irqentry_text_start) = .;              \
 313                 *(.irqentry.text)                                       \
 314                 VMLINUX_SYMBOL(__irqentry_text_end) = .;
 315 #else
 316 #define IRQENTRY_TEXT
 317 #endif
 318
 319 /* Section used for early init (in .S files) */
 320 #define HEAD_TEXT  *(.head.text)
 321
 322 /* init and exit section handling */
 323 #define INIT_DATA                                                       \
 324         *(.init.data)                                                   \
 325         DEV_DISCARD(init.data)                                          \
 326         DEV_DISCARD(init.rodata)                                        \
 327         CPU_DISCARD(init.data)                                          \
 328         CPU_DISCARD(init.rodata)                                        \
 329         MEM_DISCARD(init.data)                                          \
 330         MEM_DISCARD(init.rodata)                                        \
 331         /* implement dynamic printk debug */                            \
 332         VMLINUX_SYMBOL(__start___verbose_strings) = .;                  \
 333         *(__verbose_strings)                                            \
 334         VMLINUX_SYMBOL(__stop___verbose_strings) = .;                   \
 335         . = ALIGN(8);                                                   \
 336         VMLINUX_SYMBOL(__start___verbose) = .;                          \
 337         *(__verbose)                                                    \
 338         VMLINUX_SYMBOL(__stop___verbose) = .;
 339
 340 #define INIT_TEXT                                                       \
 341         *(.init.text)                                                   \
 342         DEV_DISCARD(init.text)                                          \
 343         CPU_DISCARD(init.text)                                          \
 344         MEM_DISCARD(init.text)
 345
 346 #define EXIT_DATA                                                       \
 347         *(.exit.data)                                                   \
 348         DEV_DISCARD(exit.data)                                          \
 349         DEV_DISCARD(exit.rodata)                                        \
 350         CPU_DISCARD(exit.data)                                          \
 351         CPU_DISCARD(exit.rodata)                                        \
 352         MEM_DISCARD(exit.data)                                          \
 353         MEM_DISCARD(exit.rodata)
 354
 355 #define EXIT_TEXT                                                       \
 356         *(.exit.text)                                                   \
 357         DEV_DISCARD(exit.text)                                          \
 358         CPU_DISCARD(exit.text)                                          \
 359         MEM_DISCARD(exit.text)
 360
 361                 /* DWARF debug sections.
 362                 Symbols in the DWARF debugging sections are relative to
 363                 the beginning of the section so we begin them at 0.  */
 364 #define DWARF_DEBUG                                                     \
 365                 /* DWARF 1 */                                           \
 366                 .debug          0 : { *(.debug) }                       \
 367                 .line           0 : { *(.line) }                        \
 368                 /* GNU DWARF 1 extensions */                            \
 369                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
 370                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
 371                 /* DWARF 1.1 and DWARF 2 */                             \
 372                 .debug_aranges  0 : { *(.debug_aranges) }               \
 373                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
 374                 /* DWARF 2 */                                           \
 375                 .debug_info     0 : { *(.debug_info                     \
 376                                 .gnu.linkonce.wi.*) }                   \
 377                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
 378                 .debug_line     0 : { *(.debug_line) }                  \
 379                 .debug_frame    0 : { *(.debug_frame) }                 \
 380                 .debug_str      0 : { *(.debug_str) }                   \
 381                 .debug_loc      0 : { *(.debug_loc) }                   \
 382                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
 383                 /* SGI/MIPS DWARF 2 extensions */                       \
 384                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
 385                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
 386                 .debug_typenames 0 : { *(.debug_typenames) }            \
 387                 .debug_varnames  0 : { *(.debug_varnames) }             \
 388
 389                 /* Stabs debugging sections.  */
 390 #define STABS_DEBUG                                                     \
 391                 .stab 0 : { *(.stab) }                                  \
 392                 .stabstr 0 : { *(.stabstr) }                            \
 393                 .stab.excl 0 : { *(.stab.excl) }                        \
 394                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
 395                 .stab.index 0 : { *(.stab.index) }                      \
 396                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
 397                 .comment 0 : { *(.comment) }
 398
 399 #ifdef CONFIG_GENERIC_BUG
 400 #define BUG_TABLE                                                       \
 401         . = ALIGN(8);                                                   \
 402         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
 403                 VMLINUX_SYMBOL(__start___bug_table) = .;                \
 404                 *(__bug_table)                                          \
 405                 VMLINUX_SYMBOL(__stop___bug_table) = .;                 \
 406         }
 407 #else
 408 #define BUG_TABLE
 409 #endif
 410
 411 #ifdef CONFIG_PM_TRACE
 412 #define TRACEDATA                                                       \
 413         . = ALIGN(4);                                                   \
 414         .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {               \
 415                 VMLINUX_SYMBOL(__tracedata_start) = .;                  \
 416                 *(.tracedata)                                           \
 417                 VMLINUX_SYMBOL(__tracedata_end) = .;                    \
 418         }
 419 #else
 420 #define TRACEDATA
 421 #endif
 422
 423 #define NOTES                                                           \
 424         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
 425                 VMLINUX_SYMBOL(__start_notes) = .;                      \
 426                 *(.note.*)                                              \
 427                 VMLINUX_SYMBOL(__stop_notes) = .;                       \
 428         }
 429
 430 #define INITCALLS                                                       \
 431         *(.initcallearly.init)                                          \
 432         VMLINUX_SYMBOL(__early_initcall_end) = .;                       \
 433         *(.initcall0.init)                                              \
 434         *(.initcall0s.init)                                             \
 435         *(.initcall1.init)                                              \
 436         *(.initcall1s.init)                                             \
 437         *(.initcall2.init)                                              \
 438         *(.initcall2s.init)                                             \
 439         *(.initcall3.init)                                              \
 440         *(.initcall3s.init)                                             \
 441         *(.initcall4.init)                                              \
 442         *(.initcall4s.init)                                             \
 443         *(.initcall5.init)                                              \
 444         *(.initcall5s.init)                                             \
 445         *(.initcallrootfs.init)                                         \
 446         *(.initcall6.init)                                              \
 447         *(.initcall6s.init)                                             \
 448         *(.initcall7.init)                                              \
 449         *(.initcall7s.init)
 450
 451 #define PERCPU(align)                                                   \
 452         . = ALIGN(align);                                               \
 453         VMLINUX_SYMBOL(__per_cpu_start) = .;                            \
 454         .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) {          \
 455                 *(.data.percpu.page_aligned)                            \
 456                 *(.data.percpu)                                         \
 457                 *(.data.percpu.shared_aligned)                          \
 458         }                                                               \
 459         VMLINUX_SYMBOL(__per_cpu_end) = .;