SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/x86_64/kernel/head.S

   1 /*
   2  *  linux/arch/x86_64/kernel/head.S -- start in 32bit and switch to 64bit
   3  *
   4  *  Copyright (C) 2000 Andrea Arcangeli <andrea@suse.de> SuSE
   5  *  Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
   6  *  Copyright (C) 2000 Karsten Keil <kkeil@suse.de>
   7  *  Copyright (C) 2001,2002 Andi Kleen <ak@suse.de>
   8  */
   9
  10
  11 #include <linux/linkage.h>
  12 #include <linux/threads.h>
  13 #include <linux/init.h>
  14 #include <asm/desc.h>
  15 #include <asm/segment.h>
  16 #include <asm/pgtable.h>
  17 #include <asm/page.h>
  18 #include <asm/msr.h>
  19 #include <asm/cache.h>
  20
  21 /* we are not able to switch in one step to the final KERNEL ADRESS SPACE
  22  * because we need identity-mapped pages on setup so define __START_KERNEL to
  23  * 0x100000 for this stage
  24  *
  25  */
  26
  27         .text
  28         .section .bootstrap.text
  29         .code32
  30         .globl startup_32
  31 /* %bx:  1 if coming from smp trampoline on secondary cpu */
  32 startup_32:
  33
  34         /*
  35          * At this point the CPU runs in 32bit protected mode (CS.D = 1) with
  36          * paging disabled and the point of this file is to switch to 64bit
  37          * long mode with a kernel mapping for kerneland to jump into the
  38          * kernel virtual addresses.
  39          * There is no stack until we set one up.
  40          */
  41
  42         /* Initialize the %ds segment register */
  43         movl $__KERNEL_DS,%eax
  44         movl %eax,%ds
  45
  46         /* Load new GDT with the 64bit segments using 32bit descriptor */
  47         lgdt    pGDT32 - __START_KERNEL_map
  48
  49         /* If the CPU doesn't support CPUID this will double fault.
  50          * Unfortunately it is hard to check for CPUID without a stack.
  51          */
  52
  53         /* Check if extended functions are implemented */
  54         movl    $0x80000000, %eax
  55         cpuid
  56         cmpl    $0x80000000, %eax
  57         jbe     no_long_mode
  58         /* Check if long mode is implemented */
  59         mov     $0x80000001, %eax
  60         cpuid
  61         btl     $29, %edx
  62         jnc     no_long_mode
  63
  64         /*
  65          * Prepare for entering 64bits mode
  66          */
  67
  68         /* Enable PAE mode */
  69         xorl    %eax, %eax
  70         btsl    $5, %eax
  71         movl    %eax, %cr4
  72
  73         /* Setup early boot stage 4 level pagetables */
  74         movl    $(boot_level4_pgt - __START_KERNEL_map), %eax
  75         movl    %eax, %cr3
  76
  77         /* Setup EFER (Extended Feature Enable Register) */
  78         movl    $MSR_EFER, %ecx
  79         rdmsr
  80
  81         /* Enable Long Mode */
  82         btsl    $_EFER_LME, %eax
  83
  84         /* Make changes effective */
  85         wrmsr
  86
  87         xorl    %eax, %eax
  88         btsl    $31, %eax                       /* Enable paging and in turn activate Long Mode */
  89         btsl    $0, %eax                        /* Enable protected mode */
  90         /* Make changes effective */
  91         movl    %eax, %cr0
  92         /*
  93          * At this point we're in long mode but in 32bit compatibility mode
  94          * with EFER.LME = 1, CS.L = 0, CS.D = 1 (and in turn
  95          * EFER.LMA = 1). Now we want to jump in 64bit mode, to do that we use
  96          * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
  97          */
  98         ljmp    $__KERNEL_CS, $(startup_64 - __START_KERNEL_map)
  99
 100         .code64
 101         .org 0x100
 102         .globl startup_64
 103 startup_64:
 104         /* We come here either from startup_32
 105          * or directly from a 64bit bootloader.
 106          * Since we may have come directly from a bootloader we
 107          * reload the page tables here.
 108          */
 109
 110         /* Enable PAE mode and PGE */
 111         xorq    %rax, %rax
 112         btsq    $5, %rax
 113         btsq    $7, %rax
 114         movq    %rax, %cr4
 115
 116         /* Setup early boot stage 4 level pagetables. */
 117         movq    $(boot_level4_pgt - __START_KERNEL_map), %rax
 118         movq    %rax, %cr3
 119
 120         /* Check if nx is implemented */
 121         movl    $0x80000001, %eax
 122         cpuid
 123         movl    %edx,%edi
 124
 125         /* Setup EFER (Extended Feature Enable Register) */
 126         movl    $MSR_EFER, %ecx
 127         rdmsr
 128
 129         /* Enable System Call */
 130         btsl    $_EFER_SCE, %eax
 131
 132         /* No Execute supported? */
 133         btl     $20,%edi
 134         jnc     1f
 135         btsl    $_EFER_NX, %eax
 136 1:
 137         /* Make changes effective */
 138         wrmsr
 139
 140         /* Setup cr0 */
 141 #define CR0_PM                          1               /* protected mode */
 142 #define CR0_MP                          (1<<1)
 143 #define CR0_ET                          (1<<4)
 144 #define CR0_NE                          (1<<5)
 145 #define CR0_WP                          (1<<16)
 146 #define CR0_AM                          (1<<18)
 147 #define CR0_PAGING                      (1<<31)
 148         movl $CR0_PM|CR0_MP|CR0_ET|CR0_NE|CR0_WP|CR0_AM|CR0_PAGING,%eax
 149         /* Make changes effective */
 150         movq    %rax, %cr0
 151
 152         /* Setup a boot time stack */
 153         movq init_rsp(%rip),%rsp
 154
 155         /* zero EFLAGS after setting rsp */
 156         pushq $0
 157         popfq
 158
 159         /*
 160          * We must switch to a new descriptor in kernel space for the GDT
 161          * because soon the kernel won't have access anymore to the userspace
 162          * addresses where we're currently running on. We have to do that here
 163          * because in 32bit we couldn't load a 64bit linear address.
 164          */
 165         lgdt    cpu_gdt_descr
 166
 167         /* set up data segments. actually 0 would do too */
 168         movl $__KERNEL_DS,%eax
 169         movl %eax,%ds
 170         movl %eax,%ss
 171         movl %eax,%es
 172
 173         /*
 174          * We don't really need to load %fs or %gs, but load them anyway
 175          * to kill any stale realmode selectors.  This allows execution
 176          * under VT hardware.
 177          */
 178         movl %eax,%fs
 179         movl %eax,%gs
 180
 181         /*
 182          * Setup up a dummy PDA. this is just for some early bootup code
 183          * that does in_interrupt()
 184          */
 185         movl    $MSR_GS_BASE,%ecx
 186         movq    $empty_zero_page,%rax
 187         movq    %rax,%rdx
 188         shrq    $32,%rdx
 189         wrmsr
 190
 191         /* esi is pointer to real mode structure with interesting info.
 192            pass it to C */
 193         movl    %esi, %edi
 194
 195         /* Finally jump to run C code and to be on real kernel address
 196          * Since we are running on identity-mapped space we have to jump
 197          * to the full 64bit address, this is only possible as indirect
 198          * jump.  In addition we need to ensure %cs is set so we make this
 199          * a far return.
 200          */
 201         movq    initial_code(%rip),%rax
 202         pushq   $0              # fake return address to stop unwinder
 203         pushq   $__KERNEL_CS    # set correct cs
 204         pushq   %rax            # target address in negative space
 205         lretq
 206
 207         /* SMP bootup changes these two */
 208         .align  8
 209         .globl  initial_code
 210 initial_code:
 211         .quad   x86_64_start_kernel
 212         .globl init_rsp
 213 init_rsp:
 214         .quad  init_thread_union+THREAD_SIZE-8
 215
 216 ENTRY(early_idt_handler)
 217         cmpl $2,early_recursion_flag(%rip)
 218         jz  1f
 219         incl early_recursion_flag(%rip)
 220         xorl %eax,%eax
 221         movq 8(%rsp),%rsi       # get rip
 222         movq (%rsp),%rdx
 223         movq %cr2,%rcx
 224         leaq early_idt_msg(%rip),%rdi
 225         call early_printk
 226         cmpl $2,early_recursion_flag(%rip)
 227         jz  1f
 228         call dump_stack
 229 #ifdef CONFIG_KALLSYMS
 230         leaq early_idt_ripmsg(%rip),%rdi
 231         movq 8(%rsp),%rsi       # get rip again
 232         call __print_symbol
 233 #endif
 234 1:      hlt
 235         jmp 1b
 236 early_recursion_flag:
 237         .long 0
 238
 239 early_idt_msg:
 240         .asciz "PANIC: early exception rip %lx error %lx cr2 %lx\n"
 241 early_idt_ripmsg:
 242         .asciz "RIP %s\n"
 243
 244 .code32
 245 ENTRY(no_long_mode)
 246         /* This isn't an x86-64 CPU so hang */
 247 1:
 248         jmp     1b
 249
 250 .org 0xf00
 251         .globl pGDT32
 252 pGDT32:
 253         .word   gdt_end-cpu_gdt_table-1
 254         .long   cpu_gdt_table-__START_KERNEL_map
 255
 256 .org 0xf10
 257 ljumpvector:
 258         .long   startup_64-__START_KERNEL_map
 259         .word   __KERNEL_CS
 260
 261 ENTRY(stext)
 262 ENTRY(_stext)
 263
 264 #define NEXT_PAGE(name) \
 265         .balign PAGE_SIZE; \
 266 ENTRY(name)
 267
 268 /* Automate the creation of 1 to 1 mapping pmd entries */
 269 #define PMDS(START, PERM, COUNT)                \
 270         i = 0 ;                                 \
 271         .rept (COUNT) ;                         \
 272         .quad   (START) + (i << 21) + (PERM) ;  \
 273         i = i + 1 ;                             \
 274         .endr
 275
 276 NEXT_PAGE(init_level4_pgt)
 277         /* This gets initialized in x86_64_start_kernel */
 278         .fill   512,8,0
 279
 280 NEXT_PAGE(level3_ident_pgt)
 281         .quad   level2_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
 282         .fill   511,8,0
 283
 284 NEXT_PAGE(level3_kernel_pgt)
 285         .fill   510,8,0
 286         /* (2^48-(2*1024*1024*1024)-((2^39)*511))/(2^30) = 510 */
 287         .quad   level2_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
 288         .fill   1,8,0
 289
 290 NEXT_PAGE(level2_ident_pgt)
 291         /* Since I easily can, map the first 1G.
 292          * Don't set NX because code runs from these pages.
 293          */
 294         PMDS(0x0000000000000000, __PAGE_KERNEL_LARGE_EXEC, PTRS_PER_PMD)
 295
 296 NEXT_PAGE(level2_kernel_pgt)
 297         /* 40MB kernel mapping. The kernel code cannot be bigger than that.
 298            When you change this change KERNEL_TEXT_SIZE in page.h too. */
 299         /* (2^48-(2*1024*1024*1024)-((2^39)*511)-((2^30)*510)) = 0 */
 300         PMDS(0x0000000000000000, __PAGE_KERNEL_LARGE_EXEC|_PAGE_GLOBAL,
 301                 KERNEL_TEXT_SIZE/PMD_SIZE)
 302         /* Module mapping starts here */
 303         .fill   (PTRS_PER_PMD - (KERNEL_TEXT_SIZE/PMD_SIZE)),8,0
 304
 305 #undef PMDS
 306 #undef NEXT_PAGE
 307
 308         .data
 309
 310 #ifdef CONFIG_ACPI_SLEEP
 311         .align PAGE_SIZE
 312 ENTRY(wakeup_level4_pgt)
 313         .quad   level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
 314         .fill   510,8,0
 315         /* (2^48-(2*1024*1024*1024))/(2^39) = 511 */
 316         .quad   level3_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
 317 #endif
 318
 319 #ifndef CONFIG_HOTPLUG_CPU
 320         __INITDATA
 321 #endif
 322         /*
 323          * This default setting generates an ident mapping at address 0x100000
 324          * and a mapping for the kernel that precisely maps virtual address
 325          * 0xffffffff80000000 to physical address 0x000000. (always using
 326          * 2Mbyte large pages provided by PAE mode)
 327          */
 328         .align PAGE_SIZE
 329 ENTRY(boot_level4_pgt)
 330         .quad   level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
 331         .fill   257,8,0
 332         .quad   level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
 333         .fill   252,8,0
 334         /* (2^48-(2*1024*1024*1024))/(2^39) = 511 */
 335         .quad   level3_kernel_pgt - __START_KERNEL_map + _PAGE_TABLE
 336
 337         .data
 338
 339         .align 16
 340         .globl cpu_gdt_descr
 341 cpu_gdt_descr:
 342         .word   gdt_end-cpu_gdt_table-1
 343 gdt:
 344         .quad   cpu_gdt_table
 345 #ifdef CONFIG_SMP
 346         .rept   NR_CPUS-1
 347         .word   0
 348         .quad   0
 349         .endr
 350 #endif
 351
 352 /* We need valid kernel segments for data and code in long mode too
 353  * IRET will check the segment types  kkeil 2000/10/28
 354  * Also sysret mandates a special GDT layout
 355  */
 356
 357         .section .data.page_aligned, "aw"
 358         .align PAGE_SIZE
 359
 360 /* The TLS descriptors are currently at a different place compared to i386.
 361    Hopefully nobody expects them at a fixed place (Wine?) */
 362
 363 ENTRY(cpu_gdt_table)
 364         .quad   0x0000000000000000      /* NULL descriptor */
 365         .quad   0x0                     /* unused */
 366         .quad   0x00af9a000000ffff      /* __KERNEL_CS */
 367         .quad   0x00cf92000000ffff      /* __KERNEL_DS */
 368         .quad   0x00cffa000000ffff      /* __USER32_CS */
 369         .quad   0x00cff2000000ffff      /* __USER_DS, __USER32_DS  */
 370         .quad   0x00affa000000ffff      /* __USER_CS */
 371         .quad   0x00cf9a000000ffff      /* __KERNEL32_CS */
 372         .quad   0,0                     /* TSS */
 373         .quad   0,0                     /* LDT */
 374         .quad   0,0,0                   /* three TLS descriptors */
 375         .quad   0x0000f40000000000      /* node/CPU stored in limit */
 376 gdt_end:
 377         /* asm/segment.h:GDT_ENTRIES must match this */
 378         /* This should be a multiple of the cache line size */
 379         /* GDTs of other CPUs are now dynamically allocated */
 380
 381         /* zero the remaining page */
 382         .fill PAGE_SIZE / 8 - GDT_ENTRIES,8,0
 383
 384         .section .bss, "aw", @nobits
 385         .align L1_CACHE_BYTES
 386 ENTRY(idt_table)
 387         .skip 256 * 16
 388
 389         .section .bss.page_aligned, "aw", @nobits
 390         .align PAGE_SIZE
 391 ENTRY(empty_zero_page)
 392         .skip PAGE_SIZE