SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/sh/kernel/entry-common.S

   1 /*
   2  *  Copyright (C) 1999, 2000, 2002  Niibe Yutaka
   3  *  Copyright (C) 2003 - 2008  Paul Mundt
   4  *
   5  * This file is subject to the terms and conditions of the GNU General Public
   6  * License.  See the file "COPYING" in the main directory of this archive
   7  * for more details.
   8  *
   9  */
  10
  11 ! NOTE:
  12 ! GNU as (as of 2.9.1) changes bf/s into bt/s and bra, when the address
  13 ! to be jumped is too far, but it causes illegal slot exception.
  14
  15 /*
  16  * entry.S contains the system-call and fault low-level handling routines.
  17  * This also contains the timer-interrupt handler, as well as all interrupts
  18  * and faults that can result in a task-switch.
  19  *
  20  * NOTE: This code handles signal-recognition, which happens every time
  21  * after a timer-interrupt and after each system call.
  22  *
  23  * NOTE: This code uses a convention that instructions in the delay slot
  24  * of a transfer-control instruction are indented by an extra space, thus:
  25  *
  26  *    jmp       @k0         ! control-transfer instruction
  27  *     ldc      k1, ssr     ! delay slot
  28  *
  29  * Stack layout in 'ret_from_syscall':
  30  *      ptrace needs to have all regs on the stack.
  31  *      if the order here is changed, it needs to be
  32  *      updated in ptrace.c and ptrace.h
  33  *
  34  *      r0
  35  *      ...
  36  *      r15 = stack pointer
  37  *      spc
  38  *      pr
  39  *      ssr
  40  *      gbr
  41  *      mach
  42  *      macl
  43  *      syscall #
  44  *
  45  */
  46 #include <asm/dwarf.h>
  47
  48 #if defined(CONFIG_PREEMPT)
  49 #  define preempt_stop()        cli ; TRACE_IRQS_OFF
  50 #else
  51 #  define preempt_stop()
  52 #  define resume_kernel         __restore_all
  53 #endif
  54
  55
  56         .align  2
  57 ENTRY(exception_error)
  58         !
  59         TRACE_IRQS_ON
  60         sti
  61         mov.l   1f, r0
  62         jmp     @r0
  63          nop
  64
  65         .align  2
  66 1:      .long   do_exception_error
  67
  68         .align  2
  69 ret_from_exception:
  70         CFI_STARTPROC simple
  71         CFI_DEF_CFA r14, 0
  72         CFI_REL_OFFSET 17, 64
  73         CFI_REL_OFFSET 15, 0
  74         CFI_REL_OFFSET 14, 56
  75         preempt_stop()
  76 ENTRY(ret_from_irq)
  77         !
  78         mov     #OFF_SR, r0
  79         mov.l   @(r0,r15), r0   ! get status register
  80
  81         shlr2   r0
  82         and     #0x3c, r0
  83         cmp/eq  #0x3c, r0
  84         bt      9f
  85         TRACE_IRQS_ON
  86 9:
  87         mov     #OFF_SR, r0
  88         mov.l   @(r0,r15), r0   ! get status register
  89         shll    r0
  90         shll    r0              ! kernel space?
  91         get_current_thread_info r8, r0
  92         bt      resume_kernel   ! Yes, it's from kernel, go back soon
  93
  94 #ifdef CONFIG_PREEMPT
  95         bra     resume_userspace
  96          nop
  97 ENTRY(resume_kernel)
  98         cli
  99         mov.l   @(TI_PRE_COUNT,r8), r0  ! current_thread_info->preempt_count
 100         tst     r0, r0
 101         bf      noresched
 102 need_resched:
 103         mov.l   @(TI_FLAGS,r8), r0      ! current_thread_info->flags
 104         tst     #_TIF_NEED_RESCHED, r0  ! need_resched set?
 105         bt      noresched
 106
 107         mov     #OFF_SR, r0
 108         mov.l   @(r0,r15), r0           ! get status register
 109         and     #0xf0, r0               ! interrupts off (exception path)?
 110         cmp/eq  #0xf0, r0
 111         bt      noresched
 112         mov.l   3f, r0
 113         jsr     @r0                     ! call preempt_schedule_irq
 114          nop
 115         bra     need_resched
 116          nop
 117
 118 noresched:
 119         bra     __restore_all
 120          nop
 121
 122         .align 2
 123 1:      .long   PREEMPT_ACTIVE
 124 2:      .long   schedule
 125 3:      .long   preempt_schedule_irq
 126 #endif
 127
 128 ENTRY(resume_userspace)
 129         ! r8: current_thread_info
 130         cli
 131         TRACE_IRQS_OfF
 132         mov.l   @(TI_FLAGS,r8), r0              ! current_thread_info->flags
 133         tst     #(_TIF_WORK_MASK & 0xff), r0
 134         bt/s    __restore_all
 135          tst    #_TIF_NEED_RESCHED, r0
 136
 137         .align  2
 138 work_pending:
 139         ! r0: current_thread_info->flags
 140         ! r8: current_thread_info
 141         ! t:  result of "tst    #_TIF_NEED_RESCHED, r0"
 142         bf/s    work_resched
 143          tst    #(_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK), r0
 144 work_notifysig:
 145         bt/s    __restore_all
 146          mov    r15, r4
 147         mov     r12, r5         ! set arg1(save_r0)
 148         mov     r0, r6
 149         mov.l   2f, r1
 150         mov.l   3f, r0
 151         jmp     @r1
 152          lds    r0, pr
 153 work_resched:
 154         mov.l   1f, r1
 155         jsr     @r1                             ! schedule
 156          nop
 157         cli
 158         TRACE_IRQS_OFF
 159         !
 160         mov.l   @(TI_FLAGS,r8), r0              ! current_thread_info->flags
 161         tst     #(_TIF_WORK_MASK & 0xff), r0
 162         bt      __restore_all
 163         bra     work_pending
 164          tst    #_TIF_NEED_RESCHED, r0
 165
 166         .align  2
 167 1:      .long   schedule
 168 2:      .long   do_notify_resume
 169 3:      .long   resume_userspace
 170
 171         .align  2
 172 syscall_exit_work:
 173         ! r0: current_thread_info->flags
 174         ! r8: current_thread_info
 175         tst     #(_TIF_WORK_SYSCALL_MASK & 0xff), r0
 176         bt/s    work_pending
 177          tst    #_TIF_NEED_RESCHED, r0
 178         TRACE_IRQS_ON
 179         sti
 180         mov     r15, r4
 181         mov.l   8f, r0                  ! do_syscall_trace_leave
 182         jsr     @r0
 183          nop
 184         bra     resume_userspace
 185          nop
 186
 187         .align  2
 188 syscall_trace_entry:
 189         !                       Yes it is traced.
 190         mov     r15, r4
 191         mov.l   7f, r11         ! Call do_syscall_trace_enter which notifies
 192         jsr     @r11            ! superior (will chomp R[0-7])
 193          nop
 194         mov.l   r0, @(OFF_R0,r15)       ! Save return value
 195         !                       Reload R0-R4 from kernel stack, where the
 196         !                       parent may have modified them using
 197         !                       ptrace(POKEUSR).  (Note that R0-R2 are
 198         !                       used by the system call handler directly
 199         !                       from the kernel stack anyway, so don't need
 200         !                       to be reloaded here.)  This allows the parent
 201         !                       to rewrite system calls and args on the fly.
 202         mov.l   @(OFF_R4,r15), r4   ! arg0
 203         mov.l   @(OFF_R5,r15), r5
 204         mov.l   @(OFF_R6,r15), r6
 205         mov.l   @(OFF_R7,r15), r7   ! arg3
 206         mov.l   @(OFF_R3,r15), r3   ! syscall_nr
 207         !
 208         mov.l   2f, r10                 ! Number of syscalls
 209         cmp/hs  r10, r3
 210         bf      syscall_call
 211         mov     #-ENOSYS, r0
 212         bra     syscall_exit
 213          mov.l  r0, @(OFF_R0,r15)       ! Return value
 214
 215 __restore_all:
 216         mov.l   1f, r0
 217         jmp     @r0
 218          nop
 219
 220         .align  2
 221 1:      .long   restore_all
 222
 223         .align  2
 224 syscall_badsys:                 ! Bad syscall number
 225         get_current_thread_info r8, r0
 226         mov     #-ENOSYS, r0
 227         bra     resume_userspace
 228          mov.l  r0, @(OFF_R0,r15)       ! Return value
 229
 230 /*
 231  * The main debug trap handler.
 232  *
 233  * r8=TRA (not the trap number!)
 234  *
 235  * Note: This assumes that the trapa value is left in its original
 236  * form (without the shlr2 shift) so the calculation for the jump
 237  * call table offset remains a simple in place mask.
 238  */
 239 debug_trap:
 240         mov     r8, r0
 241         and     #(0xf << 2), r0
 242         mov.l   1f, r8
 243         add     r0, r8
 244         mov.l   @r8, r8
 245         jsr     @r8
 246          nop
 247         bra     __restore_all
 248          nop
 249         CFI_ENDPROC
 250
 251         .align  2
 252 1:      .long   debug_trap_table
 253
 254 /*
 255  * Syscall interface:
 256  *
 257  *      Syscall #: R3
 258  *      Arguments #0 to #3: R4--R7
 259  *      Arguments #4 to #6: R0, R1, R2
 260  *      TRA: (number of arguments + ABI revision) x 4
 261  *
 262  * This code also handles delegating other traps to the BIOS/gdb stub
 263  * according to:
 264  *
 265  * Trap number
 266  * (TRA>>2)     Purpose
 267  * --------     -------
 268  * 0x00-0x0f    original SH-3/4 syscall ABI (not in general use).
 269  * 0x10-0x1f    general SH-3/4 syscall ABI.
 270  * 0x20-0x2f    syscall ABI for SH-2 parts.
 271  * 0x30-0x3f    debug traps used by the kernel.
 272  * 0x40-0xff    Not supported by all parts, so left unhandled.
 273  *
 274  * Note: When we're first called, the TRA value must be shifted
 275  * right 2 bits in order to get the value that was used as the "trapa"
 276  * argument.
 277  */
 278
 279         .align  2
 280         .globl  ret_from_fork
 281 ret_from_fork:
 282         mov.l   1f, r8
 283         jsr     @r8
 284          mov    r0, r4
 285         bra     syscall_exit
 286          nop
 287         .align  2
 288 1:      .long   schedule_tail
 289
 290 /*
 291  * The poorly named main trapa decode and dispatch routine, for
 292  * system calls and debug traps through their respective jump tables.
 293  */
 294 ENTRY(system_call)
 295         setup_frame_reg
 296 #if !defined(CONFIG_CPU_SH2)
 297         mov.l   1f, r9
 298         mov.l   @r9, r8         ! Read from TRA (Trap Address) Register
 299 #endif
 300
 301         mov     #OFF_TRA, r10
 302         add     r15, r10
 303         mov.l   r8, @r10                ! set TRA value to tra
 304
 305         /*
 306          * Check the trap type
 307          */
 308         mov     #((0x20 << 2) - 1), r9
 309         cmp/hi  r9, r8
 310         bt/s    debug_trap              ! it's a debug trap..
 311          nop
 312
 313         TRACE_IRQS_ON
 314         sti
 315
 316         !
 317         get_current_thread_info r8, r10
 318         mov.l   @(TI_FLAGS,r8), r8
 319         mov     #(_TIF_WORK_SYSCALL_MASK & 0xff), r10
 320         mov     #(_TIF_WORK_SYSCALL_MASK >> 8), r9
 321         tst     r10, r8
 322         shll8   r9
 323         bf      syscall_trace_entry
 324         tst     r9, r8
 325         bf      syscall_trace_entry
 326         !
 327         mov.l   2f, r8                  ! Number of syscalls
 328         cmp/hs  r8, r3
 329         bt      syscall_badsys
 330         !
 331 syscall_call:
 332         shll2   r3              ! x4
 333         mov.l   3f, r8          ! Load the address of sys_call_table
 334         add     r8, r3
 335         mov.l   @r3, r8
 336         jsr     @r8             ! jump to specific syscall handler
 337          nop
 338         mov.l   @(OFF_R0,r15), r12              ! save r0
 339         mov.l   r0, @(OFF_R0,r15)               ! save the return value
 340         !
 341 syscall_exit:
 342         cli
 343         TRACE_IRQS_OFF
 344         !
 345         get_current_thread_info r8, r0
 346         mov.l   @(TI_FLAGS,r8), r0              ! current_thread_info->flags
 347         tst     #(_TIF_ALLWORK_MASK & 0xff), r0
 348         mov     #(_TIF_ALLWORK_MASK >> 8), r1
 349         bf      syscall_exit_work
 350         shlr8   r0
 351         tst     r0, r1
 352         bf      syscall_exit_work
 353         bra     __restore_all
 354          nop
 355         .align  2
 356 #if !defined(CONFIG_CPU_SH2)
 357 1:      .long   TRA
 358 #endif
 359 2:      .long   NR_syscalls
 360 3:      .long   sys_call_table
 361 7:      .long   do_syscall_trace_enter
 362 8:      .long   do_syscall_trace_leave