SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/s390/kernel/entry.S

   1 /*
   2  *  arch/s390/kernel/entry.S
   3  *    S390 low-level entry points.
   4  *
   5  *    Copyright (C) IBM Corp. 1999,2006
   6  *    Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
   7  *               Hartmut Penner (hp@de.ibm.com),
   8  *               Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
   9  *               Heiko Carstens <heiko.carstens@de.ibm.com>
  10  */
  11
  12 #include <linux/sys.h>
  13 #include <linux/linkage.h>
  14 #include <linux/init.h>
  15 #include <asm/cache.h>
  16 #include <asm/lowcore.h>
  17 #include <asm/errno.h>
  18 #include <asm/ptrace.h>
  19 #include <asm/thread_info.h>
  20 #include <asm/asm-offsets.h>
  21 #include <asm/unistd.h>
  22 #include <asm/page.h>
  23
  24 /*
  25  * Stack layout for the system_call stack entry.
  26  * The first few entries are identical to the user_regs_struct.
  27  */
  28 SP_PTREGS    =  STACK_FRAME_OVERHEAD
  29 SP_ARGS      =  STACK_FRAME_OVERHEAD + __PT_ARGS
  30 SP_PSW       =  STACK_FRAME_OVERHEAD + __PT_PSW
  31 SP_R0        =  STACK_FRAME_OVERHEAD + __PT_GPRS
  32 SP_R1        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 4
  33 SP_R2        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 8
  34 SP_R3        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 12
  35 SP_R4        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 16
  36 SP_R5        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 20
  37 SP_R6        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 24
  38 SP_R7        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 28
  39 SP_R8        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 32
  40 SP_R9        =  STACK_FRAME_OVERHEAD + __PT_GPRS + 36
  41 SP_R10       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 40
  42 SP_R11       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 44
  43 SP_R12       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 48
  44 SP_R13       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 52
  45 SP_R14       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 56
  46 SP_R15       =  STACK_FRAME_OVERHEAD + __PT_GPRS + 60
  47 SP_ORIG_R2   =  STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
  48 SP_ILC       =  STACK_FRAME_OVERHEAD + __PT_ILC
  49 SP_SVCNR     =  STACK_FRAME_OVERHEAD + __PT_SVCNR
  50 SP_SIZE      =  STACK_FRAME_OVERHEAD + __PT_SIZE
  51
  52 _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  53                  _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
  54 _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_NOTIFY_RESUME | _TIF_NEED_RESCHED | \
  55                  _TIF_MCCK_PENDING)
  56 _TIF_SYSCALL = (_TIF_SYSCALL_TRACE>>8 | _TIF_SYSCALL_AUDIT>>8 | \
  57                 _TIF_SECCOMP>>8 | _TIF_SYSCALL_TRACEPOINT>>8)
  58
  59 STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  60 STACK_SIZE  = 1 << STACK_SHIFT
  61
  62 #define BASED(name) name-system_call(%r13)
  63
  64 #ifdef CONFIG_TRACE_IRQFLAGS
  65         .macro  TRACE_IRQS_ON
  66         basr    %r2,%r0
  67         l       %r1,BASED(.Ltrace_irq_on_caller)
  68         basr    %r14,%r1
  69         .endm
  70
  71         .macro  TRACE_IRQS_OFF
  72         basr    %r2,%r0
  73         l       %r1,BASED(.Ltrace_irq_off_caller)
  74         basr    %r14,%r1
  75         .endm
  76
  77         .macro  TRACE_IRQS_CHECK
  78         basr    %r2,%r0
  79         tm      SP_PSW(%r15),0x03       # irqs enabled?
  80         jz      0f
  81         l       %r1,BASED(.Ltrace_irq_on_caller)
  82         basr    %r14,%r1
  83         j       1f
  84 0:      l       %r1,BASED(.Ltrace_irq_off_caller)
  85         basr    %r14,%r1
  86 1:
  87         .endm
  88 #else
  89 #define TRACE_IRQS_ON
  90 #define TRACE_IRQS_OFF
  91 #define TRACE_IRQS_CHECK
  92 #endif
  93
  94 #ifdef CONFIG_LOCKDEP
  95         .macro  LOCKDEP_SYS_EXIT
  96         tm      SP_PSW+1(%r15),0x01     # returning to user ?
  97         jz      0f
  98         l       %r1,BASED(.Llockdep_sys_exit)
  99         basr    %r14,%r1
 100 0:
 101         .endm
 102 #else
 103 #define LOCKDEP_SYS_EXIT
 104 #endif
 105
 106 /*
 107  * Register usage in interrupt handlers:
 108  *    R9  - pointer to current task structure
 109  *    R13 - pointer to literal pool
 110  *    R14 - return register for function calls
 111  *    R15 - kernel stack pointer
 112  */
 113
 114         .macro  UPDATE_VTIME lc_from,lc_to,lc_sum
 115         lm      %r10,%r11,\lc_from
 116         sl      %r10,\lc_to
 117         sl      %r11,\lc_to+4
 118         bc      3,BASED(0f)
 119         sl      %r10,BASED(.Lc_1)
 120 0:      al      %r10,\lc_sum
 121         al      %r11,\lc_sum+4
 122         bc      12,BASED(1f)
 123         al      %r10,BASED(.Lc_1)
 124 1:      stm     %r10,%r11,\lc_sum
 125         .endm
 126
 127         .macro  SAVE_ALL_BASE savearea
 128         stm     %r12,%r15,\savearea
 129         l       %r13,__LC_SVC_NEW_PSW+4 # load &system_call to %r13
 130         .endm
 131
 132         .macro  SAVE_ALL_SVC psworg,savearea
 133         la      %r12,\psworg
 134         l       %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 135         .endm
 136
 137         .macro  SAVE_ALL_SYNC psworg,savearea
 138         la      %r12,\psworg
 139         tm      \psworg+1,0x01          # test problem state bit
 140         bz      BASED(2f)               # skip stack setup save
 141         l       %r15,__LC_KERNEL_STACK  # problem state -> load ksp
 142 #ifdef CONFIG_CHECK_STACK
 143         b       BASED(3f)
 144 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 145         bz      BASED(stack_overflow)
 146 3:
 147 #endif
 148 2:
 149         .endm
 150
 151         .macro  SAVE_ALL_ASYNC psworg,savearea
 152         la      %r12,\psworg
 153         tm      \psworg+1,0x01          # test problem state bit
 154         bnz     BASED(1f)               # from user -> load async stack
 155         clc     \psworg+4(4),BASED(.Lcritical_end)
 156         bhe     BASED(0f)
 157         clc     \psworg+4(4),BASED(.Lcritical_start)
 158         bl      BASED(0f)
 159         l       %r14,BASED(.Lcleanup_critical)
 160         basr    %r14,%r14
 161         tm      1(%r12),0x01            # retest problem state after cleanup
 162         bnz     BASED(1f)
 163 0:      l       %r14,__LC_ASYNC_STACK   # are we already on the async stack ?
 164         slr     %r14,%r15
 165         sra     %r14,STACK_SHIFT
 166         be      BASED(2f)
 167 1:      l       %r15,__LC_ASYNC_STACK
 168 #ifdef CONFIG_CHECK_STACK
 169         b       BASED(3f)
 170 2:      tml     %r15,STACK_SIZE - CONFIG_STACK_GUARD
 171         bz      BASED(stack_overflow)
 172 3:
 173 #endif
 174 2:
 175         .endm
 176
 177         .macro  CREATE_STACK_FRAME psworg,savearea
 178         s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
 179         mvc     SP_PSW(8,%r15),0(%r12)  # move user PSW to stack
 180         st      %r2,SP_ORIG_R2(%r15)    # store original content of gpr 2
 181         icm     %r12,3,__LC_SVC_ILC
 182         stm     %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 183         st      %r12,SP_SVCNR(%r15)
 184         mvc     SP_R12(16,%r15),\savearea # move %r12-%r15 to stack
 185         la      %r12,0
 186         st      %r12,__SF_BACKCHAIN(%r15)       # clear back chain
 187         .endm
 188
 189         .macro  RESTORE_ALL psworg,sync
 190         mvc     \psworg(8),SP_PSW(%r15) # move user PSW to lowcore
 191         .if !\sync
 192         ni      \psworg+1,0xfd          # clear wait state bit
 193         .endif
 194         lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15 of user
 195         stpt    __LC_EXIT_TIMER
 196         lpsw    \psworg                 # back to caller
 197         .endm
 198
 199 /*
 200  * Scheduler resume function, called by switch_to
 201  *  gpr2 = (task_struct *) prev
 202  *  gpr3 = (task_struct *) next
 203  * Returns:
 204  *  gpr2 = prev
 205  */
 206         .globl  __switch_to
 207 __switch_to:
 208         basr    %r1,0
 209 __switch_to_base:
 210         tm      __THREAD_per(%r3),0xe8          # new process is using per ?
 211         bz      __switch_to_noper-__switch_to_base(%r1) # if not we're fine
 212         stctl   %c9,%c11,__SF_EMPTY(%r15)       # We are using per stuff
 213         clc     __THREAD_per(12,%r3),__SF_EMPTY(%r15)
 214         be      __switch_to_noper-__switch_to_base(%r1) # we got away w/o bashing TLB's
 215         lctl    %c9,%c11,__THREAD_per(%r3)      # Nope we didn't
 216 __switch_to_noper:
 217         l       %r4,__THREAD_info(%r2)          # get thread_info of prev
 218         tm      __TI_flags+3(%r4),_TIF_MCCK_PENDING # machine check pending?
 219         bz      __switch_to_no_mcck-__switch_to_base(%r1)
 220         ni      __TI_flags+3(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
 221         l       %r4,__THREAD_info(%r3)          # get thread_info of next
 222         oi      __TI_flags+3(%r4),_TIF_MCCK_PENDING # set it in next
 223 __switch_to_no_mcck:
 224         stm     %r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
 225         st      %r15,__THREAD_ksp(%r2)  # store kernel stack to prev->tss.ksp
 226         l       %r15,__THREAD_ksp(%r3)  # load kernel stack from next->tss.ksp
 227         lm      %r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
 228         st      %r3,__LC_CURRENT        # __LC_CURRENT = current task struct
 229         lctl    %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
 230         l       %r3,__THREAD_info(%r3)  # load thread_info from task struct
 231         st      %r3,__LC_THREAD_INFO
 232         ahi     %r3,STACK_SIZE
 233         st      %r3,__LC_KERNEL_STACK   # __LC_KERNEL_STACK = new kernel stack
 234         br      %r14
 235
 236 __critical_start:
 237 /*
 238  * SVC interrupt handler routine. System calls are synchronous events and
 239  * are executed with interrupts enabled.
 240  */
 241
 242         .globl  system_call
 243 system_call:
 244         stpt    __LC_SYNC_ENTER_TIMER
 245 sysc_saveall:
 246         SAVE_ALL_BASE __LC_SAVE_AREA
 247         SAVE_ALL_SVC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 248         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 249         lh      %r7,0x8a          # get svc number from lowcore
 250 sysc_vtime:
 251         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 252 sysc_stime:
 253         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 254 sysc_update:
 255         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 256 sysc_do_svc:
 257         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 258         ltr     %r7,%r7                 # test for svc 0
 259         bnz     BASED(sysc_nr_ok)       # svc number > 0
 260         # svc 0: system call number in %r1
 261         cl      %r1,BASED(.Lnr_syscalls)
 262         bnl     BASED(sysc_nr_ok)
 263         lr      %r7,%r1           # copy svc number to %r7
 264 sysc_nr_ok:
 265         mvc     SP_ARGS(4,%r15),SP_R7(%r15)
 266 sysc_do_restart:
 267         sth     %r7,SP_SVCNR(%r15)
 268         sll     %r7,2             # svc number *4
 269         l       %r8,BASED(.Lsysc_table)
 270         tm      __TI_flags+2(%r9),_TIF_SYSCALL
 271         l       %r8,0(%r7,%r8)    # get system call addr.
 272         bnz     BASED(sysc_tracesys)
 273         basr    %r14,%r8          # call sys_xxxx
 274         st      %r2,SP_R2(%r15)   # store return value (change R2 on stack)
 275
 276 sysc_return:
 277         tm      __TI_flags+3(%r9),_TIF_WORK_SVC
 278         bnz     BASED(sysc_work)  # there is work to do (signals etc.)
 279 sysc_restore:
 280 #ifdef CONFIG_TRACE_IRQFLAGS
 281         la      %r1,BASED(sysc_restore_trace_psw_addr)
 282         l       %r1,0(%r1)
 283         lpsw    0(%r1)
 284 sysc_restore_trace:
 285         TRACE_IRQS_CHECK
 286         LOCKDEP_SYS_EXIT
 287 #endif
 288 sysc_leave:
 289         RESTORE_ALL __LC_RETURN_PSW,1
 290 sysc_done:
 291
 292 #ifdef CONFIG_TRACE_IRQFLAGS
 293 sysc_restore_trace_psw_addr:
 294         .long sysc_restore_trace_psw
 295
 296         .section .data,"aw",@progbits
 297         .align  8
 298         .globl  sysc_restore_trace_psw
 299 sysc_restore_trace_psw:
 300         .long   0, sysc_restore_trace + 0x80000000
 301         .previous
 302 #endif
 303
 304 #
 305 # recheck if there is more work to do
 306 #
 307 sysc_work_loop:
 308         tm      __TI_flags+3(%r9),_TIF_WORK_SVC
 309         bz      BASED(sysc_restore)     # there is no work to do
 310 #
 311 # One of the work bits is on. Find out which one.
 312 #
 313 sysc_work:
 314         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 315         bno     BASED(sysc_restore)
 316         tm      __TI_flags+3(%r9),_TIF_MCCK_PENDING
 317         bo      BASED(sysc_mcck_pending)
 318         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
 319         bo      BASED(sysc_reschedule)
 320         tm      __TI_flags+3(%r9),_TIF_SIGPENDING
 321         bnz     BASED(sysc_sigpending)
 322         tm      __TI_flags+3(%r9),_TIF_NOTIFY_RESUME
 323         bnz     BASED(sysc_notify_resume)
 324         tm      __TI_flags+3(%r9),_TIF_RESTART_SVC
 325         bo      BASED(sysc_restart)
 326         tm      __TI_flags+3(%r9),_TIF_SINGLE_STEP
 327         bo      BASED(sysc_singlestep)
 328         b       BASED(sysc_restore)
 329 sysc_work_done:
 330
 331 #
 332 # _TIF_NEED_RESCHED is set, call schedule
 333 #
 334 sysc_reschedule:
 335         l       %r1,BASED(.Lschedule)
 336         la      %r14,BASED(sysc_work_loop)
 337         br      %r1                     # call scheduler
 338
 339 #
 340 # _TIF_MCCK_PENDING is set, call handler
 341 #
 342 sysc_mcck_pending:
 343         l       %r1,BASED(.Ls390_handle_mcck)
 344         la      %r14,BASED(sysc_work_loop)
 345         br      %r1                     # TIF bit will be cleared by handler
 346
 347 #
 348 # _TIF_SIGPENDING is set, call do_signal
 349 #
 350 sysc_sigpending:
 351         ni      __TI_flags+3(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 352         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 353         l       %r1,BASED(.Ldo_signal)
 354         basr    %r14,%r1                # call do_signal
 355         tm      __TI_flags+3(%r9),_TIF_RESTART_SVC
 356         bo      BASED(sysc_restart)
 357         tm      __TI_flags+3(%r9),_TIF_SINGLE_STEP
 358         bo      BASED(sysc_singlestep)
 359         b       BASED(sysc_work_loop)
 360
 361 #
 362 # _TIF_NOTIFY_RESUME is set, call do_notify_resume
 363 #
 364 sysc_notify_resume:
 365         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 366         l       %r1,BASED(.Ldo_notify_resume)
 367         la      %r14,BASED(sysc_work_loop)
 368         br      %r1                     # call do_notify_resume
 369
 370
 371 #
 372 # _TIF_RESTART_SVC is set, set up registers and restart svc
 373 #
 374 sysc_restart:
 375         ni      __TI_flags+3(%r9),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
 376         l       %r7,SP_R2(%r15)         # load new svc number
 377         mvc     SP_R2(4,%r15),SP_ORIG_R2(%r15) # restore first argument
 378         lm      %r2,%r6,SP_R2(%r15)     # load svc arguments
 379         b       BASED(sysc_do_restart)  # restart svc
 380
 381 #
 382 # _TIF_SINGLE_STEP is set, call do_single_step
 383 #
 384 sysc_singlestep:
 385         ni      __TI_flags+3(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
 386         mvi     SP_SVCNR(%r15),0xff     # set trap indication to pgm check
 387         mvi     SP_SVCNR+1(%r15),0xff
 388         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 389         l       %r1,BASED(.Lhandle_per) # load adr. of per handler
 390         la      %r14,BASED(sysc_return) # load adr. of system return
 391         br      %r1                     # branch to do_single_step
 392
 393 #
 394 # call tracehook_report_syscall_entry/tracehook_report_syscall_exit before
 395 # and after the system call
 396 #
 397 sysc_tracesys:
 398         l       %r1,BASED(.Ltrace_entry)
 399         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 400         la      %r3,0
 401         srl     %r7,2
 402         st      %r7,SP_R2(%r15)
 403         basr    %r14,%r1
 404         cl      %r2,BASED(.Lnr_syscalls)
 405         bnl     BASED(sysc_tracenogo)
 406         l       %r8,BASED(.Lsysc_table)
 407         lr      %r7,%r2
 408         sll     %r7,2                   # svc number *4
 409         l       %r8,0(%r7,%r8)
 410 sysc_tracego:
 411         lm      %r3,%r6,SP_R3(%r15)
 412         l       %r2,SP_ORIG_R2(%r15)
 413         basr    %r14,%r8                # call sys_xxx
 414         st      %r2,SP_R2(%r15)         # store return value
 415 sysc_tracenogo:
 416         tm      __TI_flags+2(%r9),_TIF_SYSCALL
 417         bz      BASED(sysc_return)
 418         l       %r1,BASED(.Ltrace_exit)
 419         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 420         la      %r14,BASED(sysc_return)
 421         br      %r1
 422
 423 #
 424 # a new process exits the kernel with ret_from_fork
 425 #
 426         .globl  ret_from_fork
 427 ret_from_fork:
 428         l       %r13,__LC_SVC_NEW_PSW+4
 429         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 430         tm      SP_PSW+1(%r15),0x01     # forking a kernel thread ?
 431         bo      BASED(0f)
 432         st      %r15,SP_R15(%r15)       # store stack pointer for new kthread
 433 0:      l       %r1,BASED(.Lschedtail)
 434         basr    %r14,%r1
 435         TRACE_IRQS_ON
 436         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 437         b       BASED(sysc_tracenogo)
 438
 439 #
 440 # kernel_execve function needs to deal with pt_regs that is not
 441 # at the usual place
 442 #
 443         .globl  kernel_execve
 444 kernel_execve:
 445         stm     %r12,%r15,48(%r15)
 446         lr      %r14,%r15
 447         l       %r13,__LC_SVC_NEW_PSW+4
 448         s       %r15,BASED(.Lc_spsize)
 449         st      %r14,__SF_BACKCHAIN(%r15)
 450         la      %r12,SP_PTREGS(%r15)
 451         xc      0(__PT_SIZE,%r12),0(%r12)
 452         l       %r1,BASED(.Ldo_execve)
 453         lr      %r5,%r12
 454         basr    %r14,%r1
 455         ltr     %r2,%r2
 456         be      BASED(0f)
 457         a       %r15,BASED(.Lc_spsize)
 458         lm      %r12,%r15,48(%r15)
 459         br      %r14
 460         # execve succeeded.
 461 0:      stnsm   __SF_EMPTY(%r15),0xfc   # disable interrupts
 462         l       %r15,__LC_KERNEL_STACK  # load ksp
 463         s       %r15,BASED(.Lc_spsize)  # make room for registers & psw
 464         l       %r9,__LC_THREAD_INFO
 465         mvc     SP_PTREGS(__PT_SIZE,%r15),0(%r12)       # copy pt_regs
 466         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15)
 467         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 468         l       %r1,BASED(.Lexecve_tail)
 469         basr    %r14,%r1
 470         b       BASED(sysc_return)
 471
 472 /*
 473  * Program check handler routine
 474  */
 475
 476         .globl  pgm_check_handler
 477 pgm_check_handler:
 478 /*
 479  * First we need to check for a special case:
 480  * Single stepping an instruction that disables the PER event mask will
 481  * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
 482  * For a single stepped SVC the program check handler gets control after
 483  * the SVC new PSW has been loaded. But we want to execute the SVC first and
 484  * then handle the PER event. Therefore we update the SVC old PSW to point
 485  * to the pgm_check_handler and branch to the SVC handler after we checked
 486  * if we have to load the kernel stack register.
 487  * For every other possible cause for PER event without the PER mask set
 488  * we just ignore the PER event (FIXME: is there anything we have to do
 489  * for LPSW?).
 490  */
 491         stpt    __LC_SYNC_ENTER_TIMER
 492         SAVE_ALL_BASE __LC_SAVE_AREA
 493         tm      __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
 494         bnz     BASED(pgm_per)          # got per exception -> special case
 495         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 496         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 497         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 498         bz      BASED(pgm_no_vtime)
 499         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 500         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 501         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 502 pgm_no_vtime:
 503         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 504         TRACE_IRQS_OFF
 505         l       %r3,__LC_PGM_ILC        # load program interruption code
 506         la      %r8,0x7f
 507         nr      %r8,%r3
 508 pgm_do_call:
 509         l       %r7,BASED(.Ljump_table)
 510         sll     %r8,2
 511         l       %r7,0(%r8,%r7)          # load address of handler routine
 512         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 513         la      %r14,BASED(sysc_return)
 514         br      %r7                     # branch to interrupt-handler
 515
 516 #
 517 # handle per exception
 518 #
 519 pgm_per:
 520         tm      __LC_PGM_OLD_PSW,0x40   # test if per event recording is on
 521         bnz     BASED(pgm_per_std)      # ok, normal per event from user space
 522 # ok its one of the special cases, now we need to find out which one
 523         clc     __LC_PGM_OLD_PSW(8),__LC_SVC_NEW_PSW
 524         be      BASED(pgm_svcper)
 525 # no interesting special case, ignore PER event
 526         lm      %r12,%r15,__LC_SAVE_AREA
 527         lpsw    0x28
 528
 529 #
 530 # Normal per exception
 531 #
 532 pgm_per_std:
 533         SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 534         CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
 535         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 536         bz      BASED(pgm_no_vtime2)
 537         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 538         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 539         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 540 pgm_no_vtime2:
 541         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 542         TRACE_IRQS_OFF
 543         l       %r1,__TI_task(%r9)
 544         mvc     __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
 545         mvc     __THREAD_per+__PER_address(4,%r1),__LC_PER_ADDRESS
 546         mvc     __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
 547         oi      __TI_flags+3(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 548         tm      SP_PSW+1(%r15),0x01     # kernel per event ?
 549         bz      BASED(kernel_per)
 550         l       %r3,__LC_PGM_ILC        # load program interruption code
 551         la      %r8,0x7f
 552         nr      %r8,%r3                 # clear per-event-bit and ilc
 553         be      BASED(sysc_return)      # only per or per+check ?
 554         b       BASED(pgm_do_call)
 555
 556 #
 557 # it was a single stepped SVC that is causing all the trouble
 558 #
 559 pgm_svcper:
 560         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 561         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 562         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 563         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 564         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
 565         lh      %r7,0x8a                # get svc number from lowcore
 566         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 567         TRACE_IRQS_OFF
 568         l       %r8,__TI_task(%r9)
 569         mvc     __THREAD_per+__PER_atmid(2,%r8),__LC_PER_ATMID
 570         mvc     __THREAD_per+__PER_address(4,%r8),__LC_PER_ADDRESS
 571         mvc     __THREAD_per+__PER_access_id(1,%r8),__LC_PER_ACCESS_ID
 572         oi      __TI_flags+3(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
 573         TRACE_IRQS_ON
 574         lm      %r2,%r6,SP_R2(%r15)     # load svc arguments
 575         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 576         b       BASED(sysc_do_svc)
 577
 578 #
 579 # per was called from kernel, must be kprobes
 580 #
 581 kernel_per:
 582         mvi     SP_SVCNR(%r15),0xff     # set trap indication to pgm check
 583         mvi     SP_SVCNR+1(%r15),0xff
 584         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 585         l       %r1,BASED(.Lhandle_per) # load adr. of per handler
 586         la      %r14,BASED(sysc_restore)# load adr. of system return
 587         br      %r1                     # branch to do_single_step
 588
 589 /*
 590  * IO interrupt handler routine
 591  */
 592
 593         .globl io_int_handler
 594 io_int_handler:
 595         stck    __LC_INT_CLOCK
 596         stpt    __LC_ASYNC_ENTER_TIMER
 597         SAVE_ALL_BASE __LC_SAVE_AREA+16
 598         SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+16
 599         CREATE_STACK_FRAME __LC_IO_OLD_PSW,__LC_SAVE_AREA+16
 600         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 601         bz      BASED(io_no_vtime)
 602         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 603         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 604         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 605 io_no_vtime:
 606         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 607         TRACE_IRQS_OFF
 608         l       %r1,BASED(.Ldo_IRQ)     # load address of do_IRQ
 609         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 610         basr    %r14,%r1                # branch to standard irq handler
 611 io_return:
 612         tm      __TI_flags+3(%r9),_TIF_WORK_INT
 613         bnz     BASED(io_work)          # there is work to do (signals etc.)
 614 io_restore:
 615 #ifdef CONFIG_TRACE_IRQFLAGS
 616         la      %r1,BASED(io_restore_trace_psw_addr)
 617         l       %r1,0(%r1)
 618         lpsw    0(%r1)
 619 io_restore_trace:
 620         TRACE_IRQS_CHECK
 621         LOCKDEP_SYS_EXIT
 622 #endif
 623 io_leave:
 624         RESTORE_ALL __LC_RETURN_PSW,0
 625 io_done:
 626
 627 #ifdef CONFIG_TRACE_IRQFLAGS
 628 io_restore_trace_psw_addr:
 629         .long io_restore_trace_psw
 630
 631         .section .data,"aw",@progbits
 632         .align  8
 633         .globl  io_restore_trace_psw
 634 io_restore_trace_psw:
 635         .long   0, io_restore_trace + 0x80000000
 636         .previous
 637 #endif
 638
 639 #
 640 # switch to kernel stack, then check the TIF bits
 641 #
 642 io_work:
 643         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 644 #ifndef CONFIG_PREEMPT
 645         bno     BASED(io_restore)       # no-> skip resched & signal
 646 #else
 647         bnz     BASED(io_work_user)     # no -> check for preemptive scheduling
 648         # check for preemptive scheduling
 649         icm     %r0,15,__TI_precount(%r9)
 650         bnz     BASED(io_restore)       # preemption disabled
 651         l       %r1,SP_R15(%r15)
 652         s       %r1,BASED(.Lc_spsize)
 653         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 654         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 655         lr      %r15,%r1
 656 io_resume_loop:
 657         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
 658         bno     BASED(io_restore)
 659         l       %r1,BASED(.Lpreempt_schedule_irq)
 660         la      %r14,BASED(io_resume_loop)
 661         br      %r1                     # call schedule
 662 #endif
 663
 664 io_work_user:
 665         l       %r1,__LC_KERNEL_STACK
 666         s       %r1,BASED(.Lc_spsize)
 667         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 668         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 669         lr      %r15,%r1
 670 #
 671 # One of the work bits is on. Find out which one.
 672 # Checked are: _TIF_SIGPENDING, _TIF_NEED_RESCHED
 673 #               and _TIF_MCCK_PENDING
 674 #
 675 io_work_loop:
 676         tm      __TI_flags+3(%r9),_TIF_MCCK_PENDING
 677         bo      BASED(io_mcck_pending)
 678         tm      __TI_flags+3(%r9),_TIF_NEED_RESCHED
 679         bo      BASED(io_reschedule)
 680         tm      __TI_flags+3(%r9),_TIF_SIGPENDING
 681         bnz     BASED(io_sigpending)
 682         tm      __TI_flags+3(%r9),_TIF_NOTIFY_RESUME
 683         bnz     BASED(io_notify_resume)
 684         b       BASED(io_restore)
 685 io_work_done:
 686
 687 #
 688 # _TIF_MCCK_PENDING is set, call handler
 689 #
 690 io_mcck_pending:
 691         l       %r1,BASED(.Ls390_handle_mcck)
 692         basr    %r14,%r1                # TIF bit will be cleared by handler
 693         b       BASED(io_work_loop)
 694
 695 #
 696 # _TIF_NEED_RESCHED is set, call schedule
 697 #
 698 io_reschedule:
 699         TRACE_IRQS_ON
 700         l       %r1,BASED(.Lschedule)
 701         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 702         basr    %r14,%r1                # call scheduler
 703         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 704         TRACE_IRQS_OFF
 705         tm      __TI_flags+3(%r9),_TIF_WORK_INT
 706         bz      BASED(io_restore)       # there is no work to do
 707         b       BASED(io_work_loop)
 708
 709 #
 710 # _TIF_SIGPENDING is set, call do_signal
 711 #
 712 io_sigpending:
 713         TRACE_IRQS_ON
 714         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 715         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 716         l       %r1,BASED(.Ldo_signal)
 717         basr    %r14,%r1                # call do_signal
 718         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 719         TRACE_IRQS_OFF
 720         b       BASED(io_work_loop)
 721
 722 #
 723 # _TIF_SIGPENDING is set, call do_signal
 724 #
 725 io_notify_resume:
 726         TRACE_IRQS_ON
 727         stosm   __SF_EMPTY(%r15),0x03   # reenable interrupts
 728         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 729         l       %r1,BASED(.Ldo_notify_resume)
 730         basr    %r14,%r1                # call do_signal
 731         stnsm   __SF_EMPTY(%r15),0xfc   # disable I/O and ext. interrupts
 732         TRACE_IRQS_OFF
 733         b       BASED(io_work_loop)
 734
 735 /*
 736  * External interrupt handler routine
 737  */
 738
 739         .globl  ext_int_handler
 740 ext_int_handler:
 741         stck    __LC_INT_CLOCK
 742         stpt    __LC_ASYNC_ENTER_TIMER
 743         SAVE_ALL_BASE __LC_SAVE_AREA+16
 744         SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16
 745         CREATE_STACK_FRAME __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16
 746         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 747         bz      BASED(ext_no_vtime)
 748         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 749         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 750         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 751 ext_no_vtime:
 752         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 753         TRACE_IRQS_OFF
 754         la      %r2,SP_PTREGS(%r15)     # address of register-save area
 755         lh      %r3,__LC_EXT_INT_CODE   # get interruption code
 756         l       %r1,BASED(.Ldo_extint)
 757         basr    %r14,%r1
 758         b       BASED(io_return)
 759
 760 __critical_end:
 761
 762 /*
 763  * Machine check handler routines
 764  */
 765
 766         .globl mcck_int_handler
 767 mcck_int_handler:
 768         stck    __LC_INT_CLOCK
 769         spt     __LC_CPU_TIMER_SAVE_AREA        # revalidate cpu timer
 770         lm      %r0,%r15,__LC_GPREGS_SAVE_AREA  # revalidate gprs
 771         SAVE_ALL_BASE __LC_SAVE_AREA+32
 772         la      %r12,__LC_MCK_OLD_PSW
 773         tm      __LC_MCCK_CODE,0x80     # system damage?
 774         bo      BASED(mcck_int_main)    # yes -> rest of mcck code invalid
 775         mvc     __LC_SAVE_AREA+52(8),__LC_ASYNC_ENTER_TIMER
 776         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA
 777         tm      __LC_MCCK_CODE+5,0x02   # stored cpu timer value valid?
 778         bo      BASED(1f)
 779         la      %r14,__LC_SYNC_ENTER_TIMER
 780         clc     0(8,%r14),__LC_ASYNC_ENTER_TIMER
 781         bl      BASED(0f)
 782         la      %r14,__LC_ASYNC_ENTER_TIMER
 783 0:      clc     0(8,%r14),__LC_EXIT_TIMER
 784         bl      BASED(0f)
 785         la      %r14,__LC_EXIT_TIMER
 786 0:      clc     0(8,%r14),__LC_LAST_UPDATE_TIMER
 787         bl      BASED(0f)
 788         la      %r14,__LC_LAST_UPDATE_TIMER
 789 0:      spt     0(%r14)
 790         mvc     __LC_ASYNC_ENTER_TIMER(8),0(%r14)
 791 1:      tm      __LC_MCCK_CODE+2,0x09   # mwp + ia of old psw valid?
 792         bno     BASED(mcck_int_main)    # no -> skip cleanup critical
 793         tm      __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
 794         bnz     BASED(mcck_int_main)    # from user -> load async stack
 795         clc     __LC_MCK_OLD_PSW+4(4),BASED(.Lcritical_end)
 796         bhe     BASED(mcck_int_main)
 797         clc     __LC_MCK_OLD_PSW+4(4),BASED(.Lcritical_start)
 798         bl      BASED(mcck_int_main)
 799         l       %r14,BASED(.Lcleanup_critical)
 800         basr    %r14,%r14
 801 mcck_int_main:
 802         l       %r14,__LC_PANIC_STACK   # are we already on the panic stack?
 803         slr     %r14,%r15
 804         sra     %r14,PAGE_SHIFT
 805         be      BASED(0f)
 806         l       %r15,__LC_PANIC_STACK   # load panic stack
 807 0:      CREATE_STACK_FRAME __LC_MCK_OLD_PSW,__LC_SAVE_AREA+32
 808         tm      __LC_MCCK_CODE+2,0x08   # mwp of old psw valid?
 809         bno     BASED(mcck_no_vtime)    # no -> skip cleanup critical
 810         tm      SP_PSW+1(%r15),0x01     # interrupting from user ?
 811         bz      BASED(mcck_no_vtime)
 812         UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
 813         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
 814         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
 815 mcck_no_vtime:
 816         l       %r9,__LC_THREAD_INFO    # load pointer to thread_info struct
 817         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 818         l       %r1,BASED(.Ls390_mcck)
 819         basr    %r14,%r1                # call machine check handler
 820         tm      SP_PSW+1(%r15),0x01     # returning to user ?
 821         bno     BASED(mcck_return)
 822         l       %r1,__LC_KERNEL_STACK   # switch to kernel stack
 823         s       %r1,BASED(.Lc_spsize)
 824         mvc     SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
 825         xc      __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
 826         lr      %r15,%r1
 827         stosm   __SF_EMPTY(%r15),0x04   # turn dat on
 828         tm      __TI_flags+3(%r9),_TIF_MCCK_PENDING
 829         bno     BASED(mcck_return)
 830         TRACE_IRQS_OFF
 831         l       %r1,BASED(.Ls390_handle_mcck)
 832         basr    %r14,%r1                # call machine check handler
 833         TRACE_IRQS_ON
 834 mcck_return:
 835         mvc     __LC_RETURN_MCCK_PSW(8),SP_PSW(%r15) # move return PSW
 836         ni      __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
 837         mvc     __LC_ASYNC_ENTER_TIMER(8),__LC_SAVE_AREA+52
 838         tm      __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
 839         bno     BASED(0f)
 840         lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 841         stpt    __LC_EXIT_TIMER
 842         lpsw    __LC_RETURN_MCCK_PSW    # back to caller
 843 0:      lm      %r0,%r15,SP_R0(%r15)    # load gprs 0-15
 844         lpsw    __LC_RETURN_MCCK_PSW    # back to caller
 845
 846         RESTORE_ALL __LC_RETURN_MCCK_PSW,0
 847
 848 /*
 849  * Restart interruption handler, kick starter for additional CPUs
 850  */
 851 #ifdef CONFIG_SMP
 852         __CPUINIT
 853         .globl restart_int_handler
 854 restart_int_handler:
 855         basr    %r1,0
 856 restart_base:
 857         spt     restart_vtime-restart_base(%r1)
 858         stck    __LC_LAST_UPDATE_CLOCK
 859         mvc     __LC_LAST_UPDATE_TIMER(8),restart_vtime-restart_base(%r1)
 860         mvc     __LC_EXIT_TIMER(8),restart_vtime-restart_base(%r1)
 861         l       %r15,__LC_SAVE_AREA+60  # load ksp
 862         lctl    %c0,%c15,__LC_CREGS_SAVE_AREA # get new ctl regs
 863         lam     %a0,%a15,__LC_AREGS_SAVE_AREA
 864         lm      %r6,%r15,__SF_GPRS(%r15) # load registers from clone
 865         l       %r1,__LC_THREAD_INFO
 866         mvc     __LC_USER_TIMER(8),__TI_user_timer(%r1)
 867         mvc     __LC_SYSTEM_TIMER(8),__TI_system_timer(%r1)
 868         xc      __LC_STEAL_TIMER(8),__LC_STEAL_TIMER
 869         stosm   __SF_EMPTY(%r15),0x04   # now we can turn dat on
 870         basr    %r14,0
 871         l       %r14,restart_addr-.(%r14)
 872         br      %r14                    # branch to start_secondary
 873 restart_addr:
 874         .long   start_secondary
 875         .align  8
 876 restart_vtime:
 877         .long   0x7fffffff,0xffffffff
 878         .previous
 879 #else
 880 /*
 881  * If we do not run with SMP enabled, let the new CPU crash ...
 882  */
 883         .globl restart_int_handler
 884 restart_int_handler:
 885         basr    %r1,0
 886 restart_base:
 887         lpsw    restart_crash-restart_base(%r1)
 888         .align  8
 889 restart_crash:
 890         .long   0x000a0000,0x00000000
 891 restart_go:
 892 #endif
 893
 894 #ifdef CONFIG_CHECK_STACK
 895 /*
 896  * The synchronous or the asynchronous stack overflowed. We are dead.
 897  * No need to properly save the registers, we are going to panic anyway.
 898  * Setup a pt_regs so that show_trace can provide a good call trace.
 899  */
 900 stack_overflow:
 901         l       %r15,__LC_PANIC_STACK   # change to panic stack
 902         sl      %r15,BASED(.Lc_spsize)
 903         mvc     SP_PSW(8,%r15),0(%r12)  # move user PSW to stack
 904         stm     %r0,%r11,SP_R0(%r15)    # store gprs %r0-%r11 to kernel stack
 905         la      %r1,__LC_SAVE_AREA
 906         ch      %r12,BASED(.L0x020)     # old psw addr == __LC_SVC_OLD_PSW ?
 907         be      BASED(0f)
 908         ch      %r12,BASED(.L0x028)     # old psw addr == __LC_PGM_OLD_PSW ?
 909         be      BASED(0f)
 910         la      %r1,__LC_SAVE_AREA+16
 911 0:      mvc     SP_R12(16,%r15),0(%r1)  # move %r12-%r15 to stack
 912         xc      __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15) # clear back chain
 913         l       %r1,BASED(1f)           # branch to kernel_stack_overflow
 914         la      %r2,SP_PTREGS(%r15)     # load pt_regs
 915         br      %r1
 916 1:      .long   kernel_stack_overflow
 917 #endif
 918
 919 cleanup_table_system_call:
 920         .long   system_call + 0x80000000, sysc_do_svc + 0x80000000
 921 cleanup_table_sysc_return:
 922         .long   sysc_return + 0x80000000, sysc_leave + 0x80000000
 923 cleanup_table_sysc_leave:
 924         .long   sysc_leave + 0x80000000, sysc_done + 0x80000000
 925 cleanup_table_sysc_work_loop:
 926         .long   sysc_work_loop + 0x80000000, sysc_work_done + 0x80000000
 927 cleanup_table_io_return:
 928         .long   io_return + 0x80000000, io_leave + 0x80000000
 929 cleanup_table_io_leave:
 930         .long   io_leave + 0x80000000, io_done + 0x80000000
 931 cleanup_table_io_work_loop:
 932         .long   io_work_loop + 0x80000000, io_work_done + 0x80000000
 933
 934 cleanup_critical:
 935         clc     4(4,%r12),BASED(cleanup_table_system_call)
 936         bl      BASED(0f)
 937         clc     4(4,%r12),BASED(cleanup_table_system_call+4)
 938         bl      BASED(cleanup_system_call)
 939 0:
 940         clc     4(4,%r12),BASED(cleanup_table_sysc_return)
 941         bl      BASED(0f)
 942         clc     4(4,%r12),BASED(cleanup_table_sysc_return+4)
 943         bl      BASED(cleanup_sysc_return)
 944 0:
 945         clc     4(4,%r12),BASED(cleanup_table_sysc_leave)
 946         bl      BASED(0f)
 947         clc     4(4,%r12),BASED(cleanup_table_sysc_leave+4)
 948         bl      BASED(cleanup_sysc_leave)
 949 0:
 950         clc     4(4,%r12),BASED(cleanup_table_sysc_work_loop)
 951         bl      BASED(0f)
 952         clc     4(4,%r12),BASED(cleanup_table_sysc_work_loop+4)
 953         bl      BASED(cleanup_sysc_return)
 954 0:
 955         clc     4(4,%r12),BASED(cleanup_table_io_return)
 956         bl      BASED(0f)
 957         clc     4(4,%r12),BASED(cleanup_table_io_return+4)
 958         bl      BASED(cleanup_io_return)
 959 0:
 960         clc     4(4,%r12),BASED(cleanup_table_io_leave)
 961         bl      BASED(0f)
 962         clc     4(4,%r12),BASED(cleanup_table_io_leave+4)
 963         bl      BASED(cleanup_io_leave)
 964 0:
 965         clc     4(4,%r12),BASED(cleanup_table_io_work_loop)
 966         bl      BASED(0f)
 967         clc     4(4,%r12),BASED(cleanup_table_io_work_loop+4)
 968         bl      BASED(cleanup_io_return)
 969 0:
 970         br      %r14
 971
 972 cleanup_system_call:
 973         mvc     __LC_RETURN_PSW(8),0(%r12)
 974         c       %r12,BASED(.Lmck_old_psw)
 975         be      BASED(0f)
 976         la      %r12,__LC_SAVE_AREA+16
 977         b       BASED(1f)
 978 0:      la      %r12,__LC_SAVE_AREA+32
 979 1:
 980         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+4)
 981         bh      BASED(0f)
 982         mvc     __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
 983 0:      clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+8)
 984         bhe     BASED(cleanup_vtime)
 985         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn)
 986         bh      BASED(0f)
 987         mvc     __LC_SAVE_AREA(16),0(%r12)
 988 0:      st      %r13,4(%r12)
 989         st      %r12,__LC_SAVE_AREA+48  # argh
 990         SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 991         CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
 992         l       %r12,__LC_SAVE_AREA+48  # argh
 993         st      %r15,12(%r12)
 994         lh      %r7,0x8a
 995 cleanup_vtime:
 996         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+12)
 997         bhe     BASED(cleanup_stime)
 998         UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
 999 cleanup_stime:
