SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/x86_64/ia32/ia32entry.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/vsyscall32.h>
  16 #include <linux/linkage.h>
  17
  18         .macro IA32_ARG_FIXUP noebp=0
  19         movl    %edi,%r8d
  20         .if \noebp
  21         .else
  22         movl    %ebp,%r9d
  23         .endif
  24         xchg    %ecx,%esi
  25         movl    %ebx,%edi
  26         movl    %edx,%edx       /* zero extension */
  27         .endm
  28
  29         /* clobbers %eax */
  30         .macro  CLEAR_RREGS
  31         xorl    %eax,%eax
  32         movq    %rax,R11(%rsp)
  33         movq    %rax,R10(%rsp)
  34         movq    %rax,R9(%rsp)
  35         movq    %rax,R8(%rsp)
  36         .endm
  37
  38         .macro CFI_STARTPROC32 simple
  39         CFI_STARTPROC   \simple
  40         CFI_UNDEFINED   r8
  41         CFI_UNDEFINED   r9
  42         CFI_UNDEFINED   r10
  43         CFI_UNDEFINED   r11
  44         CFI_UNDEFINED   r12
  45         CFI_UNDEFINED   r13
  46         CFI_UNDEFINED   r14
  47         CFI_UNDEFINED   r15
  48         .endm
  49
  50 /*
  51  * 32bit SYSENTER instruction entry.
  52  *
  53  * Arguments:
  54  * %eax System call number.
  55  * %ebx Arg1
  56  * %ecx Arg2
  57  * %edx Arg3
  58  * %esi Arg4
  59  * %edi Arg5
  60  * %ebp user stack
  61  * 0(%ebp) Arg6
  62  *
  63  * Interrupts off.
  64  *
  65  * This is purely a fast path. For anything complicated we use the int 0x80
  66  * path below.  Set up a complete hardware stack frame to share code
  67  * with the int 0x80 path.
  68  */
  69 ENTRY(ia32_sysenter_target)
  70         CFI_STARTPROC32 simple
  71         CFI_DEF_CFA     rsp,0
  72         CFI_REGISTER    rsp,rbp
  73         swapgs
  74         movq    %gs:pda_kernelstack, %rsp
  75         addq    $(PDA_STACKOFFSET),%rsp
  76         sti
  77         movl    %ebp,%ebp               /* zero extension */
  78         pushq   $__USER32_DS
  79         CFI_ADJUST_CFA_OFFSET 8
  80         /*CFI_REL_OFFSET ss,0*/
  81         pushq   %rbp
  82         CFI_ADJUST_CFA_OFFSET 8
  83         CFI_REL_OFFSET rsp,0
  84         pushfq
  85         CFI_ADJUST_CFA_OFFSET 8
  86         /*CFI_REL_OFFSET rflags,0*/
  87         movl    $VSYSCALL32_SYSEXIT, %r10d
  88         CFI_REGISTER rip,r10
  89         pushq   $__USER32_CS
  90         CFI_ADJUST_CFA_OFFSET 8
  91         /*CFI_REL_OFFSET cs,0*/
  92         movl    %eax, %eax
  93         pushq   %r10
  94         CFI_ADJUST_CFA_OFFSET 8
  95         CFI_REL_OFFSET rip,0
  96         pushq   %rax
  97         CFI_ADJUST_CFA_OFFSET 8
  98         cld
  99         SAVE_ARGS 0,0,1
 100         /* no need to do an access_ok check here because rbp has been
 101            32bit zero extended */
 102 1:      movl    (%rbp),%r9d
 103         .section __ex_table,"a"
 104         .quad 1b,ia32_badarg
 105         .previous
 106         GET_THREAD_INFO(%r10)
 107         testl  $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 108         CFI_REMEMBER_STATE
 109         jnz  sysenter_tracesys
 110 sysenter_do_call:
 111         cmpl    $(IA32_NR_syscalls),%eax
 112         jae     ia32_badsys
 113         IA32_ARG_FIXUP 1
 114         call    *ia32_sys_call_table(,%rax,8)
 115         movq    %rax,RAX-ARGOFFSET(%rsp)
 116         GET_THREAD_INFO(%r10)
 117         cli
 118         testl   $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 119         jnz     int_ret_from_sys_call
 120         /* clear IF, that popfq doesn't enable interrupts early */
 121         andl  $~0x200,EFLAGS-R11(%rsp)
 122         RESTORE_ARGS 1,24,1,1,1,1
 123         popfq
 124         CFI_ADJUST_CFA_OFFSET -8
 125         /*CFI_RESTORE rflags*/
 126         popq    %rcx                            /* User %esp */
 127         CFI_ADJUST_CFA_OFFSET -8
 128         CFI_REGISTER rsp,rcx
 129         movl    $VSYSCALL32_SYSEXIT,%edx        /* User %eip */
 130         CFI_REGISTER rip,rdx
 131         swapgs
 132         sti             /* sti only takes effect after the next instruction */
 133         /* sysexit */
 134         .byte   0xf, 0x35
 135
 136 sysenter_tracesys:
 137         CFI_RESTORE_STATE
 138         SAVE_REST
 139         CLEAR_RREGS
 140         movq    $-ENOSYS,RAX(%rsp)      /* really needed? */
 141         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 142         call    syscall_trace_enter
 143         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 144         RESTORE_REST
 145         movl    %ebp, %ebp
 146         /* no need to do an access_ok check here because rbp has been
 147            32bit zero extended */
 148 1:      movl    (%rbp),%r9d
 149         .section __ex_table,"a"
 150         .quad 1b,ia32_badarg
 151         .previous
 152         jmp     sysenter_do_call
 153         CFI_ENDPROC
 154
 155 /*
 156  * 32bit SYSCALL instruction entry.
 157  *
 158  * Arguments:
 159  * %eax System call number.
 160  * %ebx Arg1
 161  * %ecx return EIP
 162  * %edx Arg3
 163  * %esi Arg4
 164  * %edi Arg5
 165  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 166  * %esp user stack
 167  * 0(%esp) Arg6
 168  *
 169  * Interrupts off.
 170  *
 171  * This is purely a fast path. For anything complicated we use the int 0x80
 172  * path below.  Set up a complete hardware stack frame to share code
 173  * with the int 0x80 path.
 174  */
 175 ENTRY(ia32_cstar_target)
 176         CFI_STARTPROC32 simple
 177         CFI_DEF_CFA     rsp,0
 178         CFI_REGISTER    rip,rcx
 179         /*CFI_REGISTER  rflags,r11*/
 180         swapgs
 181         movl    %esp,%r8d
 182         CFI_REGISTER    rsp,r8
 183         movq    %gs:pda_kernelstack,%rsp
 184         sti
 185         SAVE_ARGS 8,1,1
 186         movl    %eax,%eax       /* zero extension */
 187         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 188         movq    %rcx,RIP-ARGOFFSET(%rsp)
 189         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 190         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 191         movl    %ebp,%ecx
 192         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 193         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 194         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 195         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 196         movq    %r8,RSP-ARGOFFSET(%rsp)
 197         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 198         /* no need to do an access_ok check here because r8 has been
 199            32bit zero extended */
 200         /* hardware stack frame is complete now */
 201 1:      movl    (%r8),%r9d
 202         .section __ex_table,"a"
 203         .quad 1b,ia32_badarg
 204         .previous
 205         GET_THREAD_INFO(%r10)
 206         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 207         CFI_REMEMBER_STATE
 208         jnz   cstar_tracesys
 209 cstar_do_call:
 210         cmpl $IA32_NR_syscalls,%eax
 211         jae  ia32_badsys
 212         IA32_ARG_FIXUP 1
 213         call *ia32_sys_call_table(,%rax,8)
 214         movq %rax,RAX-ARGOFFSET(%rsp)
 215         GET_THREAD_INFO(%r10)
 216         cli
 217         testl $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 218         jnz  int_ret_from_sys_call
 219         RESTORE_ARGS 1,-ARG_SKIP,1,1,1
 220         movl RIP-ARGOFFSET(%rsp),%ecx
 221         CFI_REGISTER rip,rcx
 222         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 223         /*CFI_REGISTER rflags,r11*/
 224         movl RSP-ARGOFFSET(%rsp),%esp
 225         CFI_RESTORE rsp
 226         swapgs
 227         sysretl
 228
 229 cstar_tracesys:
 230         CFI_RESTORE_STATE
 231         SAVE_REST
 232         CLEAR_RREGS
 233         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 234         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 235         call syscall_trace_enter
 236         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 237         RESTORE_REST
 238         movl RSP-ARGOFFSET(%rsp), %r8d
 239         /* no need to do an access_ok check here because r8 has been
 240            32bit zero extended */
 241 1:      movl    (%r8),%r9d
 242         .section __ex_table,"a"
 243         .quad 1b,ia32_badarg
 244         .previous
 245         jmp cstar_do_call
 246
 247 ia32_badarg:
 248         movq $-EFAULT,%rax
 249         jmp ia32_sysret
 250         CFI_ENDPROC
 251
 252 /*
 253  * Emulated IA32 system calls via int 0x80.
 254  *
 255  * Arguments:
 256  * %eax System call number.
 257  * %ebx Arg1
 258  * %ecx Arg2
 259  * %edx Arg3
 260  * %esi Arg4
 261  * %edi Arg5
 262  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 263  *
 264  * Notes:
 265  * Uses the same stack frame as the x86-64 version.
 266  * All registers except %eax must be saved (but ptrace may violate that)
 267  * Arguments are zero extended. For system calls that want sign extension and
 268  * take long arguments a wrapper is needed. Most calls can just be called
 269  * directly.
 270  * Assumes it is only called from user space and entered with interrupts off.
 271  */
 272
 273 ENTRY(ia32_syscall)
 274         CFI_STARTPROC   simple
 275         CFI_DEF_CFA     rsp,SS+8-RIP
 276         /*CFI_REL_OFFSET        ss,SS-RIP*/
 277         CFI_REL_OFFSET  rsp,RSP-RIP
 278         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 279         /*CFI_REL_OFFSET        cs,CS-RIP*/
 280         CFI_REL_OFFSET  rip,RIP-RIP
 281         swapgs
 282         sti
 283         movl %eax,%eax
 284         pushq %rax
 285         CFI_ADJUST_CFA_OFFSET 8
 286         cld
 287         /* note the registers are not zero extended to the sf.
 288            this could be a problem. */
 289         SAVE_ARGS 0,0,1
 290         GET_THREAD_INFO(%r10)
 291         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 292         jnz ia32_tracesys
 293 ia32_do_syscall:
 294         cmpl $(IA32_NR_syscalls),%eax
 295         jae  ia32_badsys
 296         IA32_ARG_FIXUP
 297         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 298 ia32_sysret:
 299         movq %rax,RAX-ARGOFFSET(%rsp)
 300         jmp int_ret_from_sys_call
 301
 302 ia32_tracesys:
 303         SAVE_REST
 304         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 305         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 306         call syscall_trace_enter
 307         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 308         RESTORE_REST
 309         jmp ia32_do_syscall
 310
 311 ia32_badsys:
 312         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 313         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 314         jmp int_ret_from_sys_call
 315
 316 ni_syscall:
 317         movq %rax,%rdi
 318         jmp  sys32_ni_syscall
 319
 320 quiet_ni_syscall:
 321         movq $-ENOSYS,%rax
 322         ret
 323         CFI_ENDPROC
 324
 325         .macro PTREGSCALL label, func, arg
 326         .globl \label
 327 \label:
 328         leaq \func(%rip),%rax
 329         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 330         jmp  ia32_ptregs_common
 331         .endm
 332
 333         CFI_STARTPROC32
 334
 335         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 336         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 337         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 338         PTREGSCALL stub32_sigsuspend, sys32_sigsuspend, %rcx
 339         PTREGSCALL stub32_execve, sys32_execve, %rcx
 340         PTREGSCALL stub32_fork, sys_fork, %rdi
 341         PTREGSCALL stub32_clone, sys32_clone, %rdx
 342         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 343         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 344         PTREGSCALL stub32_rt_sigsuspend, sys_rt_sigsuspend, %rdx
 345
 346 ENTRY(ia32_ptregs_common)
 347         popq %r11
 348         CFI_ENDPROC
 349         CFI_STARTPROC32 simple
 350         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 351         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 352         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 353         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 354         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 355         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 356         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 357 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 358 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 359         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 360 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 361         SAVE_REST
 362         call *%rax
 363         RESTORE_REST
 364         jmp  ia32_sysret        /* misbalances the return cache */
 365         CFI_ENDPROC
 366
 367         .section .rodata,"a"
 368         .align 8
 369         .globl ia32_sys_call_table
 370 ia32_sys_call_table:
 371         .quad sys_restart_syscall
 372         .quad sys_exit
 373         .quad stub32_fork
 374         .quad sys_read
 375         .quad sys_write
 376         .quad compat_sys_open           /* 5 */
 377         .quad sys_close
 378         .quad sys32_waitpid
 379         .quad sys_creat
 380         .quad sys_link
 381         .quad sys_unlink                /* 10 */
 382         .quad stub32_execve
 383         .quad sys_chdir
 384         .quad compat_sys_time
 385         .quad sys_mknod
 386         .quad sys_chmod         /* 15 */
 387         .quad sys_lchown16
 388         .quad quiet_ni_syscall                  /* old break syscall holder */
 389         .quad sys_stat
 390         .quad sys32_lseek
 391         .quad sys_getpid                /* 20 */
 392         .quad compat_sys_mount  /* mount  */
 393         .quad sys_oldumount     /* old_umount  */
 394         .quad sys_setuid16
 395         .quad sys_getuid16
 396         .quad compat_sys_stime  /* stime */             /* 25 */
 397         .quad sys32_ptrace      /* ptrace */
 398         .quad sys_alarm
 399         .quad sys_fstat /* (old)fstat */
 400         .quad sys_pause
 401         .quad compat_sys_utime  /* 30 */
 402         .quad quiet_ni_syscall  /* old stty syscall holder */
 403         .quad quiet_ni_syscall  /* old gtty syscall holder */
 404         .quad sys_access
 405         .quad sys_nice
 406         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 407         .quad sys_sync
 408         .quad sys32_kill
 409         .quad sys_rename
 410         .quad sys_mkdir
 411         .quad sys_rmdir         /* 40 */
 412         .quad sys_dup
 413         .quad sys32_pipe
 414         .quad compat_sys_times
 415         .quad quiet_ni_syscall                  /* old prof syscall holder */
 416         .quad sys_brk           /* 45 */
 417         .quad sys_setgid16
 418         .quad sys_getgid16
 419         .quad sys_signal
 420         .quad sys_geteuid16
 421         .quad sys_getegid16     /* 50 */
 422         .quad sys_acct
 423         .quad sys_umount                        /* new_umount */
 424         .quad quiet_ni_syscall                  /* old lock syscall holder */
 425         .quad compat_sys_ioctl
 426         .quad compat_sys_fcntl64                /* 55 */
 427         .quad quiet_ni_syscall                  /* old mpx syscall holder */
 428         .quad sys_setpgid
 429         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 430         .quad sys32_olduname
 431         .quad sys_umask         /* 60 */
 432         .quad sys_chroot
 433         .quad sys32_ustat
 434         .quad sys_dup2
 435         .quad sys_getppid
 436         .quad sys_getpgrp               /* 65 */
 437         .quad sys_setsid
 438         .quad sys32_sigaction
 439         .quad sys_sgetmask
 440         .quad sys_ssetmask
 441         .quad sys_setreuid16    /* 70 */
 442         .quad sys_setregid16
 443         .quad stub32_sigsuspend
 444         .quad compat_sys_sigpending
 445         .quad sys_sethostname
 446         .quad compat_sys_setrlimit      /* 75 */
 447         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 448         .quad compat_sys_getrusage
 449         .quad sys32_gettimeofday
 450         .quad sys32_settimeofday
 451         .quad sys_getgroups16   /* 80 */
 452         .quad sys_setgroups16
 453         .quad sys32_old_select
 454         .quad sys_symlink
 455         .quad sys_lstat
 456         .quad sys_readlink              /* 85 */
 457 #ifdef CONFIG_IA32_AOUT
 458         .quad sys_uselib
 459 #else
 460         .quad quiet_ni_syscall
 461 #endif
 462         .quad sys_swapon
 463         .quad sys_reboot
 464         .quad compat_sys_old_readdir
 465         .quad sys32_mmap                /* 90 */
 466         .quad sys_munmap
 467         .quad sys_truncate
 468         .quad sys_ftruncate
 469         .quad sys_fchmod
 470         .quad sys_fchown16              /* 95 */
 471         .quad sys_getpriority
 472         .quad sys_setpriority
 473         .quad quiet_ni_syscall                  /* old profil syscall holder */
 474         .quad compat_sys_statfs
 475         .quad compat_sys_fstatfs                /* 100 */
 476         .quad sys_ioperm
 477         .quad compat_sys_socketcall
 478         .quad sys_syslog
 479         .quad compat_sys_setitimer
 480         .quad compat_sys_getitimer      /* 105 */
 481         .quad compat_sys_newstat
 482         .quad compat_sys_newlstat
 483         .quad compat_sys_newfstat
 484         .quad sys32_uname
 485         .quad stub32_iopl               /* 110 */
 486         .quad sys_vhangup
 487         .quad quiet_ni_syscall  /* old "idle" system call */
 488         .quad sys32_vm86_warning        /* vm86old */
 489         .quad compat_sys_wait4
 490         .quad sys_swapoff               /* 115 */
 491         .quad sys32_sysinfo
 492         .quad sys32_ipc
 493         .quad sys_fsync
 494         .quad stub32_sigreturn
 495         .quad stub32_clone              /* 120 */
 496         .quad sys_setdomainname
 497         .quad sys_uname
 498         .quad sys_modify_ldt
 499         .quad sys32_adjtimex
 500         .quad sys32_mprotect            /* 125 */
 501         .quad compat_sys_sigprocmask
 502         .quad quiet_ni_syscall          /* create_module */
 503         .quad sys_init_module
 504         .quad sys_delete_module
 505         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 506         .quad sys_quotactl
 507         .quad sys_getpgid
 508         .quad sys_fchdir
 509         .quad quiet_ni_syscall  /* bdflush */
 510         .quad sys_sysfs         /* 135 */
 511         .quad sys_personality
 512         .quad quiet_ni_syscall  /* for afs_syscall */
 513         .quad sys_setfsuid16
 514         .quad sys_setfsgid16
 515         .quad sys_llseek                /* 140 */
 516         .quad compat_sys_getdents
 517         .quad compat_sys_select
 518         .quad sys_flock
 519         .quad sys_msync
 520         .quad compat_sys_readv          /* 145 */
 521         .quad compat_sys_writev
 522         .quad sys_getsid
 523         .quad sys_fdatasync
 524         .quad sys32_sysctl      /* sysctl */
 525         .quad sys_mlock         /* 150 */
 526         .quad sys_munlock
 527         .quad sys_mlockall
 528         .quad sys_munlockall
 529         .quad sys_sched_setparam
 530         .quad sys_sched_getparam   /* 155 */
 531         .quad sys_sched_setscheduler
 532         .quad sys_sched_getscheduler
 533         .quad sys_sched_yield
 534         .quad sys_sched_get_priority_max
 535         .quad sys_sched_get_priority_min  /* 160 */
 536         .quad sys_sched_rr_get_interval
 537         .quad compat_sys_nanosleep
 538         .quad sys_mremap
 539         .quad sys_setresuid16
 540         .quad sys_getresuid16   /* 165 */
 541         .quad sys32_vm86_warning        /* vm86 */
 542         .quad quiet_ni_syscall  /* query_module */
 543         .quad sys_poll
 544         .quad compat_sys_nfsservctl
 545         .quad sys_setresgid16   /* 170 */
 546         .quad sys_getresgid16
 547         .quad sys_prctl
 548         .quad stub32_rt_sigreturn
 549         .quad sys32_rt_sigaction
 550         .quad sys32_rt_sigprocmask      /* 175 */
 551         .quad sys32_rt_sigpending
 552         .quad compat_sys_rt_sigtimedwait
 553         .quad sys32_rt_sigqueueinfo
 554         .quad stub32_rt_sigsuspend
 555         .quad sys32_pread               /* 180 */
 556         .quad sys32_pwrite
 557         .quad sys_chown16
 558         .quad sys_getcwd
 559         .quad sys_capget
 560         .quad sys_capset
 561         .quad stub32_sigaltstack
 562         .quad sys32_sendfile
 563         .quad quiet_ni_syscall          /* streams1 */
 564         .quad quiet_ni_syscall          /* streams2 */
 565         .quad stub32_vfork            /* 190 */
 566         .quad compat_sys_getrlimit
 567         .quad sys32_mmap2
 568         .quad sys32_truncate64
 569         .quad sys32_ftruncate64
 570         .quad sys32_stat64              /* 195 */
 571         .quad sys32_lstat64
 572         .quad sys32_fstat64
 573         .quad sys_lchown
 574         .quad sys_getuid
 575         .quad sys_getgid                /* 200 */
 576         .quad sys_geteuid
 577         .quad sys_getegid
 578         .quad sys_setreuid
 579         .quad sys_setregid
 580         .quad sys_getgroups     /* 205 */
 581         .quad sys_setgroups
 582         .quad sys_fchown
 583         .quad sys_setresuid
 584         .quad sys_getresuid
 585         .quad sys_setresgid     /* 210 */
 586         .quad sys_getresgid
 587         .quad sys_chown
 588         .quad sys_setuid
 589         .quad sys_setgid
 590         .quad sys_setfsuid              /* 215 */
 591         .quad sys_setfsgid
 592         .quad sys_pivot_root
 593         .quad sys_mincore
 594         .quad sys_madvise
 595         .quad compat_sys_getdents64     /* 220 getdents64 */
 596         .quad compat_sys_fcntl64
 597         .quad quiet_ni_syscall          /* tux */
 598         .quad quiet_ni_syscall          /* security */
 599         .quad sys_gettid
 600         .quad sys_readahead     /* 225 */
 601         .quad sys_setxattr
 602         .quad sys_lsetxattr
 603         .quad sys_fsetxattr
 604         .quad sys_getxattr
 605         .quad sys_lgetxattr     /* 230 */
 606         .quad sys_fgetxattr
 607         .quad sys_listxattr
 608         .quad sys_llistxattr
 609         .quad sys_flistxattr
 610         .quad sys_removexattr   /* 235 */
 611         .quad sys_lremovexattr
 612         .quad sys_fremovexattr
 613         .quad sys_tkill
 614         .quad sys_sendfile64
 615         .quad compat_sys_futex          /* 240 */
 616         .quad compat_sys_sched_setaffinity
 617         .quad compat_sys_sched_getaffinity
 618         .quad sys32_set_thread_area
 619         .quad sys32_get_thread_area
 620         .quad compat_sys_io_setup       /* 245 */
 621         .quad sys_io_destroy
 622         .quad compat_sys_io_getevents
 623         .quad compat_sys_io_submit
 624         .quad sys_io_cancel
 625         .quad sys_fadvise64             /* 250 */
 626         .quad quiet_ni_syscall  /* free_huge_pages */
 627         .quad sys_exit_group
 628         .quad sys32_lookup_dcookie
 629         .quad sys_epoll_create
 630         .quad sys_epoll_ctl             /* 255 */
 631         .quad sys_epoll_wait
 632         .quad sys_remap_file_pages
 633         .quad sys_set_tid_address
 634         .quad compat_sys_timer_create
 635         .quad compat_sys_timer_settime  /* 260 */
 636         .quad compat_sys_timer_gettime
 637         .quad sys_timer_getoverrun
 638         .quad sys_timer_delete
 639         .quad compat_sys_clock_settime
 640         .quad compat_sys_clock_gettime  /* 265 */
 641         .quad compat_sys_clock_getres
 642         .quad compat_sys_clock_nanosleep
 643         .quad compat_sys_statfs64
 644         .quad compat_sys_fstatfs64
 645         .quad sys_tgkill                /* 270 */
 646         .quad compat_sys_utimes
 647         .quad sys32_fadvise64_64
 648         .quad quiet_ni_syscall  /* sys_vserver */
 649         .quad sys_mbind
 650         .quad compat_sys_get_mempolicy  /* 275 */
 651         .quad sys_set_mempolicy
 652         .quad compat_sys_mq_open
 653         .quad sys_mq_unlink
 654         .quad compat_sys_mq_timedsend
 655         .quad compat_sys_mq_timedreceive        /* 280 */
 656         .quad compat_sys_mq_notify
 657         .quad compat_sys_mq_getsetattr
 658         .quad compat_sys_kexec_load     /* reserved for kexec */
 659         .quad compat_sys_waitid
 660         .quad quiet_ni_syscall          /* 285: sys_altroot */
 661         .quad sys_add_key
 662         .quad sys_request_key
 663         .quad sys_keyctl
 664         .quad sys_ioprio_set
 665         .quad sys_ioprio_get            /* 290 */
 666         .quad sys_inotify_init
 667         .quad sys_inotify_add_watch
 668         .quad sys_inotify_rm_watch
 669         .quad sys_migrate_pages
 670 ia32_syscall_end:
 671         .rept IA32_NR_syscalls-(ia32_syscall_end-ia32_sys_call_table)/8
 672                 .quad ni_syscall
 673         .endr