SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/x86/kernel/head_32.S

   1 /*
   2  *  linux/arch/i386/kernel/head.S -- the 32-bit startup code.
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *
   6  *  Enhanced CPU detection and feature setting code by Mike Jagdis
   7  *  and Martin Mares, November 1997.
   8  */
   9
  10 .text
  11 #include <linux/threads.h>
  12 #include <linux/linkage.h>
  13 #include <asm/segment.h>
  14 #include <asm/page.h>
  15 #include <asm/pgtable.h>
  16 #include <asm/desc.h>
  17 #include <asm/cache.h>
  18 #include <asm/thread_info.h>
  19 #include <asm/asm-offsets.h>
  20 #include <asm/setup.h>
  21
  22 /*
  23  * References to members of the new_cpu_data structure.
  24  */
  25
  26 #define X86             new_cpu_data+CPUINFO_x86
  27 #define X86_VENDOR      new_cpu_data+CPUINFO_x86_vendor
  28 #define X86_MODEL       new_cpu_data+CPUINFO_x86_model
  29 #define X86_MASK        new_cpu_data+CPUINFO_x86_mask
  30 #define X86_HARD_MATH   new_cpu_data+CPUINFO_hard_math
  31 #define X86_CPUID       new_cpu_data+CPUINFO_cpuid_level
  32 #define X86_CAPABILITY  new_cpu_data+CPUINFO_x86_capability
  33 #define X86_VENDOR_ID   new_cpu_data+CPUINFO_x86_vendor_id
  34
  35 /*
  36  * This is how much memory *in addition to the memory covered up to
  37  * and including _end* we need mapped initially.
  38  * We need:
  39  *  - one bit for each possible page, but only in low memory, which means
  40  *     2^32/4096/8 = 128K worst case (4G/4G split.)
  41  *  - enough space to map all low memory, which means
  42  *     (2^32/4096) / 1024 pages (worst case, non PAE)
  43  *     (2^32/4096) / 512 + 4 pages (worst case for PAE)
  44  *  - a few pages for allocator use before the kernel pagetable has
  45  *     been set up
  46  *
  47  * Modulo rounding, each megabyte assigned here requires a kilobyte of
  48  * memory, which is currently unreclaimed.
  49  *
  50  * This should be a multiple of a page.
  51  */
  52 LOW_PAGES = 1<<(32-PAGE_SHIFT_asm)
  53
  54 /*
  55  * To preserve the DMA pool in PAGEALLOC kernels, we'll allocate
  56  * pagetables from above the 16MB DMA limit, so we'll have to set
  57  * up pagetables 16MB more (worst-case):
  58  */
  59 #ifdef CONFIG_DEBUG_PAGEALLOC
  60 LOW_PAGES = LOW_PAGES + 0x1000000
  61 #endif
  62
  63 #if PTRS_PER_PMD > 1
  64 PAGE_TABLE_SIZE = (LOW_PAGES / PTRS_PER_PMD) + PTRS_PER_PGD
  65 #else
  66 PAGE_TABLE_SIZE = (LOW_PAGES / PTRS_PER_PGD)
  67 #endif
  68 BOOTBITMAP_SIZE = LOW_PAGES / 8
  69 ALLOCATOR_SLOP = 4
  70
  71 INIT_MAP_BEYOND_END = BOOTBITMAP_SIZE + (PAGE_TABLE_SIZE + ALLOCATOR_SLOP)*PAGE_SIZE_asm
  72
  73 /*
  74  * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
  75  * %esi points to the real-mode code as a 32-bit pointer.
  76  * CS and DS must be 4 GB flat segments, but we don't depend on
  77  * any particular GDT layout, because we load our own as soon as we
  78  * can.
  79  */
  80 .section .text.head,"ax",@progbits
  81 ENTRY(startup_32)
  82         /* check to see if KEEP_SEGMENTS flag is meaningful */
  83         cmpw $0x207, BP_version(%esi)
  84         jb 1f
  85
  86         /* test KEEP_SEGMENTS flag to see if the bootloader is asking
  87                 us to not reload segments */
  88         testb $(1<<6), BP_loadflags(%esi)
  89         jnz 2f
  90
  91 /*
  92  * Set segments to known values.
  93  */
  94 1:      lgdt boot_gdt_descr - __PAGE_OFFSET
  95         movl $(__BOOT_DS),%eax
  96         movl %eax,%ds
  97         movl %eax,%es
  98         movl %eax,%fs
  99         movl %eax,%gs
 100 2:
 101
 102 /*
 103  * Clear BSS first so that there are no surprises...
 104  */
 105         cld
 106         xorl %eax,%eax
 107         movl $__bss_start - __PAGE_OFFSET,%edi
 108         movl $__bss_stop - __PAGE_OFFSET,%ecx
 109         subl %edi,%ecx
 110         shrl $2,%ecx
 111         rep ; stosl
 112 /*
 113  * Copy bootup parameters out of the way.
 114  * Note: %esi still has the pointer to the real-mode data.
 115  * With the kexec as boot loader, parameter segment might be loaded beyond
 116  * kernel image and might not even be addressable by early boot page tables.
 117  * (kexec on panic case). Hence copy out the parameters before initializing
 118  * page tables.
 119  */
 120         movl $(boot_params - __PAGE_OFFSET),%edi
 121         movl $(PARAM_SIZE/4),%ecx
 122         cld
 123         rep
 124         movsl
 125         movl boot_params - __PAGE_OFFSET + NEW_CL_POINTER,%esi
 126         andl %esi,%esi
 127         jz 1f                   # No comand line
 128         movl $(boot_command_line - __PAGE_OFFSET),%edi
 129         movl $(COMMAND_LINE_SIZE/4),%ecx
 130         rep
 131         movsl
 132 1:
 133
 134 #ifdef CONFIG_PARAVIRT
 135         cmpw $0x207, (boot_params + BP_version - __PAGE_OFFSET)
 136         jb default_entry
 137
 138         /* Paravirt-compatible boot parameters.  Look to see what architecture
 139                 we're booting under. */
 140         movl (boot_params + BP_hardware_subarch - __PAGE_OFFSET), %eax
 141         cmpl $num_subarch_entries, %eax
 142         jae bad_subarch
 143
 144         movl subarch_entries - __PAGE_OFFSET(,%eax,4), %eax
 145         subl $__PAGE_OFFSET, %eax
 146         jmp *%eax
 147
 148 bad_subarch:
 149 WEAK(lguest_entry)
 150 WEAK(xen_entry)
 151         /* Unknown implementation; there's really
 152            nothing we can do at this point. */
 153         ud2a
 154 .data
 155 subarch_entries:
 156         .long default_entry             /* normal x86/PC */
 157         .long lguest_entry              /* lguest hypervisor */
 158         .long xen_entry                 /* Xen hypervisor */
 159 num_subarch_entries = (. - subarch_entries) / 4
 160 .previous
 161 #endif /* CONFIG_PARAVIRT */
 162
 163 /*
 164  * Initialize page tables.  This creates a PDE and a set of page
 165  * tables, which are located immediately beyond _end.  The variable
 166  * init_pg_tables_end is set up to point to the first "safe" location.
 167  * Mappings are created both at virtual address 0 (identity mapping)
 168  * and PAGE_OFFSET for up to _end+sizeof(page tables)+INIT_MAP_BEYOND_END.
 169  *
 170  * Warning: don't use %esi or the stack in this code.  However, %esp
 171  * can be used as a GPR if you really need it...
 172  */
 173 page_pde_offset = (__PAGE_OFFSET >> 20);
 174
 175 default_entry:
 176         movl $(pg0 - __PAGE_OFFSET), %edi
 177         movl $(swapper_pg_dir - __PAGE_OFFSET), %edx
 178         movl $0x007, %eax                       /* 0x007 = PRESENT+RW+USER */
 179 10:
 180         leal 0x007(%edi),%ecx                   /* Create PDE entry */
 181         movl %ecx,(%edx)                        /* Store identity PDE entry */
 182         movl %ecx,page_pde_offset(%edx)         /* Store kernel PDE entry */
 183         addl $4,%edx
 184         movl $1024, %ecx
 185 11:
 186         stosl
 187         addl $0x1000,%eax
 188         loop 11b
 189         /* End condition: we must map up to and including INIT_MAP_BEYOND_END */
 190         /* bytes beyond the end of our own page tables; the +0x007 is the attribute bits */
 191         leal (INIT_MAP_BEYOND_END+0x007)(%edi),%ebp
 192         cmpl %ebp,%eax
 193         jb 10b
 194         movl %edi,(init_pg_tables_end - __PAGE_OFFSET)
 195
 196         /* Do an early initialization of the fixmap area */
 197         movl $(swapper_pg_dir - __PAGE_OFFSET), %edx
 198         movl $(swapper_pg_pmd - __PAGE_OFFSET), %eax
 199         addl $0x67, %eax                        /* 0x67 == _PAGE_TABLE */
 200         movl %eax, 4092(%edx)
 201
 202         jmp 3f
 203 /*
 204  * Non-boot CPU entry point; entered from trampoline.S
 205  * We can't lgdt here, because lgdt itself uses a data segment, but
 206  * we know the trampoline has already loaded the boot_gdt for us.
 207  *
 208  * If cpu hotplug is not supported then this code can go in init section
 209  * which will be freed later
 210  */
 211
 212 #ifndef CONFIG_HOTPLUG_CPU
 213 .section .init.text,"ax",@progbits
 214 #endif
 215
 216 #ifdef CONFIG_SMP
 217 ENTRY(startup_32_smp)
 218         cld
 219         movl $(__BOOT_DS),%eax
 220         movl %eax,%ds
 221         movl %eax,%es
 222         movl %eax,%fs
 223         movl %eax,%gs
 224
 225 /*
 226  *      New page tables may be in 4Mbyte page mode and may
 227  *      be using the global pages.
 228  *
 229  *      NOTE! If we are on a 486 we may have no cr4 at all!
 230  *      So we do not try to touch it unless we really have
 231  *      some bits in it to set.  This won't work if the BSP
 232  *      implements cr4 but this AP does not -- very unlikely
 233  *      but be warned!  The same applies to the pse feature
 234  *      if not equally supported. --macro
 235  *
 236  *      NOTE! We have to correct for the fact that we're
 237  *      not yet offset PAGE_OFFSET..
 238  */
 239 #define cr4_bits mmu_cr4_features-__PAGE_OFFSET
 240         movl cr4_bits,%edx
 241         andl %edx,%edx
 242         jz 6f
 243         movl %cr4,%eax          # Turn on paging options (PSE,PAE,..)
 244         orl %edx,%eax
 245         movl %eax,%cr4
 246
 247         btl $5, %eax            # check if PAE is enabled
 248         jnc 6f
 249
 250         /* Check if extended functions are implemented */
 251         movl $0x80000000, %eax
 252         cpuid
 253         cmpl $0x80000000, %eax
 254         jbe 6f
 255         mov $0x80000001, %eax
 256         cpuid
 257         /* Execute Disable bit supported? */
 258         btl $20, %edx
 259         jnc 6f
 260
 261         /* Setup EFER (Extended Feature Enable Register) */
 262         movl $0xc0000080, %ecx
 263         rdmsr
 264
 265         btsl $11, %eax
 266         /* Make changes effective */
 267         wrmsr
 268
 269 6:
 270 #endif /* CONFIG_SMP */
 271 3:
 272
 273 /*
 274  * Enable paging
 275  */
 276         movl $swapper_pg_dir-__PAGE_OFFSET,%eax
 277         movl %eax,%cr3          /* set the page table pointer.. */
 278         movl %cr0,%eax
 279         orl $0x80000000,%eax
 280         movl %eax,%cr0          /* ..and set paging (PG) bit */
 281         ljmp $__BOOT_CS,$1f     /* Clear prefetch and normalize %eip */
 282 1:
 283         /* Set up the stack pointer */
 284         lss stack_start,%esp
 285
 286 /*
 287  * Initialize eflags.  Some BIOS's leave bits like NT set.  This would
 288  * confuse the debugger if this code is traced.
 289  * XXX - best to initialize before switching to protected mode.
 290  */
 291         pushl $0
 292         popfl
 293
 294 #ifdef CONFIG_SMP
 295         cmpb $0, ready
 296         jz  1f                          /* Initial CPU cleans BSS */
 297         jmp checkCPUtype
 298 1:
 299 #endif /* CONFIG_SMP */
 300
 301 /*
 302  * start system 32-bit setup. We need to re-do some of the things done
 303  * in 16-bit mode for the "real" operations.
 304  */
 305         call setup_idt
 306
 307 checkCPUtype:
 308
 309         movl $-1,X86_CPUID              #  -1 for no CPUID initially
 310
 311 /* check if it is 486 or 386. */
 312 /*
 313  * XXX - this does a lot of unnecessary setup.  Alignment checks don't
 314  * apply at our cpl of 0 and the stack ought to be aligned already, and
 315  * we don't need to preserve eflags.
 316  */
 317
 318         movb $3,X86             # at least 386
 319         pushfl                  # push EFLAGS
 320         popl %eax               # get EFLAGS
 321         movl %eax,%ecx          # save original EFLAGS
 322         xorl $0x240000,%eax     # flip AC and ID bits in EFLAGS
 323         pushl %eax              # copy to EFLAGS
 324         popfl                   # set EFLAGS
 325         pushfl                  # get new EFLAGS
 326         popl %eax               # put it in eax
 327         xorl %ecx,%eax          # change in flags
 328         pushl %ecx              # restore original EFLAGS
 329         popfl
 330         testl $0x40000,%eax     # check if AC bit changed
 331         je is386
 332
 333         movb $4,X86             # at least 486
 334         testl $0x200000,%eax    # check if ID bit changed
 335         je is486
 336
 337         /* get vendor info */
 338         xorl %eax,%eax                  # call CPUID with 0 -> return vendor ID
 339         cpuid
 340         movl %eax,X86_CPUID             # save CPUID level
 341         movl %ebx,X86_VENDOR_ID         # lo 4 chars
 342         movl %edx,X86_VENDOR_ID+4       # next 4 chars
 343         movl %ecx,X86_VENDOR_ID+8       # last 4 chars
 344
 345         orl %eax,%eax                   # do we have processor info as well?
 346         je is486
 347
 348         movl $1,%eax            # Use the CPUID instruction to get CPU type
 349         cpuid
 350         movb %al,%cl            # save reg for future use
 351         andb $0x0f,%ah          # mask processor family
 352         movb %ah,X86
 353         andb $0xf0,%al          # mask model
 354         shrb $4,%al
 355         movb %al,X86_MODEL
 356         andb $0x0f,%cl          # mask mask revision
 357         movb %cl,X86_MASK
 358         movl %edx,X86_CAPABILITY
 359
 360 is486:  movl $0x50022,%ecx      # set AM, WP, NE and MP
 361         jmp 2f
 362
 363 is386:  movl $2,%ecx            # set MP
 364 2:      movl %cr0,%eax
 365         andl $0x80000011,%eax   # Save PG,PE,ET
 366         orl %ecx,%eax
 367         movl %eax,%cr0
 368
 369         call check_x87
 370         lgdt early_gdt_descr
 371         lidt idt_descr
 372         ljmp $(__KERNEL_CS),$1f
 373 1:      movl $(__KERNEL_DS),%eax        # reload all the segment registers
 374         movl %eax,%ss                   # after changing gdt.
 375         movl %eax,%fs                   # gets reset once there's real percpu
 376
 377         movl $(__USER_DS),%eax          # DS/ES contains default USER segment
 378         movl %eax,%ds
 379         movl %eax,%es
 380
 381         xorl %eax,%eax                  # Clear GS and LDT
 382         movl %eax,%gs
 383         lldt %ax
 384
 385         cld                     # gcc2 wants the direction flag cleared at all times
 386         pushl $0                # fake return address for unwinder
 387 #ifdef CONFIG_SMP
 388         movb ready, %cl
 389         movb $1, ready
 390         cmpb $0,%cl             # the first CPU calls start_kernel
 391         je   1f
 392         movl $(__KERNEL_PERCPU), %eax
 393         movl %eax,%fs           # set this cpu's percpu
 394         jmp initialize_secondary # all other CPUs call initialize_secondary
 395 1:
 396 #endif /* CONFIG_SMP */
 397         jmp start_kernel
 398
 399 /*
 400  * We depend on ET to be correct. This checks for 287/387.
 401  */
 402 check_x87:
 403         movb $0,X86_HARD_MATH
 404         clts
 405         fninit
 406         fstsw %ax
 407         cmpb $0,%al
 408         je 1f
 409         movl %cr0,%eax          /* no coprocessor: have to set bits */
 410         xorl $4,%eax            /* set EM */
 411         movl %eax,%cr0
 412         ret
 413         ALIGN
 414 1:      movb $1,X86_HARD_MATH
 415         .byte 0xDB,0xE4         /* fsetpm for 287, ignored by 387 */
 416         ret
 417
 418 /*
 419  *  setup_idt
 420  *
 421  *  sets up a idt with 256 entries pointing to
 422  *  ignore_int, interrupt gates. It doesn't actually load
 423  *  idt - that can be done only after paging has been enabled
 424  *  and the kernel moved to PAGE_OFFSET. Interrupts
 425  *  are enabled elsewhere, when we can be relatively
 426  *  sure everything is ok.
 427  *
 428  *  Warning: %esi is live across this function.
 429  */
 430 setup_idt:
 431         lea ignore_int,%edx
 432         movl $(__KERNEL_CS << 16),%eax
 433         movw %dx,%ax            /* selector = 0x0010 = cs */
 434         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
 435
 436         lea idt_table,%edi
 437         mov $256,%ecx
 438 rp_sidt:
 439         movl %eax,(%edi)
 440         movl %edx,4(%edi)
 441         addl $8,%edi
 442         dec %ecx
 443         jne rp_sidt
 444
 445 .macro  set_early_handler handler,trapno
 446         lea \handler,%edx
 447         movl $(__KERNEL_CS << 16),%eax
 448         movw %dx,%ax
 449         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
 450         lea idt_table,%edi
 451         movl %eax,8*\trapno(%edi)
 452         movl %edx,8*\trapno+4(%edi)
 453 .endm
 454
 455         set_early_handler handler=early_divide_err,trapno=0
 456         set_early_handler handler=early_illegal_opcode,trapno=6
 457         set_early_handler handler=early_protection_fault,trapno=13
 458         set_early_handler handler=early_page_fault,trapno=14
 459
 460         ret
 461
 462 early_divide_err:
 463         xor %edx,%edx
 464         pushl $0        /* fake errcode */
 465         jmp early_fault
 466
 467 early_illegal_opcode:
 468         movl $6,%edx
 469         pushl $0        /* fake errcode */
 470         jmp early_fault
 471
 472 early_protection_fault:
 473         movl $13,%edx
 474         jmp early_fault
 475
 476 early_page_fault:
 477         movl $14,%edx
 478         jmp early_fault
 479
 480 early_fault:
 481         cld
 482 #ifdef CONFIG_PRINTK
 483         pusha
 484         movl $(__KERNEL_DS),%eax
 485         movl %eax,%ds
 486         movl %eax,%es
 487         cmpl $2,early_recursion_flag
 488         je hlt_loop
 489         incl early_recursion_flag
 490         movl %cr2,%eax
 491         pushl %eax
 492         pushl %edx              /* trapno */
 493         pushl $fault_msg
 494 #ifdef CONFIG_EARLY_PRINTK
 495         call early_printk
 496 #else
 497         call printk
 498 #endif
 499 #endif
 500         call dump_stack
 501 hlt_loop:
 502         hlt
 503         jmp hlt_loop
 504
 505 /* This is the default interrupt "handler" :-) */
 506         ALIGN
 507 ignore_int:
 508         cld
 509 #ifdef CONFIG_PRINTK
 510         pushl %eax
 511         pushl %ecx
 512         pushl %edx
 513         pushl %es
 514         pushl %ds
 515         movl $(__KERNEL_DS),%eax
 516         movl %eax,%ds
 517         movl %eax,%es
 518         cmpl $2,early_recursion_flag
 519         je hlt_loop
 520         incl early_recursion_flag
 521         pushl 16(%esp)
 522         pushl 24(%esp)
 523         pushl 32(%esp)
 524         pushl 40(%esp)
 525         pushl $int_msg
 526 #ifdef CONFIG_EARLY_PRINTK
 527         call early_printk
 528 #else
 529         call printk
 530 #endif
 531         addl $(5*4),%esp
 532         popl %ds
 533         popl %es
 534         popl %edx
 535         popl %ecx
 536         popl %eax
 537 #endif
 538         iret
 539
 540 .section .text
 541 /*
 542  * Real beginning of normal "text" segment
 543  */
 544 ENTRY(stext)
 545 ENTRY(_stext)
 546
 547 /*
 548  * BSS section
 549  */
 550 .section ".bss.page_aligned","wa"
 551         .align PAGE_SIZE_asm
 552 ENTRY(swapper_pg_dir)
 553         .fill 1024,4,0
 554 ENTRY(swapper_pg_pmd)
 555         .fill 1024,4,0
 556 ENTRY(empty_zero_page)
 557         .fill 4096,1,0
 558
 559 /*
 560  * This starts the data section.
 561  */
 562 .data
 563 ENTRY(stack_start)
 564         .long init_thread_union+THREAD_SIZE
 565         .long __BOOT_DS
 566
 567 ready:  .byte 0
 568
 569 early_recursion_flag:
 570         .long 0
 571
 572 int_msg:
 573         .asciz "Unknown interrupt or fault at EIP %p %p %p\n"
 574
 575 fault_msg:
 576         .ascii                                                          \
 577 /* fault info: */       "BUG: Int %d: CR2 %p\n"                         \
 578 /* pusha regs: */       "     EDI %p  ESI %p  EBP %p  ESP %p\n"         \
 579                         "     EBX %p  EDX %p  ECX %p  EAX %p\n"         \
 580 /* fault frame: */      "     err %p  EIP %p   CS %p  flg %p\n"         \
 581                                                                         \
 582                         "Stack: %p %p %p %p %p %p %p %p\n"              \
 583                         "       %p %p %p %p %p %p %p %p\n"              \
 584                         "       %p %p %p %p %p %p %p %p\n"
 585
 586 #include "../../x86/xen/xen-head.S"
 587
 588 /*
 589  * The IDT and GDT 'descriptors' are a strange 48-bit object
 590  * only used by the lidt and lgdt instructions. They are not
 591  * like usual segment descriptors - they consist of a 16-bit
 592  * segment size, and 32-bit linear address value:
 593  */
 594
 595 .globl boot_gdt_descr
 596 .globl idt_descr
 597
 598         ALIGN
 599 # early boot GDT descriptor (must use 1:1 address mapping)
 600         .word 0                         # 32 bit align gdt_desc.address
 601 boot_gdt_descr:
 602         .word __BOOT_DS+7
 603         .long boot_gdt - __PAGE_OFFSET
 604
 605         .word 0                         # 32-bit align idt_desc.address
 606 idt_descr:
 607         .word IDT_ENTRIES*8-1           # idt contains 256 entries
 608         .long idt_table
 609
 610 # boot GDT descriptor (later on used by CPU#0):
 611         .word 0                         # 32 bit align gdt_desc.address
 612 ENTRY(early_gdt_descr)
 613         .word GDT_ENTRIES*8-1
 614         .long per_cpu__gdt_page         /* Overwritten for secondary CPUs */
 615
 616 /*
 617  * The boot_gdt must mirror the equivalent in setup.S and is
 618  * used only for booting.
 619  */
 620         .align L1_CACHE_BYTES
 621 ENTRY(boot_gdt)
 622         .fill GDT_ENTRY_BOOT_CS,8,0
 623         .quad 0x00cf9a000000ffff        /* kernel 4GB code at 0x00000000 */
 624         .quad 0x00cf92000000ffff        /* kernel 4GB data at 0x00000000 */