SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page_types.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64 #ifdef CONFIG_FUNCTION_TRACER
  65 #ifdef CONFIG_DYNAMIC_FTRACE
  66 ENTRY(mcount)
  67         retq
  68 END(mcount)
  69
  70 ENTRY(ftrace_caller)
  71         cmpl $0, function_trace_stop
  72         jne  ftrace_stub
  73
  74         MCOUNT_SAVE_FRAME
  75
  76         movq 0x38(%rsp), %rdi
  77         movq 8(%rbp), %rsi
  78         subq $MCOUNT_INSN_SIZE, %rdi
  79
  80 GLOBAL(ftrace_call)
  81         call ftrace_stub
  82
  83         MCOUNT_RESTORE_FRAME
  84
  85 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  86 GLOBAL(ftrace_graph_call)
  87         jmp ftrace_stub
  88 #endif
  89
  90 GLOBAL(ftrace_stub)
  91         retq
  92 END(ftrace_caller)
  93
  94 #else /* ! CONFIG_DYNAMIC_FTRACE */
  95 ENTRY(mcount)
  96         cmpl $0, function_trace_stop
  97         jne  ftrace_stub
  98
  99         cmpq $ftrace_stub, ftrace_trace_function
 100         jnz trace
 101
 102 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 103         cmpq $ftrace_stub, ftrace_graph_return
 104         jnz ftrace_graph_caller
 105
 106         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 107         jnz ftrace_graph_caller
 108 #endif
 109
 110 GLOBAL(ftrace_stub)
 111         retq
 112
 113 trace:
 114         MCOUNT_SAVE_FRAME
 115
 116         movq 0x38(%rsp), %rdi
 117         movq 8(%rbp), %rsi
 118         subq $MCOUNT_INSN_SIZE, %rdi
 119
 120         call   *ftrace_trace_function
 121
 122         MCOUNT_RESTORE_FRAME
 123
 124         jmp ftrace_stub
 125 END(mcount)
 126 #endif /* CONFIG_DYNAMIC_FTRACE */
 127 #endif /* CONFIG_FUNCTION_TRACER */
 128
 129 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 130 ENTRY(ftrace_graph_caller)
 131         cmpl $0, function_trace_stop
 132         jne ftrace_stub
 133
 134         MCOUNT_SAVE_FRAME
 135
 136         leaq 8(%rbp), %rdi
 137         movq 0x38(%rsp), %rsi
 138         subq $MCOUNT_INSN_SIZE, %rsi
 139
 140         call    prepare_ftrace_return
 141
 142         MCOUNT_RESTORE_FRAME
 143
 144         retq
 145 END(ftrace_graph_caller)
 146
 147 GLOBAL(return_to_handler)
 148         subq  $80, %rsp
 149
 150         /* Save the return values */
 151         movq %rax, (%rsp)
 152         movq %rdx, 8(%rsp)
 153
 154         call ftrace_return_to_handler
 155
 156         movq %rax, 72(%rsp)
 157         movq 8(%rsp), %rdx
 158         movq (%rsp), %rax
 159         addq $72, %rsp
 160         retq
 161 #endif
 162
 163
 164 #ifndef CONFIG_PREEMPT
 165 #define retint_kernel retint_restore_args
 166 #endif
 167
 168 #ifdef CONFIG_PARAVIRT
 169 ENTRY(native_usergs_sysret64)
 170         swapgs
 171         sysretq
 172 ENDPROC(native_usergs_sysret64)
 173 #endif /* CONFIG_PARAVIRT */
 174
 175
 176 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 177 #ifdef CONFIG_TRACE_IRQFLAGS
 178         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 179         jnc  1f
 180         TRACE_IRQS_ON
 181 1:
 182 #endif
 183 .endm
 184
 185 /*
 186  * C code is not supposed to know about undefined top of stack. Every time
 187  * a C function with an pt_regs argument is called from the SYSCALL based
 188  * fast path FIXUP_TOP_OF_STACK is needed.
 189  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 190  * manipulation.
 191  */
 192
 193         /* %rsp:at FRAMEEND */
 194         .macro FIXUP_TOP_OF_STACK tmp offset=0
 195         movq PER_CPU_VAR(old_rsp),\tmp
 196         movq \tmp,RSP+\offset(%rsp)
 197         movq $__USER_DS,SS+\offset(%rsp)
 198         movq $__USER_CS,CS+\offset(%rsp)
 199         movq $-1,RCX+\offset(%rsp)
 200         movq R11+\offset(%rsp),\tmp  /* get eflags */
 201         movq \tmp,EFLAGS+\offset(%rsp)
 202         .endm
 203
 204         .macro RESTORE_TOP_OF_STACK tmp offset=0
 205         movq RSP+\offset(%rsp),\tmp
 206         movq \tmp,PER_CPU_VAR(old_rsp)
 207         movq EFLAGS+\offset(%rsp),\tmp
 208         movq \tmp,R11+\offset(%rsp)
 209         .endm
 210
 211         .macro FAKE_STACK_FRAME child_rip
 212         /* push in order ss, rsp, eflags, cs, rip */
 213         xorl %eax, %eax
 214         pushq $__KERNEL_DS /* ss */
 215         CFI_ADJUST_CFA_OFFSET   8
 216         /*CFI_REL_OFFSET        ss,0*/
 217         pushq %rax /* rsp */
 218         CFI_ADJUST_CFA_OFFSET   8
 219         CFI_REL_OFFSET  rsp,0
 220         pushq $X86_EFLAGS_IF /* eflags - interrupts on */
 221         CFI_ADJUST_CFA_OFFSET   8
 222         /*CFI_REL_OFFSET        rflags,0*/
 223         pushq $__KERNEL_CS /* cs */
 224         CFI_ADJUST_CFA_OFFSET   8
 225         /*CFI_REL_OFFSET        cs,0*/
 226         pushq \child_rip /* rip */
 227         CFI_ADJUST_CFA_OFFSET   8
 228         CFI_REL_OFFSET  rip,0
 229         pushq   %rax /* orig rax */
 230         CFI_ADJUST_CFA_OFFSET   8
 231         .endm
 232
 233         .macro UNFAKE_STACK_FRAME
 234         addq $8*6, %rsp
 235         CFI_ADJUST_CFA_OFFSET   -(6*8)
 236         .endm
 237
 238 /*
 239  * initial frame state for interrupts (and exceptions without error code)
 240  */
 241         .macro EMPTY_FRAME start=1 offset=0
 242         .if \start
 243         CFI_STARTPROC simple
 244         CFI_SIGNAL_FRAME
 245         CFI_DEF_CFA rsp,8+\offset
 246         .else
 247         CFI_DEF_CFA_OFFSET 8+\offset
 248         .endif
 249         .endm
 250
 251 /*
 252  * initial frame state for interrupts (and exceptions without error code)
 253  */
 254         .macro INTR_FRAME start=1 offset=0
 255         EMPTY_FRAME \start, SS+8+\offset-RIP
 256         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 257         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 258         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 259         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 260         CFI_REL_OFFSET rip, RIP+\offset-RIP
 261         .endm
 262
 263 /*
 264  * initial frame state for exceptions with error code (and interrupts
 265  * with vector already pushed)
 266  */
 267         .macro XCPT_FRAME start=1 offset=0
 268         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 269         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 270         .endm
 271
 272 /*
 273  * frame that enables calling into C.
 274  */
 275         .macro PARTIAL_FRAME start=1 offset=0
 276         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 277         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 278         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 283         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 286         .endm
 287
 288 /*
 289  * frame that enables passing a complete pt_regs to a C function.
 290  */
 291         .macro DEFAULT_FRAME start=1 offset=0
 292         PARTIAL_FRAME \start, R11+\offset-R15
 293         CFI_REL_OFFSET rbx, RBX+\offset
 294         CFI_REL_OFFSET rbp, RBP+\offset
 295         CFI_REL_OFFSET r12, R12+\offset
 296         CFI_REL_OFFSET r13, R13+\offset
 297         CFI_REL_OFFSET r14, R14+\offset
 298         CFI_REL_OFFSET r15, R15+\offset
 299         .endm
 300
 301 /* save partial stack frame */
 302 ENTRY(save_args)
 303         XCPT_FRAME
 304         cld
 305         movq_cfi rdi, RDI+16-ARGOFFSET
 306         movq_cfi rsi, RSI+16-ARGOFFSET
 307         movq_cfi rdx, RDX+16-ARGOFFSET
 308         movq_cfi rcx, RCX+16-ARGOFFSET
 309         movq_cfi rax, RAX+16-ARGOFFSET
 310         movq_cfi  r8,  R8+16-ARGOFFSET
 311         movq_cfi  r9,  R9+16-ARGOFFSET
 312         movq_cfi r10, R10+16-ARGOFFSET
 313         movq_cfi r11, R11+16-ARGOFFSET
 314
 315         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
 316         movq_cfi rbp, 8         /* push %rbp */
 317         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 318         testl $3, CS(%rdi)
 319         je 1f
 320         SWAPGS
 321         /*
 322          * irq_count is used to check if a CPU is already on an interrupt stack
 323          * or not. While this is essentially redundant with preempt_count it is
 324          * a little cheaper to use a separate counter in the PDA (short of
 325          * moving irq_enter into assembly, which would be too much work)
 326          */
 327 1:      incl PER_CPU_VAR(irq_count)
 328         jne 2f
 329         popq_cfi %rax                   /* move return address... */
 330         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 331         EMPTY_FRAME 0
 332         pushq_cfi %rbp                  /* backlink for unwinder */
 333         pushq_cfi %rax                  /* ... to the new stack */
 334         /*
 335          * We entered an interrupt context - irqs are off:
 336          */
 337 2:      TRACE_IRQS_OFF
 338         ret
 339         CFI_ENDPROC
 340 END(save_args)
 341
 342 ENTRY(save_rest)
 343         PARTIAL_FRAME 1 REST_SKIP+8
 344         movq 5*8+16(%rsp), %r11 /* save return address */
 345         movq_cfi rbx, RBX+16
 346         movq_cfi rbp, RBP+16
 347         movq_cfi r12, R12+16
 348         movq_cfi r13, R13+16
 349         movq_cfi r14, R14+16
 350         movq_cfi r15, R15+16
 351         movq %r11, 8(%rsp)      /* return address */
 352         FIXUP_TOP_OF_STACK %r11, 16
 353         ret
 354         CFI_ENDPROC
 355 END(save_rest)
 356
 357 /* save complete stack frame */
 358         .pushsection .kprobes.text, "ax"
 359 ENTRY(save_paranoid)
 360         XCPT_FRAME 1 RDI+8
 361         cld
 362         movq_cfi rdi, RDI+8
 363         movq_cfi rsi, RSI+8
 364         movq_cfi rdx, RDX+8
 365         movq_cfi rcx, RCX+8
 366         movq_cfi rax, RAX+8
 367         movq_cfi r8, R8+8
 368         movq_cfi r9, R9+8
 369         movq_cfi r10, R10+8
 370         movq_cfi r11, R11+8
 371         movq_cfi rbx, RBX+8
 372         movq_cfi rbp, RBP+8
 373         movq_cfi r12, R12+8
 374         movq_cfi r13, R13+8
 375         movq_cfi r14, R14+8
 376         movq_cfi r15, R15+8
 377         movl $1,%ebx
 378         movl $MSR_GS_BASE,%ecx
 379         rdmsr
 380         testl %edx,%edx
 381         js 1f   /* negative -> in kernel */
 382         SWAPGS
 383         xorl %ebx,%ebx
 384 1:      ret
 385         CFI_ENDPROC
 386 END(save_paranoid)
 387         .popsection
 388
 389 /*
 390  * A newly forked process directly context switches into this address.
 391  *
 392  * rdi: prev task we switched from
 393  */
 394 ENTRY(ret_from_fork)
 395         DEFAULT_FRAME
 396
 397         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 398
 399         push kernel_eflags(%rip)
 400         CFI_ADJUST_CFA_OFFSET 8
 401         popf                                    # reset kernel eflags
 402         CFI_ADJUST_CFA_OFFSET -8
 403
 404         call schedule_tail                      # rdi: 'prev' task parameter
 405
 406         GET_THREAD_INFO(%rcx)
 407
 408         RESTORE_REST
 409
 410         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 411         je   int_ret_from_sys_call
 412
 413         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 414         jnz  int_ret_from_sys_call
 415
 416         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 417         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 418
 419         CFI_ENDPROC
 420 END(ret_from_fork)
 421
 422 /*
 423  * System call entry. Upto 6 arguments in registers are supported.
 424  *
 425  * SYSCALL does not save anything on the stack and does not change the
 426  * stack pointer.
 427  */
 428
 429 /*
 430  * Register setup:
 431  * rax  system call number
 432  * rdi  arg0
 433  * rcx  return address for syscall/sysret, C arg3
 434  * rsi  arg1
 435  * rdx  arg2
 436  * r10  arg3    (--> moved to rcx for C)
 437  * r8   arg4
 438  * r9   arg5
 439  * r11  eflags for syscall/sysret, temporary for C
 440  * r12-r15,rbp,rbx saved by C code, not touched.
 441  *
 442  * Interrupts are off on entry.
 443  * Only called from user space.
 444  *
 445  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 446  *      and report it properly in ps. Unfortunately we haven't.
 447  *
 448  * When user can change the frames always force IRET. That is because
 449  * it deals with uncanonical addresses better. SYSRET has trouble
 450  * with them due to bugs in both AMD and Intel CPUs.
 451  */
 452
 453 ENTRY(system_call)
 454         CFI_STARTPROC   simple
 455         CFI_SIGNAL_FRAME
 456         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 457         CFI_REGISTER    rip,rcx
 458         /*CFI_REGISTER  rflags,r11*/
 459         SWAPGS_UNSAFE_STACK
 460         /*
 461          * A hypervisor implementation might want to use a label
 462          * after the swapgs, so that it can do the swapgs
 463          * for the guest and jump here on syscall.
 464          */
 465 ENTRY(system_call_after_swapgs)
 466
 467         movq    %rsp,PER_CPU_VAR(old_rsp)
 468         movq    PER_CPU_VAR(kernel_stack),%rsp
 469         /*
 470          * No need to follow this irqs off/on section - it's straight
 471          * and short:
 472          */
 473         ENABLE_INTERRUPTS(CLBR_NONE)
 474         SAVE_ARGS 8,1
 475         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 476         movq  %rcx,RIP-ARGOFFSET(%rsp)
 477         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 478         GET_THREAD_INFO(%rcx)
 479         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 480         jnz tracesys
 481 system_call_fastpath:
 482         cmpq $__NR_syscall_max,%rax
 483         ja badsys
 484         movq %r10,%rcx
 485         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 486         movq %rax,RAX-ARGOFFSET(%rsp)
 487 /*
 488  * Syscall return path ending with SYSRET (fast path)
 489  * Has incomplete stack frame and undefined top of stack.
 490  */
 491 ret_from_sys_call:
 492         movl $_TIF_ALLWORK_MASK,%edi
 493         /* edi: flagmask */
 494 sysret_check:
 495         LOCKDEP_SYS_EXIT
 496         GET_THREAD_INFO(%rcx)
 497         DISABLE_INTERRUPTS(CLBR_NONE)
 498         TRACE_IRQS_OFF
 499         movl TI_flags(%rcx),%edx
 500         andl %edi,%edx
 501         jnz  sysret_careful
 502         CFI_REMEMBER_STATE
 503         /*
 504          * sysretq will re-enable interrupts:
 505          */
 506         TRACE_IRQS_ON
 507         movq RIP-ARGOFFSET(%rsp),%rcx
 508         CFI_REGISTER    rip,rcx
 509         RESTORE_ARGS 0,-ARG_SKIP,1
 510         /*CFI_REGISTER  rflags,r11*/
 511         movq    PER_CPU_VAR(old_rsp), %rsp
 512         USERGS_SYSRET64
 513
 514         CFI_RESTORE_STATE
 515         /* Handle reschedules */
 516         /* edx: work, edi: workmask */
 517 sysret_careful:
 518         bt $TIF_NEED_RESCHED,%edx
 519         jnc sysret_signal
 520         TRACE_IRQS_ON
 521         ENABLE_INTERRUPTS(CLBR_NONE)
 522         pushq %rdi
 523         CFI_ADJUST_CFA_OFFSET 8
 524         call schedule
 525         popq  %rdi
 526         CFI_ADJUST_CFA_OFFSET -8
 527         jmp sysret_check
 528
 529         /* Handle a signal */
 530 sysret_signal:
 531         TRACE_IRQS_ON
 532         ENABLE_INTERRUPTS(CLBR_NONE)
 533 #ifdef CONFIG_AUDITSYSCALL
 534         bt $TIF_SYSCALL_AUDIT,%edx
 535         jc sysret_audit
 536 #endif
 537         /* edx: work flags (arg3) */
 538         leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
 539         xorl %esi,%esi # oldset -> arg2
 540         SAVE_REST
 541         FIXUP_TOP_OF_STACK %r11
 542         call do_notify_resume
 543         RESTORE_TOP_OF_STACK %r11
 544         RESTORE_REST
 545         movl $_TIF_WORK_MASK,%edi
 546         /* Use IRET because user could have changed frame. This
 547            works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
 548         DISABLE_INTERRUPTS(CLBR_NONE)
 549         TRACE_IRQS_OFF
 550         jmp int_with_check
 551
 552 badsys:
 553         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 554         jmp ret_from_sys_call
 555
 556 #ifdef CONFIG_AUDITSYSCALL
 557         /*
 558          * Fast path for syscall audit without full syscall trace.
 559          * We just call audit_syscall_entry() directly, and then
 560          * jump back to the normal fast path.
 561          */
 562 auditsys:
 563         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 564         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 565         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 566         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 567         movq %rax,%rsi                  /* 2nd arg: syscall number */
 568         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 569         call audit_syscall_entry
 570         LOAD_ARGS 0             /* reload call-clobbered registers */
 571         jmp system_call_fastpath
 572
 573         /*
 574          * Return fast path for syscall audit.  Call audit_syscall_exit()
 575          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 576          * masked off.
 577          */
 578 sysret_audit:
 579         movq %rax,%rsi          /* second arg, syscall return value */
 580         cmpq $0,%rax            /* is it < 0? */
 581         setl %al                /* 1 if so, 0 if not */
 582         movzbl %al,%edi         /* zero-extend that into %edi */
 583         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 584         call audit_syscall_exit
 585         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 586         jmp sysret_check
 587 #endif  /* CONFIG_AUDITSYSCALL */
 588
 589         /* Do syscall tracing */
 590 tracesys:
 591 #ifdef CONFIG_AUDITSYSCALL
 592         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 593         jz auditsys
 594 #endif
 595         SAVE_REST
 596         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 597         FIXUP_TOP_OF_STACK %rdi
 598         movq %rsp,%rdi
 599         call syscall_trace_enter
 600         /*
 601          * Reload arg registers from stack in case ptrace changed them.
 602          * We don't reload %rax because syscall_trace_enter() returned
 603          * the value it wants us to use in the table lookup.
 604          */
 605         LOAD_ARGS ARGOFFSET, 1
 606         RESTORE_REST
 607         cmpq $__NR_syscall_max,%rax
 608         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 609         movq %r10,%rcx  /* fixup for C */
 610         call *sys_call_table(,%rax,8)
 611         movq %rax,RAX-ARGOFFSET(%rsp)
 612         /* Use IRET because user could have changed frame */
 613
 614 /*
 615  * Syscall return path ending with IRET.
 616  * Has correct top of stack, but partial stack frame.
 617  */
 618 GLOBAL(int_ret_from_sys_call)
 619         DISABLE_INTERRUPTS(CLBR_NONE)
 620         TRACE_IRQS_OFF
 621         testl $3,CS-ARGOFFSET(%rsp)
 622         je retint_restore_args
 623         movl $_TIF_ALLWORK_MASK,%edi
 624         /* edi: mask to check */
 625 GLOBAL(int_with_check)
 626         LOCKDEP_SYS_EXIT_IRQ
 627         GET_THREAD_INFO(%rcx)
 628         movl TI_flags(%rcx),%edx
 629         andl %edi,%edx
 630         jnz   int_careful
 631         andl    $~TS_COMPAT,TI_status(%rcx)
 632         jmp   retint_swapgs
 633
 634         /* Either reschedule or signal or syscall exit tracking needed. */
 635         /* First do a reschedule test. */
 636         /* edx: work, edi: workmask */
 637 int_careful:
 638         bt $TIF_NEED_RESCHED,%edx
 639         jnc  int_very_careful
 640         TRACE_IRQS_ON
 641         ENABLE_INTERRUPTS(CLBR_NONE)
 642         pushq %rdi
 643         CFI_ADJUST_CFA_OFFSET 8
 644         call schedule
 645         popq %rdi
 646         CFI_ADJUST_CFA_OFFSET -8
 647         DISABLE_INTERRUPTS(CLBR_NONE)
 648         TRACE_IRQS_OFF
 649         jmp int_with_check
 650
 651         /* handle signals and tracing -- both require a full stack frame */
 652 int_very_careful:
 653         TRACE_IRQS_ON
 654         ENABLE_INTERRUPTS(CLBR_NONE)
 655         SAVE_REST
 656         /* Check for syscall exit trace */
 657         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 658         jz int_signal
 659         pushq %rdi
 660         CFI_ADJUST_CFA_OFFSET 8
 661         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 662         call syscall_trace_leave
 663         popq %rdi
 664         CFI_ADJUST_CFA_OFFSET -8
 665         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 666         jmp int_restore_rest
 667
 668 int_signal:
 669         testl $_TIF_DO_NOTIFY_MASK,%edx
 670         jz 1f
 671         movq %rsp,%rdi          # &ptregs -> arg1
 672         xorl %esi,%esi          # oldset -> arg2
 673         call do_notify_resume
 674 1:      movl $_TIF_WORK_MASK,%edi
 675 int_restore_rest:
 676         RESTORE_REST
 677         DISABLE_INTERRUPTS(CLBR_NONE)
 678         TRACE_IRQS_OFF
 679         jmp int_with_check
 680         CFI_ENDPROC
 681 END(system_call)
 682
 683 /*
 684  * Certain special system calls that need to save a complete full stack frame.
 685  */
 686         .macro PTREGSCALL label,func,arg
 687 ENTRY(\label)
 688         PARTIAL_FRAME 1 8               /* offset 8: return address */
 689         subq $REST_SKIP, %rsp
 690         CFI_ADJUST_CFA_OFFSET REST_SKIP
 691         call save_rest
 692         DEFAULT_FRAME 0 8               /* offset 8: return address */
 693         leaq 8(%rsp), \arg      /* pt_regs pointer */
 694         call \func
 695         jmp ptregscall_common
 696         CFI_ENDPROC
 697 END(\label)
 698         .endm
 699
 700         PTREGSCALL stub_clone, sys_clone, %r8
 701         PTREGSCALL stub_fork, sys_fork, %rdi
 702         PTREGSCALL stub_vfork, sys_vfork, %rdi
 703         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 704         PTREGSCALL stub_iopl, sys_iopl, %rsi
 705
 706 ENTRY(ptregscall_common)
 707         DEFAULT_FRAME 1 8       /* offset 8: return address */
 708         RESTORE_TOP_OF_STACK %r11, 8
 709         movq_cfi_restore R15+8, r15
 710         movq_cfi_restore R14+8, r14
 711         movq_cfi_restore R13+8, r13
 712         movq_cfi_restore R12+8, r12
 713         movq_cfi_restore RBP+8, rbp
 714         movq_cfi_restore RBX+8, rbx
 715         ret $REST_SKIP          /* pop extended registers */
 716         CFI_ENDPROC
 717 END(ptregscall_common)
 718
 719 ENTRY(stub_execve)
 720         CFI_STARTPROC
 721         popq %r11
 722         CFI_ADJUST_CFA_OFFSET -8
 723         CFI_REGISTER rip, r11
 724         SAVE_REST
 725         FIXUP_TOP_OF_STACK %r11
 726         movq %rsp, %rcx
 727         call sys_execve
 728         RESTORE_TOP_OF_STACK %r11
 729         movq %rax,RAX(%rsp)
 730         RESTORE_REST
 731         jmp int_ret_from_sys_call
 732         CFI_ENDPROC
 733 END(stub_execve)
 734
 735 /*
 736  * sigreturn is special because it needs to restore all registers on return.
 737  * This cannot be done with SYSRET, so use the IRET return path instead.
 738  */
 739 ENTRY(stub_rt_sigreturn)
 740         CFI_STARTPROC
 741         addq $8, %rsp
 742         CFI_ADJUST_CFA_OFFSET   -8
 743         SAVE_REST
 744         movq %rsp,%rdi
 745         FIXUP_TOP_OF_STACK %r11
 746         call sys_rt_sigreturn
 747         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 748         RESTORE_REST
 749         jmp int_ret_from_sys_call
 750         CFI_ENDPROC
 751 END(stub_rt_sigreturn)
 752
 753 /*
 754  * Build the entry stubs and pointer table with some assembler magic.
 755  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 756  * single cache line on all modern x86 implementations.
 757  */
 758         .section .init.rodata,"a"
 759 ENTRY(interrupt)
 760         .text
 761         .p2align 5
 762         .p2align CONFIG_X86_L1_CACHE_SHIFT
 763 ENTRY(irq_entries_start)
 764         INTR_FRAME
 765 vector=FIRST_EXTERNAL_VECTOR
 766 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 767         .balign 32
 768   .rept 7
 769     .if vector < NR_VECTORS
 770       .if vector <> FIRST_EXTERNAL_VECTOR
 771         CFI_ADJUST_CFA_OFFSET -8
 772       .endif
 773 1:      pushq $(~vector+0x80)   /* Note: always in signed byte range */
 774         CFI_ADJUST_CFA_OFFSET 8
 775       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 776         jmp 2f
 777       .endif
 778       .previous
 779         .quad 1b
 780       .text
 781 vector=vector+1
 782     .endif
 783   .endr
 784 2:      jmp common_interrupt
 785 .endr
 786         CFI_ENDPROC
 787 END(irq_entries_start)
 788
 789 .previous
 790 END(interrupt)
 791 .previous
 792
 793 /*
 794  * Interrupt entry/exit.
 795  *
 796  * Interrupt entry points save only callee clobbered registers in fast path.
 797  *
 798  * Entry runs with interrupts off.
 799  */
 800
 801 /* 0(%rsp): ~(interrupt number) */
 802         .macro interrupt func
 803         subq $10*8, %rsp
 804         CFI_ADJUST_CFA_OFFSET 10*8
 805         call save_args
 806         PARTIAL_FRAME 0
 807         call \func
 808         .endm
 809
 810         /*
 811          * The interrupt stubs push (~vector+0x80) onto the stack and
 812          * then jump to common_interrupt.
 813          */
 814         .p2align CONFIG_X86_L1_CACHE_SHIFT
 815 common_interrupt:
 816         XCPT_FRAME
 817         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 818         interrupt do_IRQ
 819         /* 0(%rsp): old_rsp-ARGOFFSET */
 820 ret_from_intr:
 821         DISABLE_INTERRUPTS(CLBR_NONE)
 822         TRACE_IRQS_OFF
 823         decl PER_CPU_VAR(irq_count)
 824         leaveq
 825         CFI_DEF_CFA_REGISTER    rsp
 826         CFI_ADJUST_CFA_OFFSET   -8
 827 exit_intr:
 828         GET_THREAD_INFO(%rcx)
 829         testl $3,CS-ARGOFFSET(%rsp)
 830         je retint_kernel
 831
 832         /* Interrupt came from user space */
 833         /*
 834          * Has a correct top of stack, but a partial stack frame
 835          * %rcx: thread info. Interrupts off.
 836          */
 837 retint_with_reschedule:
 838         movl $_TIF_WORK_MASK,%edi
 839 retint_check:
 840         LOCKDEP_SYS_EXIT_IRQ
 841         movl TI_flags(%rcx),%edx
 842         andl %edi,%edx
 843         CFI_REMEMBER_STATE
 844         jnz  retint_careful
 845
 846 retint_swapgs:          /* return to user-space */
 847         /*
 848          * The iretq could re-enable interrupts:
 849          */
 850         DISABLE_INTERRUPTS(CLBR_ANY)
 851         TRACE_IRQS_IRETQ
 852         SWAPGS
 853         jmp restore_args
 854
 855 retint_restore_args:    /* return to kernel space */
 856         DISABLE_INTERRUPTS(CLBR_ANY)
 857         /*
 858          * The iretq could re-enable interrupts:
 859          */
 860         TRACE_IRQS_IRETQ
 861 restore_args:
 862         RESTORE_ARGS 0,8,0
 863
 864 irq_return:
 865         INTERRUPT_RETURN
 866
 867         .section __ex_table, "a"
 868         .quad irq_return, bad_iret
 869         .previous
 870
 871 #ifdef CONFIG_PARAVIRT
 872 ENTRY(native_iret)
 873         iretq
 874
 875         .section __ex_table,"a"
 876         .quad native_iret, bad_iret
 877         .previous
 878 #endif
 879
 880         .section .fixup,"ax"
 881 bad_iret:
 882         /*
 883          * The iret traps when the %cs or %ss being restored is bogus.
 884          * We've lost the original trap vector and error code.
 885          * #GPF is the most likely one to get for an invalid selector.
 886          * So pretend we completed the iret and took the #GPF in user mode.
 887          *
 888          * We are now running with the kernel GS after exception recovery.
 889          * But error_entry expects us to have user GS to match the user %cs,
 890          * so swap back.
 891          */
 892         pushq $0
 893
 894         SWAPGS
 895         jmp general_protection
 896
 897         .previous
 898
 899         /* edi: workmask, edx: work */
 900 retint_careful:
 901         CFI_RESTORE_STATE
 902         bt    $TIF_NEED_RESCHED,%edx
 903         jnc   retint_signal
 904         TRACE_IRQS_ON
 905         ENABLE_INTERRUPTS(CLBR_NONE)
 906         pushq %rdi
 907         CFI_ADJUST_CFA_OFFSET   8
 908         call  schedule
 909         popq %rdi
 910         CFI_ADJUST_CFA_OFFSET   -8
 911         GET_THREAD_INFO(%rcx)
 912         DISABLE_INTERRUPTS(CLBR_NONE)
 913         TRACE_IRQS_OFF
 914         jmp retint_check
 915
 916 retint_signal:
 917         testl $_TIF_DO_NOTIFY_MASK,%edx
 918         jz    retint_swapgs
 919         TRACE_IRQS_ON
 920         ENABLE_INTERRUPTS(CLBR_NONE)
 921         SAVE_REST
 922         movq $-1,ORIG_RAX(%rsp)
 923         xorl %esi,%esi          # oldset
 924         movq %rsp,%rdi          # &pt_regs
 925         call do_notify_resume
 926         RESTORE_REST
 927         DISABLE_INTERRUPTS(CLBR_NONE)
 928         TRACE_IRQS_OFF
 929         GET_THREAD_INFO(%rcx)
 930         jmp retint_with_reschedule
 931
 932 #ifdef CONFIG_PREEMPT
 933         /* Returning to kernel space. Check if we need preemption */
 934         /* rcx:  threadinfo. interrupts off. */
 935 ENTRY(retint_kernel)
 936         cmpl $0,TI_preempt_count(%rcx)
 937         jnz  retint_restore_args
 938         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 939         jnc  retint_restore_args
 940         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 941         jnc  retint_restore_args
 942         call preempt_schedule_irq
 943         jmp exit_intr
 944 #endif
 945
 946         CFI_ENDPROC
 947 END(common_interrupt)
 948
 949 /*
 950  * APIC interrupts.
 951  */
 952 .macro apicinterrupt num sym do_sym
 953 ENTRY(\sym)
 954         INTR_FRAME
 955         pushq $~(\num)
 956         CFI_ADJUST_CFA_OFFSET 8
 957         interrupt \do_sym
 958         jmp ret_from_intr
 959         CFI_ENDPROC
 960 END(\sym)
 961 .endm
 962
 963 #ifdef CONFIG_SMP
 964 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 965         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 966 #endif
 967
 968 #ifdef CONFIG_X86_UV
 969 apicinterrupt UV_BAU_MESSAGE \
 970         uv_bau_message_intr1 uv_bau_message_interrupt
 971 #endif
 972 apicinterrupt LOCAL_TIMER_VECTOR \
 973         apic_timer_interrupt smp_apic_timer_interrupt
 974 apicinterrupt GENERIC_INTERRUPT_VECTOR \
 975         generic_interrupt smp_generic_interrupt
 976
 977 #ifdef CONFIG_SMP
 978 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
 979         invalidate_interrupt0 smp_invalidate_interrupt
 980 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
 981         invalidate_interrupt1 smp_invalidate_interrupt
 982 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
 983         invalidate_interrupt2 smp_invalidate_interrupt
 984 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
 985         invalidate_interrupt3 smp_invalidate_interrupt
 986 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
 987         invalidate_interrupt4 smp_invalidate_interrupt
 988 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
 989         invalidate_interrupt5 smp_invalidate_interrupt
 990 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
 991         invalidate_interrupt6 smp_invalidate_interrupt
 992 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
 993         invalidate_interrupt7 smp_invalidate_interrupt
 994 #endif
 995
 996 apicinterrupt THRESHOLD_APIC_VECTOR \
 997         threshold_interrupt mce_threshold_interrupt
 998 apicinterrupt THERMAL_APIC_VECTOR \
 999         thermal_interrupt smp_thermal_interrupt
