SAFE public projects git trees. - safe/jmp/linux-2.6/blob - scripts/get_maintainer.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2007, Joe Perches <joe@perches.com>
   3 #           created from checkpatch.pl
   4 #
   5 # Print selected MAINTAINERS information for
   6 # the files modified in a patch or for a file
   7 #
   8 # usage: perl scripts/get_maintainers.pl [OPTIONS] <patch>
   9 #        perl scripts/get_maintainers.pl [OPTIONS] -f <file>
  10 #
  11 # Licensed under the terms of the GNU GPL License version 2
  12
  13 use strict;
  14
  15 my $P = $0;
  16 my $V = '0.20';
  17
  18 use Getopt::Long qw(:config no_auto_abbrev);
  19
  20 my $lk_path = "./";
  21 my $email = 1;
  22 my $email_usename = 1;
  23 my $email_maintainer = 1;
  24 my $email_list = 1;
  25 my $email_subscriber_list = 0;
  26 my $email_git = 1;
  27 my $email_git_penguin_chiefs = 0;
  28 my $email_git_min_signatures = 1;
  29 my $email_git_max_maintainers = 5;
  30 my $email_git_min_percent = 5;
  31 my $email_git_since = "1-year-ago";
  32 my $email_git_blame = 0;
  33 my $email_remove_duplicates = 1;
  34 my $output_multiline = 1;
  35 my $output_separator = ", ";
  36 my $scm = 0;
  37 my $web = 0;
  38 my $subsystem = 0;
  39 my $status = 0;
  40 my $from_filename = 0;
  41 my $pattern_depth = 0;
  42 my $version = 0;
  43 my $help = 0;
  44
  45 my $exit = 0;
  46
  47 my @penguin_chief = ();
  48 push(@penguin_chief,"Linus Torvalds:torvalds\@linux-foundation.org");
  49 #Andrew wants in on most everything - 2009/01/14
  50 #push(@penguin_chief,"Andrew Morton:akpm\@linux-foundation.org");
  51
  52 my @penguin_chief_names = ();
  53 foreach my $chief (@penguin_chief) {
  54     if ($chief =~ m/^(.*):(.*)/) {
  55         my $chief_name = $1;
  56         my $chief_addr = $2;
  57         push(@penguin_chief_names, $chief_name);
  58     }
  59 }
  60 my $penguin_chiefs = "\(" . join("|",@penguin_chief_names) . "\)";
  61
  62 # rfc822 email address - preloaded methods go here.
  63 my $rfc822_lwsp = "(?:(?:\\r\\n)?[ \\t])";
  64 my $rfc822_char = '[\\000-\\377]';
  65
  66 if (!GetOptions(
  67                 'email!' => \$email,
  68                 'git!' => \$email_git,
  69                 'git-chief-penguins!' => \$email_git_penguin_chiefs,
  70                 'git-min-signatures=i' => \$email_git_min_signatures,
  71                 'git-max-maintainers=i' => \$email_git_max_maintainers,
  72                 'git-min-percent=i' => \$email_git_min_percent,
  73                 'git-since=s' => \$email_git_since,
  74                 'git-blame!' => \$email_git_blame,
  75                 'remove-duplicates!' => \$email_remove_duplicates,
  76                 'm!' => \$email_maintainer,
  77                 'n!' => \$email_usename,
  78                 'l!' => \$email_list,
  79                 's!' => \$email_subscriber_list,
  80                 'multiline!' => \$output_multiline,
  81                 'separator=s' => \$output_separator,
  82                 'subsystem!' => \$subsystem,
  83                 'status!' => \$status,
  84                 'scm!' => \$scm,
  85                 'web!' => \$web,
  86                 'pattern-depth=i' => \$pattern_depth,
  87                 'f|file' => \$from_filename,
  88                 'v|version' => \$version,
  89                 'h|help' => \$help,
  90                 )) {
  91     usage();
  92     die "$P: invalid argument\n";
  93 }
  94
  95 if ($help != 0) {
  96     usage();
  97     exit 0;
  98 }
  99
 100 if ($version != 0) {
 101     print("${P} ${V}\n");
 102     exit 0;
 103 }
 104
 105 if ($#ARGV < 0) {
 106     usage();
 107     die "$P: argument missing: patchfile or -f file please\n";
 108 }
 109
 110 if ($output_separator ne ", ") {
 111     $output_multiline = 0;
 112 }
 113
 114 my $selections = $email + $scm + $status + $subsystem + $web;
 115 if ($selections == 0) {
 116     usage();
 117     die "$P:  Missing required option: email, scm, status, subsystem or web\n";
 118 }
 119
 120 if ($email &&
 121     ($email_maintainer + $email_list + $email_subscriber_list +
 122      $email_git + $email_git_penguin_chiefs + $email_git_blame) == 0) {
 123     usage();
 124     die "$P: Please select at least 1 email option\n";
 125 }
 126
 127 if (!top_of_kernel_tree($lk_path)) {
 128     die "$P: The current directory does not appear to be "
 129         . "a linux kernel source tree.\n";
 130 }
 131
 132 ## Read MAINTAINERS for type/value pairs
 133
 134 my @typevalue = ();
 135 open(MAINT, "<${lk_path}MAINTAINERS") || die "$P: Can't open MAINTAINERS\n";
 136 while (<MAINT>) {
 137     my $line = $_;
 138
 139     if ($line =~ m/^(\C):\s*(.*)/) {
 140         my $type = $1;
 141         my $value = $2;
 142
 143         ##Filename pattern matching
 144         if ($type eq "F" || $type eq "X") {
 145             $value =~ s@\.@\\\.@g;       ##Convert . to \.
 146             $value =~ s/\*/\.\*/g;       ##Convert * to .*
 147             $value =~ s/\?/\./g;         ##Convert ? to .
 148             ##if pattern is a directory and it lacks a trailing slash, add one
 149             if ((-d $value)) {
 150                 $value =~ s@([^/])$@$1/@;
 151             }
 152         }
 153         push(@typevalue, "$type:$value");
 154     } elsif (!/^(\s)*$/) {
 155         $line =~ s/\n$//g;
 156         push(@typevalue, $line);
 157     }
 158 }
 159 close(MAINT);
 160
 161 my %mailmap;
 162
 163 if ($email_remove_duplicates) {
 164     open(MAILMAP, "<${lk_path}.mailmap") || warn "$P: Can't open .mailmap\n";
 165     while (<MAILMAP>) {
 166         my $line = $_;
 167
 168         next if ($line =~ m/^\s*#/);
 169         next if ($line =~ m/^\s*$/);
 170
 171         my ($name, $address) = parse_email($line);
 172         $line = format_email($name, $address);
 173
 174         next if ($line =~ m/^\s*$/);
 175
 176         if (exists($mailmap{$name})) {
 177             my $obj = $mailmap{$name};
 178             push(@$obj, $address);
 179         } else {
 180             my @arr = ($address);
 181             $mailmap{$name} = \@arr;
 182         }
 183     }
 184     close(MAILMAP);
 185 }
 186
 187 ## use the filenames on the command line or find the filenames in the patchfiles
 188
 189 my @files = ();
 190 my @range = ();
 191
 192 foreach my $file (@ARGV) {
 193     ##if $file is a directory and it lacks a trailing slash, add one
 194     if ((-d $file)) {
 195         $file =~ s@([^/])$@$1/@;
 196     } elsif (!(-f $file)) {
 197         die "$P: file '${file}' not found\n";
 198     }
 199     if ($from_filename) {
 200         push(@files, $file);
 201     } else {
 202         my $file_cnt = @files;
 203         my $lastfile;
 204         open(PATCH, "<$file") or die "$P: Can't open ${file}\n";
 205         while (<PATCH>) {
 206             if (m/^\+\+\+\s+(\S+)/) {
 207                 my $filename = $1;
 208                 $filename =~ s@^[^/]*/@@;
 209                 $filename =~ s@\n@@;
 210                 $lastfile = $filename;
 211                 push(@files, $filename);
 212             } elsif (m/^\@\@ -(\d+),(\d+)/) {
 213                 if ($email_git_blame) {
 214                     push(@range, "$lastfile:$1:$2");
 215                 }
 216             }
 217         }
 218         close(PATCH);
 219         if ($file_cnt == @files) {
 220             warn "$P: file '${file}' doesn't appear to be a patch.  "
 221                 . "Add -f to options?\n";
 222         }
 223         @files = sort_and_uniq(@files);
 224     }
 225 }
 226
 227 my @email_to = ();
 228 my @list_to = ();
 229 my @scm = ();
 230 my @web = ();
 231 my @subsystem = ();
 232 my @status = ();
 233
 234 # Find responsible parties
 235
 236 foreach my $file (@files) {
 237
 238 #Do not match excluded file patterns
 239
 240     my $exclude = 0;
 241     foreach my $line (@typevalue) {
 242         if ($line =~ m/^(\C):\s*(.*)/) {
 243             my $type = $1;
 244             my $value = $2;
 245             if ($type eq 'X') {
 246                 if (file_match_pattern($file, $value)) {
 247                     $exclude = 1;
 248                     last;
 249                 }
 250             }
 251         }
 252     }
 253
 254     if (!$exclude) {
 255         my $tvi = 0;
 256         my %hash;
 257         foreach my $line (@typevalue) {
 258             if ($line =~ m/^(\C):\s*(.*)/) {
 259                 my $type = $1;
 260                 my $value = $2;
 261                 if ($type eq 'F') {
 262                     if (file_match_pattern($file, $value)) {
 263                         my $value_pd = ($value =~ tr@/@@);
 264                         my $file_pd = ($file  =~ tr@/@@);
 265                         $value_pd++ if (substr($value,-1,1) ne "/");
 266                         if ($pattern_depth == 0 ||
 267                             (($file_pd - $value_pd) < $pattern_depth)) {
 268                             $hash{$tvi} = $value_pd;
 269                         }
 270                     }
 271                 }
 272             }
 273             $tvi++;
 274         }
 275         foreach my $line (sort {$hash{$b} <=> $hash{$a}} keys %hash) {
 276             add_categories($line);
 277         }
 278     }
 279
 280     if ($email && $email_git) {
 281         recent_git_signoffs($file);
 282     }
 283
 284     if ($email && $email_git_blame) {
 285         git_assign_blame($file);
 286     }
 287 }
 288
 289 if ($email) {
 290     foreach my $chief (@penguin_chief) {
 291         if ($chief =~ m/^(.*):(.*)/) {
 292             my $email_address;
 293
 294             $email_address = format_email($1, $2);
 295             if ($email_git_penguin_chiefs) {
 296                 push(@email_to, $email_address);
 297             } else {
 298                 @email_to = grep(!/${email_address}/, @email_to);
 299             }
 300         }
 301     }
 302 }
 303
 304 if ($email || $email_list) {
 305     my @to = ();
 306     if ($email) {
 307         @to = (@to, @email_to);
 308     }
 309     if ($email_list) {
 310         @to = (@to, @list_to);
 311     }
 312     output(uniq(@to));
 313 }
 314
 315 if ($scm) {
 316     @scm = sort_and_uniq(@scm);
 317     output(@scm);
 318 }
 319
 320 if ($status) {
 321     @status = sort_and_uniq(@status);
 322     output(@status);
 323 }
 324
 325 if ($subsystem) {
 326     @subsystem = sort_and_uniq(@subsystem);
 327     output(@subsystem);
 328 }
 329
 330 if ($web) {
 331     @web = sort_and_uniq(@web);
 332     output(@web);
 333 }
 334
 335 exit($exit);
 336
 337 sub file_match_pattern {
 338     my ($file, $pattern) = @_;
 339     if (substr($pattern, -1) eq "/") {
 340         if ($file =~ m@^$pattern@) {
 341             return 1;
 342         }
 343     } else {
 344         if ($file =~ m@^$pattern@) {
 345             my $s1 = ($file =~ tr@/@@);
 346             my $s2 = ($pattern =~ tr@/@@);
 347             if ($s1 == $s2) {
 348                 return 1;
 349             }
 350         }
 351     }
 352     return 0;
 353 }
 354
 355 sub usage {
 356     print <<EOT;
 357 usage: $P [options] patchfile
 358        $P [options] -f file|directory
 359 version: $V
 360
 361 MAINTAINER field selection options:
 362   --email => print email address(es) if any
 363     --git => include recent git \*-by: signers
 364     --git-chief-penguins => include ${penguin_chiefs}
 365     --git-min-signatures => number of signatures required (default: 1)
 366     --git-max-maintainers => maximum maintainers to add (default: 5)
 367     --git-min-percent => minimum percentage of commits required (default: 5)
 368     --git-since => git history to use (default: 1-year-ago)
 369     --git-blame => use git blame to find modified commits for patch or file
 370     --m => include maintainer(s) if any
 371     --n => include name 'Full Name <addr\@domain.tld>'
 372     --l => include list(s) if any
 373     --s => include subscriber only list(s) if any
 374     --remove-duplicates => minimize duplicate email names/addresses
 375   --scm => print SCM tree(s) if any
 376   --status => print status if any
 377   --subsystem => print subsystem name if any
 378   --web => print website(s) if any
 379
 380 Output type options:
 381   --separator [, ] => separator for multiple entries on 1 line
 382     using --separator also sets --nomultiline if --separator is not [, ]
 383   --multiline => print 1 entry per line
 384
 385 Other options:
 386   --pattern-depth => Number of pattern directory traversals (default: 0 (all))
 387   --version => show version
 388   --help => show this help information
 389
 390 Default options:
 391   [--email --git --m --n --l --multiline --pattern-depth=0 --remove-duplicates]
 392
 393 Notes:
 394   Using "-f directory" may give unexpected results:
 395       Used with "--git", git signators for _all_ files in and below
 396           directory are examined as git recurses directories.
 397           Any specified X: (exclude) pattern matches are _not_ ignored.
 398       Used with "--nogit", directory is used as a pattern match,
 399          no individual file within the directory or subdirectory
 400          is matched.
 401       Used with "--git-blame", does not iterate all files in directory
 402   Using "--git-blame" is slow and may add old committers and authors
 403       that are no longer active maintainers to the output.
 404 EOT
 405 }
 406
 407 sub top_of_kernel_tree {
 408         my ($lk_path) = @_;
 409
 410         if ($lk_path ne "" && substr($lk_path,length($lk_path)-1,1) ne "/") {
 411             $lk_path .= "/";
 412         }
 413         if (   (-f "${lk_path}COPYING")
 414             && (-f "${lk_path}CREDITS")
 415             && (-f "${lk_path}Kbuild")
 416             && (-f "${lk_path}MAINTAINERS")
 417             && (-f "${lk_path}Makefile")
 418             && (-f "${lk_path}README")
 419             && (-d "${lk_path}Documentation")
 420             && (-d "${lk_path}arch")
 421             && (-d "${lk_path}include")
 422             && (-d "${lk_path}drivers")
 423             && (-d "${lk_path}fs")
 424             && (-d "${lk_path}init")
 425             && (-d "${lk_path}ipc")
 426             && (-d "${lk_path}kernel")
 427             && (-d "${lk_path}lib")
 428             && (-d "${lk_path}scripts")) {
 429                 return 1;
 430         }
 431         return 0;
 432 }
 433
 434 sub parse_email {
 435     my ($formatted_email) = @_;
 436
 437     my $name = "";
 438     my $address = "";
 439
 440     if ($formatted_email =~ /^([^<]+)<(.+\@.*)>.*$/) {
 441         $name = $1;
 442         $address = $2;
 443     } elsif ($formatted_email =~ /^\s*<(.+\@\S*)>.*$/) {
 444         $address = $1;
 445     } elsif ($formatted_email =~ /^(.+\@\S*)$/) {
 446         $address = $1;
 447     }
 448
 449     $name =~ s/^\s+|\s+$//g;
 450     $name =~ s/^\"|\"$//g;
 451     $address =~ s/^\s+|\s+$//g;
 452
 453     if ($name =~ /[^a-z0-9 \.\-]/i) {    ##has "must quote" chars
 454         $name =~ s/(?<!\\)"/\\"/g;       ##escape quotes
 455         $name = "\"$name\"";
 456     }
 457
 458     return ($name, $address);
 459 }
 460
 461 sub format_email {
 462     my ($name, $address) = @_;
 463
 464     my $formatted_email;
 465
 466     $name =~ s/^\s+|\s+$//g;
 467     $name =~ s/^\"|\"$//g;
 468     $address =~ s/^\s+|\s+$//g;
 469
 470     if ($name =~ /[^a-z0-9 \.\-]/i) {    ##has "must quote" chars
 471         $name =~ s/(?<!\\)"/\\"/g;       ##escape quotes
 472         $name = "\"$name\"";
 473     }
 474
 475     if ($email_usename) {
 476         if ("$name" eq "") {
 477             $formatted_email = "$address";
 478         } else {
 479             $formatted_email = "$name <${address}>";
 480         }
 481     } else {
 482         $formatted_email = $address;
 483     }
 484
 485     return $formatted_email;
 486 }
 487
 488 sub add_categories {
 489     my ($index) = @_;
 490
 491     $index = $index - 1;
 492     while ($index >= 0) {
 493         my $tv = $typevalue[$index];
 494         if ($tv =~ m/^(\C):\s*(.*)/) {
 495             my $ptype = $1;
 496             my $pvalue = $2;
 497             if ($ptype eq "L") {
 498                 my $list_address = $pvalue;
 499                 my $list_additional = "";
 500                 if ($list_address =~ m/([^\s]+)\s+(.*)$/) {
 501                     $list_address = $1;
 502                     $list_additional = $2;
 503                 }
 504                 if ($list_additional =~ m/subscribers-only/) {
 505                     if ($email_subscriber_list) {
 506                         push(@list_to, $list_address);
 507                     }
 508                 } else {
 509                     if ($email_list) {
 510                         push(@list_to, $list_address);
 511                     }
 512                 }
 513             } elsif ($ptype eq "M") {
 514                 my ($name, $address) = parse_email($pvalue);
 515                 if ($name eq "") {
 516                     if ($index >= 0) {
 517                         my $tv = $typevalue[$index - 1];
 518                         if ($tv =~ m/^(\C):\s*(.*)/) {
 519                             if ($1 eq "P") {
 520                                 $name = $2;
 521                             }
 522                         }
 523                     }
 524                 }
 525                 if ($email_maintainer) {
 526                     push_email_addresses($pvalue);
 527                 }
 528             } elsif ($ptype eq "T") {
 529                 push(@scm, $pvalue);
 530             } elsif ($ptype eq "W") {
 531                 push(@web, $pvalue);
 532             } elsif ($ptype eq "S") {
 533                 push(@status, $pvalue);
 534             }
 535
 536             $index--;
 537         } else {
 538             push(@subsystem,$tv);
 539             $index = -1;
 540         }
 541     }
 542 }
 543
 544 my %email_hash_name;
 545 my %email_hash_address;
 546
 547 sub email_inuse {
 548     my ($name, $address) = @_;
 549
 550     return 1 if (($name eq "") && ($address eq ""));
 551     return 1 if (($name ne "") && exists($email_hash_name{$name}));
 552     return 1 if (($address ne "") && exists($email_hash_address{$address}));
 553
 554     return 0;
 555 }
 556
 557 sub push_email_address {
 558     my ($line) = @_;
 559
 560     my ($name, $address) = parse_email($line);
 561
 562     if (!$email_remove_duplicates) {
 563         push(@email_to, format_email($name, $address));
 564     } elsif (!email_inuse($name, $address)) {
 565         push(@email_to, format_email($name, $address));
 566         $email_hash_name{$name}++;
 567         $email_hash_address{$address}++;
 568     }
 569 }
 570
 571 sub push_email_addresses {
 572     my ($address) = @_;
 573
 574     my @address_list = ();
 575
 576     if (rfc822_valid($address)) {
 577         push_email_address($address);
 578     } elsif (@address_list = rfc822_validlist($address)) {
 579         my $array_count = shift(@address_list);
 580         while (my $entry = shift(@address_list)) {
 581             push_email_address($entry);
 582         }
 583     } else {
 584         warn("Invalid MAINTAINERS address: '" . $address . "'\n");
 585     }
 586 }
 587
 588 sub which {
 589     my ($bin) = @_;
 590
 591     foreach my $path (split(/:/, $ENV{PATH})) {
 592         if (-e "$path/$bin") {
 593             return "$path/$bin";
 594         }
 595     }
 596
 597     return "";
 598 }
 599
 600 sub mailmap {
 601     my @lines = @_;
 602     my %hash;
 603
 604     foreach my $line (@lines) {
 605         my ($name, $address) = parse_email($line);
 606         if (!exists($hash{$name})) {
 607             $hash{$name} = $address;
 608         } elsif ($address ne $hash{$name}) {
 609             $address = $hash{$name};
 610             $line = format_email($name, $address);
 611         }
 612         if (exists($mailmap{$name})) {
 613             my $obj = $mailmap{$name};
 614             foreach my $map_address (@$obj) {
 615                 if (($map_address eq $address) &&
 616                     ($map_address ne $hash{$name})) {
 617                     $line = format_email($name, $hash{$name});
 618                 }
 619             }
 620         }
 621     }
 622
 623     return @lines;
 624 }
 625
 626 sub recent_git_signoffs {
 627     my ($file) = @_;
 628
 629     my $sign_offs = "";
 630     my $cmd = "";
 631     my $output = "";
 632     my $count = 0;
 633     my @lines = ();
 634     my %hash;
 635     my $total_sign_offs;
 636
 637     if (which("git") eq "") {
 638         warn("$P: git not found.  Add --nogit to options?\n");
 639         return;
 640     }
 641     if (!(-d ".git")) {
 642         warn("$P: .git directory not found.  Use a git repository for better results.\n");
 643         warn("$P: perhaps 'git clone git://git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux-2.6.git'\n");
 644         return;
 645     }
 646
 647     $cmd = "git log --since=${email_git_since} -- ${file}";
 648
 649     $output = `${cmd}`;
 650     $output =~ s/^\s*//gm;
 651
 652     @lines = split("\n", $output);
 653
 654     @lines = grep(/^[-_         a-z]+by:.*\@.*$/i, @lines);
 655     if (!$email_git_penguin_chiefs) {
 656         @lines = grep(!/${penguin_chiefs}/i, @lines);
 657     }
 658     # cut -f2- -d":"
 659     s/.*:\s*(.+)\s*/$1/ for (@lines);
 660
 661     $total_sign_offs = @lines;
 662
 663     if ($email_remove_duplicates) {
 664         @lines = mailmap(@lines);
 665     }
 666
 667     @lines = sort(@lines);
 668
 669     # uniq -c
 670     $hash{$_}++ for @lines;
 671
 672     # sort -rn
 673     foreach my $line (sort {$hash{$b} <=> $hash{$a}} keys %hash) {
 674         my $sign_offs = $hash{$line};
 675         $count++;
 676         last if ($sign_offs < $email_git_min_signatures ||
 677                  $count > $email_git_max_maintainers ||
 678                  $sign_offs * 100 / $total_sign_offs < $email_git_min_percent);
 679         push_email_address($line);
 680     }
 681 }
 682
 683 sub save_commits {
 684     my ($cmd, @commits) = @_;
 685     my $output;
 686     my @lines = ();
 687
 688     $output = `${cmd}`;
 689
 690     @lines = split("\n", $output);
 691     foreach my $line (@lines) {
 692         if ($line =~ m/^(\w+) /) {
 693             push (@commits, $1);
 694         }
 695     }
 696     return @commits;
 697 }
 698
 699 sub git_assign_blame {
 700     my ($file) = @_;
 701
 702     my @lines = ();
 703     my @commits = ();
 704     my $cmd;
 705     my $output;
 706     my %hash;
 707     my $total_sign_offs;
 708     my $count;
 709
 710     if (@range) {
 711         foreach my $file_range_diff (@range) {
 712             next if (!($file_range_diff =~ m/(.+):(.+):(.+)/));
 713             my $diff_file = $1;
 714             my $diff_start = $2;
 715             my $diff_length = $3;
 716             next if (!("$file" eq "$diff_file"));
 717             $cmd = "git blame -l -L $diff_start,+$diff_length $file";
 718             @commits = save_commits($cmd, @commits);
 719         }
 720     } else {
 721         if (-f $file) {
 722             $cmd = "git blame -l $file";
 723             @commits = save_commits($cmd, @commits);
 724         }
 725     }
 726
 727     $total_sign_offs = 0;
 728     @commits = uniq(@commits);
 729     foreach my $commit (@commits) {
 730         $cmd = "git log -1 ${commit}";
 731
 732         $output = `${cmd}`;
 733         $output =~ s/^\s*//gm;
 734         @lines = split("\n", $output);
 735
 736         @lines = grep(/^[-_     a-z]+by:.*\@.*$/i, @lines);
 737         if (!$email_git_penguin_chiefs) {
 738             @lines = grep(!/${penguin_chiefs}/i, @lines);
 739         }
 740
 741         # cut -f2- -d":"
 742         s/.*:\s*(.+)\s*/$1/ for (@lines);
 743
 744         $total_sign_offs += @lines;
 745
 746         if ($email_remove_duplicates) {
 747             @lines = mailmap(@lines);
 748         }
 749
 750         $hash{$_}++ for @lines;
 751     }
 752
 753     $count = 0;
 754     foreach my $line (sort {$hash{$b} <=> $hash{$a}} keys %hash) {
 755         my $sign_offs = $hash{$line};
 756         $count++;
 757         last if ($sign_offs < $email_git_min_signatures ||
 758                  $count > $email_git_max_maintainers ||
 759                  $sign_offs * 100 / $total_sign_offs < $email_git_min_percent);
 760         push_email_address($line);
 761     }
 762 }
 763
 764 sub uniq {
 765     my @parms = @_;
 766
 767     my %saw;
 768     @parms = grep(!$saw{$_}++, @parms);
 769     return @parms;
 770 }
 771
 772 sub sort_and_uniq {
 773     my @parms = @_;
 774
 775     my %saw;
 776     @parms = sort @parms;
 777     @parms = grep(!$saw{$_}++, @parms);
 778     return @parms;
 779 }
 780
 781 sub output {
 782     my @parms = @_;
 783
 784     if ($output_multiline) {
 785         foreach my $line (@parms) {
 786             print("${line}\n");
 787         }
 788     } else {
 789         print(join($output_separator, @parms));
 790         print("\n");
 791     }
 792 }
 793
 794 my $rfc822re;
 795
 796 sub make_rfc822re {
 797 #   Basic lexical tokens are specials, domain_literal, quoted_string, atom, and
 798 #   comment.  We must allow for rfc822_lwsp (or comments) after each of these.
 799 #   This regexp will only work on addresses which have had comments stripped
 800 #   and replaced with rfc822_lwsp.
 801
 802     my $specials = '()<>@,;:\\\\".\\[\\]';
 803     my $controls = '\\000-\\037\\177';
 804
 805     my $dtext = "[^\\[\\]\\r\\\\]";
 806     my $domain_literal = "\\[(?:$dtext|\\\\.)*\\]$rfc822_lwsp*";
 807
 808     my $quoted_string = "\"(?:[^\\\"\\r\\\\]|\\\\.|$rfc822_lwsp)*\"$rfc822_lwsp*";
 809
 810 #   Use zero-width assertion to spot the limit of an atom.  A simple
 811 #   $rfc822_lwsp* causes the regexp engine to hang occasionally.
 812     my $atom = "[^$specials $controls]+(?:$rfc822_lwsp+|\\Z|(?=[\\[\"$specials]))";
 813     my $word = "(?:$atom|$quoted_string)";
 814     my $localpart = "$word(?:\\.$rfc822_lwsp*$word)*";
 815
 816     my $sub_domain = "(?:$atom|$domain_literal)";
 817     my $domain = "$sub_domain(?:\\.$rfc822_lwsp*$sub_domain)*";
 818
 819     my $addr_spec = "$localpart\@$rfc822_lwsp*$domain";
 820
 821     my $phrase = "$word*";
 822     my $route = "(?:\@$domain(?:,\@$rfc822_lwsp*$domain)*:$rfc822_lwsp*)";
 823     my $route_addr = "\\<$rfc822_lwsp*$route?$addr_spec\\>$rfc822_lwsp*";
 824     my $mailbox = "(?:$addr_spec|$phrase$route_addr)";
 825
 826     my $group = "$phrase:$rfc822_lwsp*(?:$mailbox(?:,\\s*$mailbox)*)?;\\s*";
 827     my $address = "(?:$mailbox|$group)";
 828
 829     return "$rfc822_lwsp*$address";
 830 }
 831
 832 sub rfc822_strip_comments {
 833     my $s = shift;
 834 #   Recursively remove comments, and replace with a single space.  The simpler
 835 #   regexps in the Email Addressing FAQ are imperfect - they will miss escaped
 836 #   chars in atoms, for example.
 837
 838     while ($s =~ s/^((?:[^"\\]|\\.)*
 839                     (?:"(?:[^"\\]|\\.)*"(?:[^"\\]|\\.)*)*)
 840                     \((?:[^()\\]|\\.)*\)/$1 /osx) {}
 841     return $s;
 842 }
 843
 844 #   valid: returns true if the parameter is an RFC822 valid address
 845 #
 846 sub rfc822_valid ($) {
 847     my $s = rfc822_strip_comments(shift);
 848
 849     if (!$rfc822re) {
 850         $rfc822re = make_rfc822re();
 851     }
 852
 853     return $s =~ m/^$rfc822re$/so && $s =~ m/^$rfc822_char*$/;
 854 }
 855
 856 #   validlist: In scalar context, returns true if the parameter is an RFC822
 857 #              valid list of addresses.
 858 #
 859 #              In list context, returns an empty list on failure (an invalid
 860 #              address was found); otherwise a list whose first element is the
 861 #              number of addresses found and whose remaining elements are the
 862 #              addresses.  This is needed to disambiguate failure (invalid)
 863 #              from success with no addresses found, because an empty string is
 864 #              a valid list.
 865
 866 sub rfc822_validlist ($) {
 867     my $s = rfc822_strip_comments(shift);
 868
 869     if (!$rfc822re) {
 870         $rfc822re = make_rfc822re();
 871     }
 872     # * null list items are valid according to the RFC
 873     # * the '1' business is to aid in distinguishing failure from no results
 874
 875     my @r;
 876     if ($s =~ m/^(?:$rfc822re)?(?:,(?:$rfc822re)?)*$/so &&
 877         $s =~ m/^$rfc822_char*$/) {
 878         while ($s =~ m/(?:^|,$rfc822_lwsp*)($rfc822re)/gos) {
 879             push @r, $1;
 880         }
 881         return wantarray ? (scalar(@r), @r) : 1;
 882     }
 883     else {
 884         return wantarray ? () : 0;
 885     }
 886 }