1000         clc     __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+16)
1001         bh      BASED(cleanup_update)
1002         UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
1003 cleanup_update:
1004         mvc     __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
1005         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_system_call+4)
1006         la      %r12,__LC_RETURN_PSW
1007         br      %r14
1008 cleanup_system_call_insn:
1009         .long   sysc_saveall + 0x80000000
1010         .long   system_call + 0x80000000
1011         .long   sysc_vtime + 0x80000000
1012         .long   sysc_stime + 0x80000000
1013         .long   sysc_update + 0x80000000
1014
1015 cleanup_sysc_return:
1016         mvc     __LC_RETURN_PSW(4),0(%r12)
1017         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_sysc_return)
1018         la      %r12,__LC_RETURN_PSW
1019         br      %r14
1020
1021 cleanup_sysc_leave:
1022         clc     4(4,%r12),BASED(cleanup_sysc_leave_insn)
1023         be      BASED(2f)
1024         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1025         clc     4(4,%r12),BASED(cleanup_sysc_leave_insn+4)
1026         be      BASED(2f)
1027         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)
1028         c       %r12,BASED(.Lmck_old_psw)
1029         bne     BASED(0f)
1030         mvc     __LC_SAVE_AREA+32(16),SP_R12(%r15)
1031         b       BASED(1f)
1032 0:      mvc     __LC_SAVE_AREA+16(16),SP_R12(%r15)
1033 1:      lm      %r0,%r11,SP_R0(%r15)
1034         l       %r15,SP_R15(%r15)
1035 2:      la      %r12,__LC_RETURN_PSW
1036         br      %r14
1037 cleanup_sysc_leave_insn:
1038         .long   sysc_done - 4 + 0x80000000
1039         .long   sysc_done - 8 + 0x80000000
1040
1041 cleanup_io_return:
1042         mvc     __LC_RETURN_PSW(4),0(%r12)
1043         mvc     __LC_RETURN_PSW+4(4),BASED(cleanup_table_io_work_loop)
1044         la      %r12,__LC_RETURN_PSW
1045         br      %r14
1046
1047 cleanup_io_leave:
1048         clc     4(4,%r12),BASED(cleanup_io_leave_insn)
1049         be      BASED(2f)
1050         mvc     __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
1051         clc     4(4,%r12),BASED(cleanup_io_leave_insn+4)
1052         be      BASED(2f)
1053         mvc     __LC_RETURN_PSW(8),SP_PSW(%r15)
1054         c       %r12,BASED(.Lmck_old_psw)
1055         bne     BASED(0f)
1056         mvc     __LC_SAVE_AREA+32(16),SP_R12(%r15)
1057         b       BASED(1f)
1058 0:      mvc     __LC_SAVE_AREA+16(16),SP_R12(%r15)
1059 1:      lm      %r0,%r11,SP_R0(%r15)
1060         l       %r15,SP_R15(%r15)
1061 2:      la      %r12,__LC_RETURN_PSW
1062         br      %r14
1063 cleanup_io_leave_insn:
1064         .long   io_done - 4 + 0x80000000
1065         .long   io_done - 8 + 0x80000000
1066
1067 /*
1068  * Integer constants
1069  */
1070                 .align  4
1071 .Lc_spsize:     .long   SP_SIZE
1072 .Lc_overhead:   .long   STACK_FRAME_OVERHEAD
1073 .Lnr_syscalls:  .long   NR_syscalls
1074 .L0x018:        .short  0x018
1075 .L0x020:        .short  0x020
1076 .L0x028:        .short  0x028
1077 .L0x030:        .short  0x030
1078 .L0x038:        .short  0x038
1079 .Lc_1:          .long   1
1080
1081 /*
1082  * Symbol constants
1083  */
1084 .Ls390_mcck:    .long   s390_do_machine_check
1085 .Ls390_handle_mcck:
1086                 .long   s390_handle_mcck
1087 .Lmck_old_psw:  .long   __LC_MCK_OLD_PSW
1088 .Ldo_IRQ:       .long   do_IRQ
1089 .Ldo_extint:    .long   do_extint
1090 .Ldo_signal:    .long   do_signal
1091 .Ldo_notify_resume:
1092                 .long   do_notify_resume
1093 .Lhandle_per:   .long   do_single_step
1094 .Ldo_execve:    .long   do_execve
1095 .Lexecve_tail:  .long   execve_tail
1096 .Ljump_table:   .long   pgm_check_table
1097 .Lschedule:     .long   schedule
1098 #ifdef CONFIG_PREEMPT
1099 .Lpreempt_schedule_irq:
1100                 .long   preempt_schedule_irq
1101 #endif
1102 .Ltrace_entry:  .long   do_syscall_trace_enter
1103 .Ltrace_exit:   .long   do_syscall_trace_exit
1104 .Lschedtail:    .long   schedule_tail
1105 .Lsysc_table:   .long   sys_call_table
1106 #ifdef CONFIG_TRACE_IRQFLAGS
1107 .Ltrace_irq_on_caller:
1108                 .long   trace_hardirqs_on_caller
1109 .Ltrace_irq_off_caller:
1110                 .long   trace_hardirqs_off_caller
1111 #endif
1112 #ifdef CONFIG_LOCKDEP
1113 .Llockdep_sys_exit:
1114                 .long   lockdep_sys_exit
1115 #endif
1116 .Lcritical_start:
1117                 .long   __critical_start + 0x80000000
1118 .Lcritical_end:
1119                 .long   __critical_end + 0x80000000
1120 .Lcleanup_critical:
1121                 .long   cleanup_critical
1122
1123                 .section .rodata, "a"
1124 #define SYSCALL(esa,esame,emu)  .long esa
1125         .globl  sys_call_table
1126 sys_call_table:
1127 #include "syscalls.S"
1128 #undef SYSCALL