SAFE public projects git trees. - safe/jmp/linux-2.6/blob - include/asm-generic/vmlinux.lds.h

   1 #ifndef LOAD_OFFSET
   2 #define LOAD_OFFSET 0
   3 #endif
   4
   5 #ifndef VMLINUX_SYMBOL
   6 #define VMLINUX_SYMBOL(_sym_) _sym_
   7 #endif
   8
   9 /* Align . to a 8 byte boundary equals to maximum function alignment. */
  10 #define ALIGN_FUNCTION()  . = ALIGN(8)
  11
  12 /* The actual configuration determine if the init/exit sections
  13  * are handled as text/data or they can be discarded (which
  14  * often happens at runtime)
  15  */
  16 #ifdef CONFIG_HOTPLUG
  17 #define DEV_KEEP(sec)    *(.dev##sec)
  18 #define DEV_DISCARD(sec)
  19 #else
  20 #define DEV_KEEP(sec)
  21 #define DEV_DISCARD(sec) *(.dev##sec)
  22 #endif
  23
  24 #ifdef CONFIG_HOTPLUG_CPU
  25 #define CPU_KEEP(sec)    *(.cpu##sec)
  26 #define CPU_DISCARD(sec)
  27 #else
  28 #define CPU_KEEP(sec)
  29 #define CPU_DISCARD(sec) *(.cpu##sec)
  30 #endif
  31
  32 #if defined(CONFIG_MEMORY_HOTPLUG)
  33 #define MEM_KEEP(sec)    *(.mem##sec)
  34 #define MEM_DISCARD(sec)
  35 #else
  36 #define MEM_KEEP(sec)
  37 #define MEM_DISCARD(sec) *(.mem##sec)
  38 #endif
  39
  40
  41 /* .data section */
  42 #define DATA_DATA                                                       \
  43         *(.data)                                                        \
  44         *(.data.init.refok)                                             \
  45         DEV_KEEP(init.data)                                             \
  46         DEV_KEEP(exit.data)                                             \
  47         CPU_KEEP(init.data)                                             \
  48         CPU_KEEP(exit.data)                                             \
  49         MEM_KEEP(init.data)                                             \
  50         MEM_KEEP(exit.data)                                             \
  51         . = ALIGN(8);                                                   \
  52         VMLINUX_SYMBOL(__start___markers) = .;                          \
  53         *(__markers)                                                    \
  54         VMLINUX_SYMBOL(__stop___markers) = .;
  55
  56 #define RO_DATA(align)                                                  \
  57         . = ALIGN((align));                                             \
  58         .rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {           \
  59                 VMLINUX_SYMBOL(__start_rodata) = .;                     \
  60                 *(.rodata) *(.rodata.*)                                 \
  61                 *(__vermagic)           /* Kernel version magic */      \
  62                 *(__markers_strings)    /* Markers: strings */          \
  63         }                                                               \
  64                                                                         \
  65         .rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {          \
  66                 *(.rodata1)                                             \
  67         }                                                               \
  68                                                                         \
  69         /* PCI quirks */                                                \
  70         .pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {        \
  71                 VMLINUX_SYMBOL(__start_pci_fixups_early) = .;           \
  72                 *(.pci_fixup_early)                                     \
  73                 VMLINUX_SYMBOL(__end_pci_fixups_early) = .;             \
  74                 VMLINUX_SYMBOL(__start_pci_fixups_header) = .;          \
  75                 *(.pci_fixup_header)                                    \
  76                 VMLINUX_SYMBOL(__end_pci_fixups_header) = .;            \
  77                 VMLINUX_SYMBOL(__start_pci_fixups_final) = .;           \
  78                 *(.pci_fixup_final)                                     \
  79                 VMLINUX_SYMBOL(__end_pci_fixups_final) = .;             \
  80                 VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;          \
  81                 *(.pci_fixup_enable)                                    \
  82                 VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;            \
  83                 VMLINUX_SYMBOL(__start_pci_fixups_resume) = .;          \
  84                 *(.pci_fixup_resume)                                    \
  85                 VMLINUX_SYMBOL(__end_pci_fixups_resume) = .;            \
  86         }                                                               \
  87                                                                         \
  88         /* RapidIO route ops */                                         \
  89         .rio_route        : AT(ADDR(.rio_route) - LOAD_OFFSET) {        \
  90                 VMLINUX_SYMBOL(__start_rio_route_ops) = .;              \
  91                 *(.rio_route_ops)                                       \
  92                 VMLINUX_SYMBOL(__end_rio_route_ops) = .;                \
  93         }                                                               \
  94                                                                         \
  95         /* Kernel symbol table: Normal symbols */                       \
  96         __ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {         \
  97                 VMLINUX_SYMBOL(__start___ksymtab) = .;                  \
  98                 *(__ksymtab)                                            \
  99                 VMLINUX_SYMBOL(__stop___ksymtab) = .;                   \
 100         }                                                               \
 101                                                                         \
 102         /* Kernel symbol table: GPL-only symbols */                     \
 103         __ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {     \
 104                 VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;              \
 105                 *(__ksymtab_gpl)                                        \
 106                 VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;               \
 107         }                                                               \
 108                                                                         \
 109         /* Kernel symbol table: Normal unused symbols */                \
 110         __ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {  \
 111                 VMLINUX_SYMBOL(__start___ksymtab_unused) = .;           \
 112                 *(__ksymtab_unused)                                     \
 113                 VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;            \
 114         }                                                               \
 115                                                                         \
 116         /* Kernel symbol table: GPL-only unused symbols */              \
 117         __ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
 118                 VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;       \
 119                 *(__ksymtab_unused_gpl)                                 \
 120                 VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;        \
 121         }                                                               \
 122                                                                         \
 123         /* Kernel symbol table: GPL-future-only symbols */              \
 124         __ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
 125                 VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;       \
 126                 *(__ksymtab_gpl_future)                                 \
 127                 VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;        \
 128         }                                                               \
 129                                                                         \
 130         /* Kernel symbol table: Normal symbols */                       \
 131         __kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {         \
 132                 VMLINUX_SYMBOL(__start___kcrctab) = .;                  \
 133                 *(__kcrctab)                                            \
 134                 VMLINUX_SYMBOL(__stop___kcrctab) = .;                   \
 135         }                                                               \
 136                                                                         \
 137         /* Kernel symbol table: GPL-only symbols */                     \
 138         __kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {     \
 139                 VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;              \
 140                 *(__kcrctab_gpl)                                        \
 141                 VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;               \
 142         }                                                               \
 143                                                                         \
 144         /* Kernel symbol table: Normal unused symbols */                \
 145         __kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {  \
 146                 VMLINUX_SYMBOL(__start___kcrctab_unused) = .;           \
 147                 *(__kcrctab_unused)                                     \
 148                 VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;            \
 149         }                                                               \
 150                                                                         \
 151         /* Kernel symbol table: GPL-only unused symbols */              \
 152         __kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
 153                 VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;       \
 154                 *(__kcrctab_unused_gpl)                                 \
 155                 VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;        \
 156         }                                                               \
 157                                                                         \
 158         /* Kernel symbol table: GPL-future-only symbols */              \
 159         __kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
 160                 VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;       \
 161                 *(__kcrctab_gpl_future)                                 \
 162                 VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;        \
 163         }                                                               \
 164                                                                         \
 165         /* Kernel symbol table: strings */                              \
 166         __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
 167                 *(__ksymtab_strings)                                    \
 168         }                                                               \
 169                                                                         \
 170         /* __*init sections */                                          \
 171         __init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {         \
 172                 DEV_KEEP(init.rodata)                                   \
 173                 DEV_KEEP(exit.rodata)                                   \
 174                 CPU_KEEP(init.rodata)                                   \
 175                 CPU_KEEP(exit.rodata)                                   \
 176                 MEM_KEEP(init.rodata)                                   \
 177                 MEM_KEEP(exit.rodata)                                   \
 178         }                                                               \
 179                                                                         \
 180         /* Built-in module parameters. */                               \
 181         __param : AT(ADDR(__param) - LOAD_OFFSET) {                     \
 182                 VMLINUX_SYMBOL(__start___param) = .;                    \
 183                 *(__param)                                              \
 184                 VMLINUX_SYMBOL(__stop___param) = .;                     \
 185                 VMLINUX_SYMBOL(__end_rodata) = .;                       \
 186         }                                                               \
 187         . = ALIGN((align));
 188
 189 /* RODATA provided for backward compatibility.
 190  * All archs are supposed to use RO_DATA() */
 191 #define RODATA RO_DATA(4096)
 192
 193 #define SECURITY_INIT                                                   \
 194         .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
 195                 VMLINUX_SYMBOL(__security_initcall_start) = .;          \
 196                 *(.security_initcall.init)                              \
 197                 VMLINUX_SYMBOL(__security_initcall_end) = .;            \
 198         }
 199
 200 /* .text section. Map to function alignment to avoid address changes
 201  * during second ld run in second ld pass when generating System.map */
 202 #define TEXT_TEXT                                                       \
 203                 ALIGN_FUNCTION();                                       \
 204                 *(.text)                                                \
 205                 *(.text.init.refok)                                     \
 206                 *(.exit.text.refok)                                     \
 207         DEV_KEEP(init.text)                                             \
 208         DEV_KEEP(exit.text)                                             \
 209         CPU_KEEP(init.text)                                             \
 210         CPU_KEEP(exit.text)                                             \
 211         MEM_KEEP(init.text)                                             \
 212         MEM_KEEP(exit.text)
 213
 214
 215 /* sched.text is aling to function alignment to secure we have same
 216  * address even at second ld pass when generating System.map */
 217 #define SCHED_TEXT                                                      \
 218                 ALIGN_FUNCTION();                                       \
 219                 VMLINUX_SYMBOL(__sched_text_start) = .;                 \
 220                 *(.sched.text)                                          \
 221                 VMLINUX_SYMBOL(__sched_text_end) = .;
 222
 223 /* spinlock.text is aling to function alignment to secure we have same
 224  * address even at second ld pass when generating System.map */
 225 #define LOCK_TEXT                                                       \
 226                 ALIGN_FUNCTION();                                       \
 227                 VMLINUX_SYMBOL(__lock_text_start) = .;                  \
 228                 *(.spinlock.text)                                       \
 229                 VMLINUX_SYMBOL(__lock_text_end) = .;
 230
 231 #define KPROBES_TEXT                                                    \
 232                 ALIGN_FUNCTION();                                       \
 233                 VMLINUX_SYMBOL(__kprobes_text_start) = .;               \
 234                 *(.kprobes.text)                                        \
 235                 VMLINUX_SYMBOL(__kprobes_text_end) = .;
 236
 237 /* init and exit section handling */
 238 #define INIT_DATA                                                       \
 239         *(.init.data)                                                   \
 240         DEV_DISCARD(init.data)                                          \
 241         DEV_DISCARD(init.rodata)                                        \
 242         CPU_DISCARD(init.data)                                          \
 243         CPU_DISCARD(init.rodata)                                        \
 244         MEM_DISCARD(init.data)                                          \
 245         MEM_DISCARD(init.rodata)
 246
 247 #define INIT_TEXT                                                       \
 248         *(.init.text)                                                   \
 249         DEV_DISCARD(init.text)                                          \
 250         CPU_DISCARD(init.text)                                          \
 251         MEM_DISCARD(init.text)
 252
 253 #define EXIT_DATA                                                       \
 254         *(.exit.data)                                                   \
 255         DEV_DISCARD(exit.data)                                          \
 256         DEV_DISCARD(exit.rodata)                                        \
 257         CPU_DISCARD(exit.data)                                          \
 258         CPU_DISCARD(exit.rodata)                                        \
 259         MEM_DISCARD(exit.data)                                          \
 260         MEM_DISCARD(exit.rodata)
 261
 262 #define EXIT_TEXT                                                       \
 263         *(.exit.text)                                                   \
 264         DEV_DISCARD(exit.text)                                          \
 265         CPU_DISCARD(exit.text)                                          \
 266         MEM_DISCARD(exit.text)
 267
 268                 /* DWARF debug sections.
 269                 Symbols in the DWARF debugging sections are relative to
 270                 the beginning of the section so we begin them at 0.  */
 271 #define DWARF_DEBUG                                                     \
 272                 /* DWARF 1 */                                           \
 273                 .debug          0 : { *(.debug) }                       \
 274                 .line           0 : { *(.line) }                        \
 275                 /* GNU DWARF 1 extensions */                            \
 276                 .debug_srcinfo  0 : { *(.debug_srcinfo) }               \
 277                 .debug_sfnames  0 : { *(.debug_sfnames) }               \
 278                 /* DWARF 1.1 and DWARF 2 */                             \
 279                 .debug_aranges  0 : { *(.debug_aranges) }               \
 280                 .debug_pubnames 0 : { *(.debug_pubnames) }              \
 281                 /* DWARF 2 */                                           \
 282                 .debug_info     0 : { *(.debug_info                     \
 283                                 .gnu.linkonce.wi.*) }                   \
 284                 .debug_abbrev   0 : { *(.debug_abbrev) }                \
 285                 .debug_line     0 : { *(.debug_line) }                  \
 286                 .debug_frame    0 : { *(.debug_frame) }                 \
 287                 .debug_str      0 : { *(.debug_str) }                   \
 288                 .debug_loc      0 : { *(.debug_loc) }                   \
 289                 .debug_macinfo  0 : { *(.debug_macinfo) }               \
 290                 /* SGI/MIPS DWARF 2 extensions */                       \
 291                 .debug_weaknames 0 : { *(.debug_weaknames) }            \
 292                 .debug_funcnames 0 : { *(.debug_funcnames) }            \
 293                 .debug_typenames 0 : { *(.debug_typenames) }            \
 294                 .debug_varnames  0 : { *(.debug_varnames) }             \
 295
 296                 /* Stabs debugging sections.  */
 297 #define STABS_DEBUG                                                     \
 298                 .stab 0 : { *(.stab) }                                  \
 299                 .stabstr 0 : { *(.stabstr) }                            \
 300                 .stab.excl 0 : { *(.stab.excl) }                        \
 301                 .stab.exclstr 0 : { *(.stab.exclstr) }                  \
 302                 .stab.index 0 : { *(.stab.index) }                      \
 303                 .stab.indexstr 0 : { *(.stab.indexstr) }                \
 304                 .comment 0 : { *(.comment) }
 305
 306 #define BUG_TABLE                                                       \
 307         . = ALIGN(8);                                                   \
 308         __bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {             \
 309                 __start___bug_table = .;                                \
 310                 *(__bug_table)                                          \
 311                 __stop___bug_table = .;                                 \
 312         }
 313
 314 #define NOTES                                                           \
 315         .notes : AT(ADDR(.notes) - LOAD_OFFSET) {                       \
 316                 VMLINUX_SYMBOL(__start_notes) = .;                      \
 317                 *(.note.*)                                              \
 318                 VMLINUX_SYMBOL(__stop_notes) = .;                       \
 319         }
 320
 321 #define INITCALLS                                                       \
 322         *(.initcall0.init)                                              \
 323         *(.initcall0s.init)                                             \
 324         *(.initcall1.init)                                              \
 325         *(.initcall1s.init)                                             \
 326         *(.initcall2.init)                                              \
 327         *(.initcall2s.init)                                             \
 328         *(.initcall3.init)                                              \
 329         *(.initcall3s.init)                                             \
 330         *(.initcall4.init)                                              \
 331         *(.initcall4s.init)                                             \
 332         *(.initcall5.init)                                              \
 333         *(.initcall5s.init)                                             \
 334         *(.initcallrootfs.init)                                         \
 335         *(.initcall6.init)                                              \
 336         *(.initcall6s.init)                                             \
 337         *(.initcall7.init)                                              \
 338         *(.initcall7s.init)
 339
 340 #define PERCPU(align)                                                   \
 341         . = ALIGN(align);                                               \
 342         __per_cpu_start = .;                                            \
 343         .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) {          \
 344                 *(.data.percpu)                                         \
 345                 *(.data.percpu.shared_aligned)                          \
 346         }                                                               \
 347         __per_cpu_end = .;