SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 SECTIONS
  17 {
  18   . = __START_KERNEL;
  19   phys_startup_64 = startup_64 - LOAD_OFFSET;
  20   _text = .;                    /* Text and read-only data */
  21   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  22         /* First the code that has to be first for bootstrapping */
  23         *(.bootstrap.text)
  24         /* Then all the functions that are "hot" in profiles, to group them
  25            onto the same hugetlb entry */
  26         #include "functionlist"
  27         /* Then the rest */
  28         *(.text)
  29         SCHED_TEXT
  30         LOCK_TEXT
  31         KPROBES_TEXT
  32         *(.fixup)
  33         *(.gnu.warning)
  34         } = 0x9090
  35                                 /* out-of-line lock text */
  36   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  37
  38   _etext = .;                   /* End of text section */
  39
  40   . = ALIGN(16);                /* Exception table */
  41   __start___ex_table = .;
  42   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  43   __stop___ex_table = .;
  44
  45   RODATA
  46
  47 #ifdef CONFIG_STACK_UNWIND
  48   . = ALIGN(8);
  49   .eh_frame : AT(ADDR(.eh_frame) - LOAD_OFFSET) {
  50         __start_unwind = .;
  51         *(.eh_frame)
  52         __end_unwind = .;
  53   }
  54 #endif
  55
  56                                 /* Data */
  57   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  58         *(.data)
  59         CONSTRUCTORS
  60         }
  61
  62   _edata = .;                   /* End of data section */
  63
  64   __bss_start = .;              /* BSS */
  65   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
  66         *(.bss.page_aligned)
  67         *(.bss)
  68         }
  69   __bss_stop = .;
  70
  71   . = ALIGN(PAGE_SIZE);
  72   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  73   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  74         *(.data.cacheline_aligned)
  75   }
  76   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  77   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  78         *(.data.read_mostly)
  79   }
  80
  81 #define VSYSCALL_ADDR (-10*1024*1024)
  82 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  83 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  84
  85 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  86 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  87
  88 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  89 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  90
  91   . = VSYSCALL_ADDR;
  92   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) }
  93   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  94
  95   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  96   .xtime_lock : AT(VLOAD(.xtime_lock)) { *(.xtime_lock) }
  97   xtime_lock = VVIRT(.xtime_lock);
  98
  99   .vxtime : AT(VLOAD(.vxtime)) { *(.vxtime) }
 100   vxtime = VVIRT(.vxtime);
 101
 102   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
 103   vgetcpu_mode = VVIRT(.vgetcpu_mode);
 104
 105   .wall_jiffies : AT(VLOAD(.wall_jiffies)) { *(.wall_jiffies) }
 106   wall_jiffies = VVIRT(.wall_jiffies);
 107
 108   .sys_tz : AT(VLOAD(.sys_tz)) { *(.sys_tz) }
 109   sys_tz = VVIRT(.sys_tz);
 110
 111   .sysctl_vsyscall : AT(VLOAD(.sysctl_vsyscall)) { *(.sysctl_vsyscall) }
 112   sysctl_vsyscall = VVIRT(.sysctl_vsyscall);
 113
 114   .xtime : AT(VLOAD(.xtime)) { *(.xtime) }
 115   xtime = VVIRT(.xtime);
 116
 117   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 118   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 119   jiffies = VVIRT(.jiffies);
 120
 121   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) { *(.vsyscall_1) }
 122   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) { *(.vsyscall_2) }
 123   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) { *(.vsyscall_3) }
 124
 125   . = VSYSCALL_VIRT_ADDR + 4096;
 126
 127 #undef VSYSCALL_ADDR
 128 #undef VSYSCALL_PHYS_ADDR
 129 #undef VSYSCALL_VIRT_ADDR
 130 #undef VLOAD_OFFSET
 131 #undef VLOAD
 132 #undef VVIRT_OFFSET
 133 #undef VVIRT
 134
 135   . = ALIGN(8192);              /* init_task */
 136   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 137         *(.data.init_task)
 138   }
 139
 140   . = ALIGN(4096);
 141   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 142         *(.data.page_aligned)
 143   }
 144
 145   /* might get freed after init */
 146   . = ALIGN(4096);
 147   __smp_alt_begin = .;
 148   __smp_alt_instructions = .;
 149   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
 150         *(.smp_altinstructions)
 151   }
 152   __smp_alt_instructions_end = .;
 153   . = ALIGN(8);
 154   __smp_locks = .;
 155   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 156         *(.smp_locks)
 157   }
 158   __smp_locks_end = .;
 159   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 160         *(.smp_altinstr_replacement)
 161   }
 162   . = ALIGN(4096);
 163   __smp_alt_end = .;
 164
 165   . = ALIGN(4096);              /* Init code and data */
 166   __init_begin = .;
 167   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 168         _sinittext = .;
 169         *(.init.text)
 170         _einittext = .;
 171   }
 172   __initdata_begin = .;
 173   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 174   __initdata_end = .;
 175   . = ALIGN(16);
 176   __setup_start = .;
 177   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 178   __setup_end = .;
 179   __initcall_start = .;
 180   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 181         *(.initcall1.init)
 182         *(.initcall2.init)
 183         *(.initcall3.init)
 184         *(.initcall4.init)
 185         *(.initcall5.init)
 186         *(.initcall6.init)
 187         *(.initcall7.init)
 188   }
 189   __initcall_end = .;
 190   __con_initcall_start = .;
 191   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 192         *(.con_initcall.init)
 193   }
 194   __con_initcall_end = .;
 195   SECURITY_INIT
 196   . = ALIGN(8);
 197   __alt_instructions = .;
 198   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 199         *(.altinstructions)
 200   }
 201   __alt_instructions_end = .;
 202   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 203         *(.altinstr_replacement)
 204   }
 205   /* .exit.text is discard at runtime, not link time, to deal with references
 206      from .altinstructions and .eh_frame */
 207   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 208   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 209   . = ALIGN(4096);
 210   __initramfs_start = .;
 211   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 212   __initramfs_end = .;
 213   /* temporary here to work around NR_CPUS. If you see this comment in 2.6.17+
 214    complain */
 215   . = ALIGN(4096);
 216   __init_end = .;
 217   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 218   __per_cpu_start = .;
 219   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 220   __per_cpu_end = .;
 221
 222   . = ALIGN(4096);
 223   __nosave_begin = .;
 224   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 225   . = ALIGN(4096);
 226   __nosave_end = .;
 227
 228   _end = . ;
 229
 230   /* Sections to be discarded */
 231   /DISCARD/ : {
 232         *(.exitcall.exit)
 233 #ifndef CONFIG_UNWIND_INFO
 234         *(.eh_frame)
 235 #endif
 236         }
 237
 238   STABS_DEBUG
 239
 240   DWARF_DEBUG
 241 }