1000
1001 #ifdef CONFIG_SMP
1002 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1003         call_function_single_interrupt smp_call_function_single_interrupt
1004 apicinterrupt CALL_FUNCTION_VECTOR \
1005         call_function_interrupt smp_call_function_interrupt
1006 apicinterrupt RESCHEDULE_VECTOR \
1007         reschedule_interrupt smp_reschedule_interrupt
1008 #endif
1009
1010 apicinterrupt ERROR_APIC_VECTOR \
1011         error_interrupt smp_error_interrupt
1012 apicinterrupt SPURIOUS_APIC_VECTOR \
1013         spurious_interrupt smp_spurious_interrupt
1014
1015 /*
1016  * Exception entry points.
1017  */
1018 .macro zeroentry sym do_sym
1019 ENTRY(\sym)
1020         INTR_FRAME
1021         PARAVIRT_ADJUST_EXCEPTION_FRAME
1022         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1023         subq $15*8,%rsp
1024         CFI_ADJUST_CFA_OFFSET 15*8
1025         call error_entry
1026         DEFAULT_FRAME 0
1027         movq %rsp,%rdi          /* pt_regs pointer */
1028         xorl %esi,%esi          /* no error code */
1029         call \do_sym
1030         jmp error_exit          /* %ebx: no swapgs flag */
1031         CFI_ENDPROC
1032 END(\sym)
1033 .endm
1034
1035 .macro paranoidzeroentry sym do_sym
1036 ENTRY(\sym)
1037         INTR_FRAME
1038         PARAVIRT_ADJUST_EXCEPTION_FRAME
1039         pushq $-1               /* ORIG_RAX: no syscall to restart */
1040         CFI_ADJUST_CFA_OFFSET 8
1041         subq $15*8, %rsp
1042         call save_paranoid
1043         TRACE_IRQS_OFF
1044         movq %rsp,%rdi          /* pt_regs pointer */
1045         xorl %esi,%esi          /* no error code */
1046         call \do_sym
1047         jmp paranoid_exit       /* %ebx: no swapgs flag */
1048         CFI_ENDPROC
1049 END(\sym)
1050 .endm
1051
1052 .macro paranoidzeroentry_ist sym do_sym ist
1053 ENTRY(\sym)
1054         INTR_FRAME
1055         PARAVIRT_ADJUST_EXCEPTION_FRAME
1056         pushq $-1               /* ORIG_RAX: no syscall to restart */
1057         CFI_ADJUST_CFA_OFFSET 8
1058         subq $15*8, %rsp
1059         call save_paranoid
1060         TRACE_IRQS_OFF
1061         movq %rsp,%rdi          /* pt_regs pointer */
1062         xorl %esi,%esi          /* no error code */
1063         PER_CPU(init_tss, %rbp)
1064         subq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1065         call \do_sym
1066         addq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1067         jmp paranoid_exit       /* %ebx: no swapgs flag */
1068         CFI_ENDPROC
1069 END(\sym)
1070 .endm
1071
1072 .macro errorentry sym do_sym
1073 ENTRY(\sym)
1074         XCPT_FRAME
1075         PARAVIRT_ADJUST_EXCEPTION_FRAME
1076         subq $15*8,%rsp
1077         CFI_ADJUST_CFA_OFFSET 15*8
1078         call error_entry
1079         DEFAULT_FRAME 0
1080         movq %rsp,%rdi                  /* pt_regs pointer */
1081         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1082         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1083         call \do_sym
1084         jmp error_exit                  /* %ebx: no swapgs flag */
1085         CFI_ENDPROC
1086 END(\sym)
1087 .endm
1088
1089         /* error code is on the stack already */
1090 .macro paranoiderrorentry sym do_sym
1091 ENTRY(\sym)
1092         XCPT_FRAME
1093         PARAVIRT_ADJUST_EXCEPTION_FRAME
1094         subq $15*8,%rsp
1095         CFI_ADJUST_CFA_OFFSET 15*8
1096         call save_paranoid
1097         DEFAULT_FRAME 0
1098         TRACE_IRQS_OFF
1099         movq %rsp,%rdi                  /* pt_regs pointer */
1100         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1101         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1102         call \do_sym
1103         jmp paranoid_exit               /* %ebx: no swapgs flag */
1104         CFI_ENDPROC
1105 END(\sym)
1106 .endm
1107
1108 zeroentry divide_error do_divide_error
1109 zeroentry overflow do_overflow
1110 zeroentry bounds do_bounds
1111 zeroentry invalid_op do_invalid_op
1112 zeroentry device_not_available do_device_not_available
1113 paranoiderrorentry double_fault do_double_fault
1114 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1115 errorentry invalid_TSS do_invalid_TSS
1116 errorentry segment_not_present do_segment_not_present
1117 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1118 zeroentry coprocessor_error do_coprocessor_error
1119 errorentry alignment_check do_alignment_check
1120 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1121
1122         /* Reload gs selector with exception handling */
1123         /* edi:  new selector */
1124 ENTRY(native_load_gs_index)
1125         CFI_STARTPROC
1126         pushf
1127         CFI_ADJUST_CFA_OFFSET 8
1128         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1129         SWAPGS
1130 gs_change:
1131         movl %edi,%gs
1132 2:      mfence          /* workaround */
1133         SWAPGS
1134         popf
1135         CFI_ADJUST_CFA_OFFSET -8
1136         ret
1137         CFI_ENDPROC
1138 END(native_load_gs_index)
1139
1140         .section __ex_table,"a"
1141         .align 8
1142         .quad gs_change,bad_gs
1143         .previous
1144         .section .fixup,"ax"
1145         /* running with kernelgs */
1146 bad_gs:
1147         SWAPGS                  /* switch back to user gs */
1148         xorl %eax,%eax
1149         movl %eax,%gs
1150         jmp  2b
1151         .previous
1152
1153 /*
1154  * Create a kernel thread.
1155  *
1156  * C extern interface:
1157  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1158  *
1159  * asm input arguments:
1160  *      rdi: fn, rsi: arg, rdx: flags
1161  */
1162 ENTRY(kernel_thread)
1163         CFI_STARTPROC
1164         FAKE_STACK_FRAME $child_rip
1165         SAVE_ALL
1166
1167         # rdi: flags, rsi: usp, rdx: will be &pt_regs
1168         movq %rdx,%rdi
1169         orq  kernel_thread_flags(%rip),%rdi
1170         movq $-1, %rsi
1171         movq %rsp, %rdx
1172
1173         xorl %r8d,%r8d
1174         xorl %r9d,%r9d
1175
1176         # clone now
1177         call do_fork
1178         movq %rax,RAX(%rsp)
1179         xorl %edi,%edi
1180
1181         /*
1182          * It isn't worth to check for reschedule here,
1183          * so internally to the x86_64 port you can rely on kernel_thread()
1184          * not to reschedule the child before returning, this avoids the need
1185          * of hacks for example to fork off the per-CPU idle tasks.
1186          * [Hopefully no generic code relies on the reschedule -AK]
1187          */
1188         RESTORE_ALL
1189         UNFAKE_STACK_FRAME
1190         ret
1191         CFI_ENDPROC
1192 END(kernel_thread)
1193
1194 ENTRY(child_rip)
1195         pushq $0                # fake return address
1196         CFI_STARTPROC
1197         /*
1198          * Here we are in the child and the registers are set as they were
1199          * at kernel_thread() invocation in the parent.
1200          */
1201         movq %rdi, %rax
1202         movq %rsi, %rdi
1203         call *%rax
1204         # exit
1205         mov %eax, %edi
1206         call do_exit
1207         ud2                     # padding for call trace
1208         CFI_ENDPROC
1209 END(child_rip)
1210
1211 /*
1212  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1213  *
1214  * C extern interface:
1215  *       extern long execve(char *name, char **argv, char **envp)
1216  *
1217  * asm input arguments:
1218  *      rdi: name, rsi: argv, rdx: envp
1219  *
1220  * We want to fallback into:
1221  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1222  *
1223  * do_sys_execve asm fallback arguments:
1224  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1225  */
1226 ENTRY(kernel_execve)
1227         CFI_STARTPROC
1228         FAKE_STACK_FRAME $0
1229         SAVE_ALL
1230         movq %rsp,%rcx
1231         call sys_execve
1232         movq %rax, RAX(%rsp)
1233         RESTORE_REST
1234         testq %rax,%rax
1235         je int_ret_from_sys_call
1236         RESTORE_ARGS
1237         UNFAKE_STACK_FRAME
1238         ret
1239         CFI_ENDPROC
1240 END(kernel_execve)
1241
1242 /* Call softirq on interrupt stack. Interrupts are off. */
1243 ENTRY(call_softirq)
1244         CFI_STARTPROC
1245         push %rbp
1246         CFI_ADJUST_CFA_OFFSET   8
1247         CFI_REL_OFFSET rbp,0
1248         mov  %rsp,%rbp
1249         CFI_DEF_CFA_REGISTER rbp
1250         incl PER_CPU_VAR(irq_count)
1251         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1252         push  %rbp                      # backlink for old unwinder
1253         call __do_softirq
1254         leaveq
1255         CFI_DEF_CFA_REGISTER    rsp
1256         CFI_ADJUST_CFA_OFFSET   -8
1257         decl PER_CPU_VAR(irq_count)
1258         ret
1259         CFI_ENDPROC
1260 END(call_softirq)
1261
1262 #ifdef CONFIG_XEN
1263 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1264
1265 /*
1266  * A note on the "critical region" in our callback handler.
1267  * We want to avoid stacking callback handlers due to events occurring
1268  * during handling of the last event. To do this, we keep events disabled
1269  * until we've done all processing. HOWEVER, we must enable events before
1270  * popping the stack frame (can't be done atomically) and so it would still
1271  * be possible to get enough handler activations to overflow the stack.
1272  * Although unlikely, bugs of that kind are hard to track down, so we'd
1273  * like to avoid the possibility.
1274  * So, on entry to the handler we detect whether we interrupted an
1275  * existing activation in its critical region -- if so, we pop the current
1276  * activation and restart the handler using the previous one.
1277  */
1278 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1279         CFI_STARTPROC
1280 /*
1281  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1282  * see the correct pointer to the pt_regs
1283  */
1284         movq %rdi, %rsp            # we don't return, adjust the stack frame
1285         CFI_ENDPROC
1286         DEFAULT_FRAME
1287 11:     incl PER_CPU_VAR(irq_count)
1288         movq %rsp,%rbp
1289         CFI_DEF_CFA_REGISTER rbp
1290         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1291         pushq %rbp                      # backlink for old unwinder
1292         call xen_evtchn_do_upcall
1293         popq %rsp
1294         CFI_DEF_CFA_REGISTER rsp
1295         decl PER_CPU_VAR(irq_count)
1296         jmp  error_exit
1297         CFI_ENDPROC
1298 END(do_hypervisor_callback)
1299
1300 /*
1301  * Hypervisor uses this for application faults while it executes.
1302  * We get here for two reasons:
1303  *  1. Fault while reloading DS, ES, FS or GS
1304  *  2. Fault while executing IRET
1305  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1306  * registers that could be reloaded and zeroed the others.
1307  * Category 2 we fix up by killing the current process. We cannot use the
1308  * normal Linux return path in this case because if we use the IRET hypercall
1309  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1310  * We distinguish between categories by comparing each saved segment register
1311  * with its current contents: any discrepancy means we in category 1.
1312  */
1313 ENTRY(xen_failsafe_callback)
1314         INTR_FRAME 1 (6*8)
1315         /*CFI_REL_OFFSET gs,GS*/
1316         /*CFI_REL_OFFSET fs,FS*/
1317         /*CFI_REL_OFFSET es,ES*/
1318         /*CFI_REL_OFFSET ds,DS*/
1319         CFI_REL_OFFSET r11,8
1320         CFI_REL_OFFSET rcx,0
1321         movw %ds,%cx
1322         cmpw %cx,0x10(%rsp)
1323         CFI_REMEMBER_STATE
1324         jne 1f
1325         movw %es,%cx
1326         cmpw %cx,0x18(%rsp)
1327         jne 1f
1328         movw %fs,%cx
1329         cmpw %cx,0x20(%rsp)
1330         jne 1f
1331         movw %gs,%cx
1332         cmpw %cx,0x28(%rsp)
1333         jne 1f
1334         /* All segments match their saved values => Category 2 (Bad IRET). */
1335         movq (%rsp),%rcx
1336         CFI_RESTORE rcx
1337         movq 8(%rsp),%r11
1338         CFI_RESTORE r11
1339         addq $0x30,%rsp
1340         CFI_ADJUST_CFA_OFFSET -0x30
1341         pushq_cfi $0    /* RIP */
1342         pushq_cfi %r11
1343         pushq_cfi %rcx
1344         jmp general_protection
1345         CFI_RESTORE_STATE
1346 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1347         movq (%rsp),%rcx
1348         CFI_RESTORE rcx
1349         movq 8(%rsp),%r11
1350         CFI_RESTORE r11
1351         addq $0x30,%rsp
1352         CFI_ADJUST_CFA_OFFSET -0x30
1353         pushq_cfi $0
1354         SAVE_ALL
1355         jmp error_exit
1356         CFI_ENDPROC
1357 END(xen_failsafe_callback)
1358
1359 #endif /* CONFIG_XEN */
1360
1361 /*
1362  * Some functions should be protected against kprobes
1363  */
1364         .pushsection .kprobes.text, "ax"
1365
1366 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1367 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1368 paranoiderrorentry stack_segment do_stack_segment
1369 #ifdef CONFIG_XEN
1370 zeroentry xen_debug do_debug
1371 zeroentry xen_int3 do_int3
1372 errorentry xen_stack_segment do_stack_segment
1373 #endif
1374 errorentry general_protection do_general_protection
1375 errorentry page_fault do_page_fault
1376 #ifdef CONFIG_X86_MCE
1377 paranoidzeroentry machine_check do_machine_check
1378 #endif
1379
1380         /*
1381          * "Paranoid" exit path from exception stack.
1382          * Paranoid because this is used by NMIs and cannot take
1383          * any kernel state for granted.
1384          * We don't do kernel preemption checks here, because only
1385          * NMI should be common and it does not enable IRQs and
1386          * cannot get reschedule ticks.
1387          *
1388          * "trace" is 0 for the NMI handler only, because irq-tracing
1389          * is fundamentally NMI-unsafe. (we cannot change the soft and
1390          * hard flags at once, atomically)
1391          */
1392
1393         /* ebx: no swapgs flag */
1394 ENTRY(paranoid_exit)
1395         INTR_FRAME
1396         DISABLE_INTERRUPTS(CLBR_NONE)
1397         TRACE_IRQS_OFF
1398         testl %ebx,%ebx                         /* swapgs needed? */
1399         jnz paranoid_restore
1400         testl $3,CS(%rsp)
1401         jnz   paranoid_userspace
1402 paranoid_swapgs:
1403         TRACE_IRQS_IRETQ 0
1404         SWAPGS_UNSAFE_STACK
1405         RESTORE_ALL 8
1406         jmp irq_return
1407 paranoid_restore:
1408         TRACE_IRQS_IRETQ 0
1409         RESTORE_ALL 8
1410         jmp irq_return
1411 paranoid_userspace:
1412         GET_THREAD_INFO(%rcx)
1413         movl TI_flags(%rcx),%ebx
1414         andl $_TIF_WORK_MASK,%ebx
1415         jz paranoid_swapgs
1416         movq %rsp,%rdi                  /* &pt_regs */
1417         call sync_regs
1418         movq %rax,%rsp                  /* switch stack for scheduling */
1419         testl $_TIF_NEED_RESCHED,%ebx
1420         jnz paranoid_schedule
1421         movl %ebx,%edx                  /* arg3: thread flags */
1422         TRACE_IRQS_ON
1423         ENABLE_INTERRUPTS(CLBR_NONE)
1424         xorl %esi,%esi                  /* arg2: oldset */
1425         movq %rsp,%rdi                  /* arg1: &pt_regs */
1426         call do_notify_resume
1427         DISABLE_INTERRUPTS(CLBR_NONE)
1428         TRACE_IRQS_OFF
1429         jmp paranoid_userspace
1430 paranoid_schedule:
1431         TRACE_IRQS_ON
1432         ENABLE_INTERRUPTS(CLBR_ANY)
1433         call schedule
1434         DISABLE_INTERRUPTS(CLBR_ANY)
1435         TRACE_IRQS_OFF
1436         jmp paranoid_userspace
1437         CFI_ENDPROC
1438 END(paranoid_exit)
1439
1440 /*
1441  * Exception entry point. This expects an error code/orig_rax on the stack.
1442  * returns in "no swapgs flag" in %ebx.
1443  */
1444 ENTRY(error_entry)
1445         XCPT_FRAME
1446         CFI_ADJUST_CFA_OFFSET 15*8
1447         /* oldrax contains error code */
1448         cld
1449         movq_cfi rdi, RDI+8
1450         movq_cfi rsi, RSI+8
1451         movq_cfi rdx, RDX+8
1452         movq_cfi rcx, RCX+8
1453         movq_cfi rax, RAX+8
1454         movq_cfi  r8,  R8+8
1455         movq_cfi  r9,  R9+8
1456         movq_cfi r10, R10+8
1457         movq_cfi r11, R11+8
1458         movq_cfi rbx, RBX+8
1459         movq_cfi rbp, RBP+8
1460         movq_cfi r12, R12+8
1461         movq_cfi r13, R13+8
1462         movq_cfi r14, R14+8
1463         movq_cfi r15, R15+8
1464         xorl %ebx,%ebx
1465         testl $3,CS+8(%rsp)
1466         je error_kernelspace
1467 error_swapgs:
1468         SWAPGS
1469 error_sti:
1470         TRACE_IRQS_OFF
1471         ret
1472         CFI_ENDPROC
1473
1474 /*
1475  * There are two places in the kernel that can potentially fault with
1476  * usergs. Handle them here. The exception handlers after iret run with
1477  * kernel gs again, so don't set the user space flag. B stepping K8s
1478  * sometimes report an truncated RIP for IRET exceptions returning to
1479  * compat mode. Check for these here too.
1480  */
1481 error_kernelspace:
1482         incl %ebx
1483         leaq irq_return(%rip),%rcx
1484         cmpq %rcx,RIP+8(%rsp)
1485         je error_swapgs
1486         movl %ecx,%ecx  /* zero extend */
1487         cmpq %rcx,RIP+8(%rsp)
1488         je error_swapgs
1489         cmpq $gs_change,RIP+8(%rsp)
1490         je error_swapgs
1491         jmp error_sti
1492 END(error_entry)
1493
1494
1495 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1496 ENTRY(error_exit)
1497         DEFAULT_FRAME
1498         movl %ebx,%eax
1499         RESTORE_REST
1500         DISABLE_INTERRUPTS(CLBR_NONE)
1501         TRACE_IRQS_OFF
1502         GET_THREAD_INFO(%rcx)
1503         testl %eax,%eax
1504         jne retint_kernel
1505         LOCKDEP_SYS_EXIT_IRQ
1506         movl TI_flags(%rcx),%edx
1507         movl $_TIF_WORK_MASK,%edi
1508         andl %edi,%edx
1509         jnz retint_careful
1510         jmp retint_swapgs
1511         CFI_ENDPROC
1512 END(error_exit)
1513
1514
1515         /* runs on exception stack */
1516 ENTRY(nmi)
1517         INTR_FRAME
1518         PARAVIRT_ADJUST_EXCEPTION_FRAME
1519         pushq_cfi $-1
1520         subq $15*8, %rsp
1521         CFI_ADJUST_CFA_OFFSET 15*8
1522         call save_paranoid
1523         DEFAULT_FRAME 0
1524         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1525         movq %rsp,%rdi
1526         movq $-1,%rsi
1527         call do_nmi
1528 #ifdef CONFIG_TRACE_IRQFLAGS
1529         /* paranoidexit; without TRACE_IRQS_OFF */
1530         /* ebx: no swapgs flag */
1531         DISABLE_INTERRUPTS(CLBR_NONE)
1532         testl %ebx,%ebx                         /* swapgs needed? */
1533         jnz nmi_restore
1534         testl $3,CS(%rsp)
1535         jnz nmi_userspace
1536 nmi_swapgs:
1537         SWAPGS_UNSAFE_STACK
1538 nmi_restore:
1539         RESTORE_ALL 8
1540         jmp irq_return
1541 nmi_userspace:
1542         GET_THREAD_INFO(%rcx)
1543         movl TI_flags(%rcx),%ebx
1544         andl $_TIF_WORK_MASK,%ebx
1545         jz nmi_swapgs
1546         movq %rsp,%rdi                  /* &pt_regs */
1547         call sync_regs
1548         movq %rax,%rsp                  /* switch stack for scheduling */
1549         testl $_TIF_NEED_RESCHED,%ebx
1550         jnz nmi_schedule
1551         movl %ebx,%edx                  /* arg3: thread flags */
1552         ENABLE_INTERRUPTS(CLBR_NONE)
1553         xorl %esi,%esi                  /* arg2: oldset */
1554         movq %rsp,%rdi                  /* arg1: &pt_regs */
1555         call do_notify_resume
1556         DISABLE_INTERRUPTS(CLBR_NONE)
1557         jmp nmi_userspace
1558 nmi_schedule:
1559         ENABLE_INTERRUPTS(CLBR_ANY)
1560         call schedule
1561         DISABLE_INTERRUPTS(CLBR_ANY)
1562         jmp nmi_userspace
1563         CFI_ENDPROC
1564 #else
1565         jmp paranoid_exit
1566         CFI_ENDPROC
1567 #endif
1568 END(nmi)
1569
1570 ENTRY(ignore_sysret)
1571         CFI_STARTPROC
1572         mov $-ENOSYS,%eax
1573         sysret
1574         CFI_ENDPROC
1575 END(ignore_sysret)
1576
1577 /*
1578  * End of kprobes section
1579  */
1580         .popsection