SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/x86/kernel/vmlinux.lds.S

   1 /*
   2  * ld script for the x86 kernel
   3  *
   4  * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5  *
   6  * Modernisation, unification and other changes and fixes:
   7  *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8  *
   9  *
  10  * Don't define absolute symbols until and unless you know that symbol
  11  * value is should remain constant even if kernel image is relocated
  12  * at run time. Absolute symbols are not relocated. If symbol value should
  13  * change if kernel is relocated, make the symbol section relative and
  14  * put it inside the section definition.
  15  */
  16
  17 #ifdef CONFIG_X86_32
  18 #define LOAD_OFFSET __PAGE_OFFSET
  19 #else
  20 #define LOAD_OFFSET __START_KERNEL_map
  21 #endif
  22
  23 #include <asm-generic/vmlinux.lds.h>
  24 #include <asm/asm-offsets.h>
  25 #include <asm/thread_info.h>
  26 #include <asm/page_types.h>
  27 #include <asm/cache.h>
  28 #include <asm/boot.h>
  29
  30 #undef i386     /* in case the preprocessor is a 32bit one */
  31
  32 OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34 #ifdef CONFIG_X86_32
  35 OUTPUT_ARCH(i386)
  36 ENTRY(phys_startup_32)
  37 jiffies = jiffies_64;
  38 #else
  39 OUTPUT_ARCH(i386:x86-64)
  40 ENTRY(phys_startup_64)
  41 jiffies_64 = jiffies;
  42 #endif
  43
  44 PHDRS {
  45         text PT_LOAD FLAGS(5);          /* R_E */
  46         data PT_LOAD FLAGS(7);          /* RWE */
  47 #ifdef CONFIG_X86_64
  48         user PT_LOAD FLAGS(7);          /* RWE */
  49 #ifdef CONFIG_SMP
  50         percpu PT_LOAD FLAGS(7);        /* RWE */
  51 #endif
  52         init PT_LOAD FLAGS(7);          /* RWE */
  53 #endif
  54         note PT_NOTE FLAGS(0);          /* ___ */
  55 }
  56
  57 SECTIONS
  58 {
  59 #ifdef CONFIG_X86_32
  60         . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  61         phys_startup_32 = startup_32 - LOAD_OFFSET;
  62 #else
  63         . = __START_KERNEL;
  64         phys_startup_64 = startup_64 - LOAD_OFFSET;
  65 #endif
  66
  67         /* Text and read-only data */
  68         .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  69                 _text = .;
  70                 /* bootstrapping code */
  71                 HEAD_TEXT
  72 #ifdef CONFIG_X86_32
  73                 . = ALIGN(PAGE_SIZE);
  74                 *(.text.page_aligned)
  75 #endif
  76                 . = ALIGN(8);
  77                 _stext = .;
  78                 TEXT_TEXT
  79                 SCHED_TEXT
  80                 LOCK_TEXT
  81                 KPROBES_TEXT
  82                 IRQENTRY_TEXT
  83                 *(.fixup)
  84                 *(.gnu.warning)
  85                 /* End of text section */
  86                 _etext = .;
  87         } :text = 0x9090
  88
  89         NOTES :text :note
  90
  91         /* Exception table */
  92         . = ALIGN(16);
  93         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
  94                 __start___ex_table = .;
  95                 *(__ex_table)
  96                 __stop___ex_table = .;
  97         } :text = 0x9090
  98
  99         RO_DATA(PAGE_SIZE)
 100
 101         /* Data */
 102         .data : AT(ADDR(.data) - LOAD_OFFSET) {
 103                 /* Start of data section */
 104                 _sdata = .;
 105
 106                 /* init_task */
 107                 INIT_TASK_DATA(THREAD_SIZE)
 108
 109 #ifdef CONFIG_X86_32
 110                 /* 32 bit has nosave before _edata */
 111                 NOSAVE_DATA
 112 #endif
 113
 114                 PAGE_ALIGNED_DATA(PAGE_SIZE)
 115                 *(.data.idt)
 116
 117                 CACHELINE_ALIGNED_DATA(CONFIG_X86_L1_CACHE_BYTES)
 118
 119                 DATA_DATA
 120                 CONSTRUCTORS
 121
 122                 /* rarely changed data like cpu maps */
 123                 READ_MOSTLY_DATA(CONFIG_X86_INTERNODE_CACHE_BYTES)
 124
 125                 /* End of data section */
 126                 _edata = .;
 127         } :data
 128
 129 #ifdef CONFIG_X86_64
 130
 131 #define VSYSCALL_ADDR (-10*1024*1024)
 132
 133 #define VLOAD_OFFSET (VSYSCALL_ADDR - __vsyscall_0 + LOAD_OFFSET)
 134 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
 135
 136 #define VVIRT_OFFSET (VSYSCALL_ADDR - __vsyscall_0)
 137 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
 138
 139         . = ALIGN(4096);
 140         __vsyscall_0 = .;
 141
 142         . = VSYSCALL_ADDR;
 143         .vsyscall_0 : AT(VLOAD(.vsyscall_0)) {
 144                 *(.vsyscall_0)
 145         } :user
 146
 147         . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 148         .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) {
 149                 *(.vsyscall_fn)
 150         }
 151
 152         . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 153         .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data)) {
 154                 *(.vsyscall_gtod_data)
 155         }
 156
 157         vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data);
 158         .vsyscall_clock : AT(VLOAD(.vsyscall_clock)) {
 159                 *(.vsyscall_clock)
 160         }
 161         vsyscall_clock = VVIRT(.vsyscall_clock);
 162
 163
 164         .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) {
 165                 *(.vsyscall_1)
 166         }
 167         .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) {
 168                 *(.vsyscall_2)
 169         }
 170
 171         .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) {
 172                 *(.vgetcpu_mode)
 173         }
 174         vgetcpu_mode = VVIRT(.vgetcpu_mode);
 175
 176         . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 177         .jiffies : AT(VLOAD(.jiffies)) {
 178                 *(.jiffies)
 179         }
 180         jiffies = VVIRT(.jiffies);
 181
 182         .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) {
 183                 *(.vsyscall_3)
 184         }
 185
 186         . = __vsyscall_0 + PAGE_SIZE;
 187
 188 #undef VSYSCALL_ADDR
 189 #undef VLOAD_OFFSET
 190 #undef VLOAD
 191 #undef VVIRT_OFFSET
 192 #undef VVIRT
 193
 194 #endif /* CONFIG_X86_64 */
 195
 196         /* Init code and data - will be freed after init */
 197         . = ALIGN(PAGE_SIZE);
 198         .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 199                 __init_begin = .; /* paired with __init_end */
 200         }
 201
 202 #if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 203         /*
 204          * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 205          * output PHDR, so the next output section - .init.text - should
 206          * start another segment - init.
 207          */
 208         PERCPU_VADDR(0, :percpu)
 209 #endif
 210
 211         .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 212                 _sinittext = .;
 213                 INIT_TEXT
 214                 _einittext = .;
 215         }
 216 #ifdef CONFIG_X86_64
 217         :init
 218 #endif
 219
 220         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 221                 INIT_DATA
 222         }
 223
 224         . = ALIGN(16);
 225         .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 226                 __setup_start = .;
 227                 *(.init.setup)
 228                 __setup_end = .;
 229         }
 230         .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 231                 __initcall_start = .;
 232                 INITCALLS
 233                 __initcall_end = .;
 234         }
 235
 236         .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 237                 __con_initcall_start = .;
 238                 *(.con_initcall.init)
 239                 __con_initcall_end = .;
 240         }
 241
 242         .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 243                 __x86_cpu_dev_start = .;
 244                 *(.x86_cpu_dev.init)
 245                 __x86_cpu_dev_end = .;
 246         }
 247
 248         SECURITY_INIT
 249
 250         . = ALIGN(8);
 251         .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 252                 __parainstructions = .;
 253                 *(.parainstructions)
 254                 __parainstructions_end = .;
 255         }
 256
 257         . = ALIGN(8);
 258         .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 259                 __alt_instructions = .;
 260                 *(.altinstructions)
 261                 __alt_instructions_end = .;
 262         }
 263
 264         .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 265                 *(.altinstr_replacement)
 266         }
 267
 268         /*
 269          * .exit.text is discard at runtime, not link time, to deal with
 270          *  references from .altinstructions and .eh_frame
 271          */
 272         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 273                 EXIT_TEXT
 274         }
 275
 276         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 277                 EXIT_DATA
 278         }
 279
 280 #ifdef CONFIG_BLK_DEV_INITRD
 281         . = ALIGN(PAGE_SIZE);
 282         .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 283                 __initramfs_start = .;
 284                 *(.init.ramfs)
 285                 __initramfs_end = .;
 286         }
 287 #endif
 288
 289 #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 290         PERCPU(PAGE_SIZE)
 291 #endif
 292
 293         . = ALIGN(PAGE_SIZE);
 294
 295         /* freed after init ends here */
 296         .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 297                 __init_end = .;
 298         }
 299
 300         /*
 301          * smp_locks might be freed after init
 302          * start/end must be page aligned
 303          */
 304         . = ALIGN(PAGE_SIZE);
 305         .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 306                 __smp_locks = .;
 307                 *(.smp_locks)
 308                 __smp_locks_end = .;
 309                 . = ALIGN(PAGE_SIZE);
 310         }
 311
 312 #ifdef CONFIG_X86_64
 313         .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 314                 NOSAVE_DATA
 315         }
 316 #endif
 317
 318         /* BSS */
 319         . = ALIGN(PAGE_SIZE);
 320         .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 321                 __bss_start = .;
 322                 *(.bss.page_aligned)
 323                 *(.bss)
 324                 . = ALIGN(4);
 325                 __bss_stop = .;
 326         }
 327
 328         . = ALIGN(PAGE_SIZE);
 329         .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 330                 __brk_base = .;
 331                 . += 64 * 1024;         /* 64k alignment slop space */
 332                 *(.brk_reservation)     /* areas brk users have reserved */
 333                 __brk_limit = .;
 334         }
 335
 336         .end : AT(ADDR(.end) - LOAD_OFFSET) {
 337                 _end = .;
 338         }
 339
 340         STABS_DEBUG
 341         DWARF_DEBUG
 342
 343         /* Sections to be discarded */
 344         DISCARDS
 345         /DISCARD/ : { *(.eh_frame) }
 346 }
 347
 348
 349 #ifdef CONFIG_X86_32
 350 . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 351            "kernel image bigger than KERNEL_IMAGE_SIZE");
 352 #else
 353 /*
 354  * Per-cpu symbols which need to be offset from __per_cpu_load
 355  * for the boot processor.
 356  */
 357 #define INIT_PER_CPU(x) init_per_cpu__##x = per_cpu__##x + __per_cpu_load
 358 INIT_PER_CPU(gdt_page);
 359 INIT_PER_CPU(irq_stack_union);
 360
 361 /*
 362  * Build-time check on the image size:
 363  */
 364 . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 365            "kernel image bigger than KERNEL_IMAGE_SIZE");
 366
 367 #ifdef CONFIG_SMP
 368 . = ASSERT((per_cpu__irq_stack_union == 0),
 369            "irq_stack_union is not at start of per-cpu area");
 370 #endif
 371
 372 #endif /* CONFIG_X86_32 */
 373
 374 #ifdef CONFIG_KEXEC
 375 #include <asm/kexec.h>
 376
 377 . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 378            "kexec control code size is too big");
 379 #endif
 380