SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64 #ifdef CONFIG_FUNCTION_TRACER
  65 #ifdef CONFIG_DYNAMIC_FTRACE
  66 ENTRY(mcount)
  67         retq
  68 END(mcount)
  69
  70 ENTRY(ftrace_caller)
  71         cmpl $0, function_trace_stop
  72         jne  ftrace_stub
  73
  74         MCOUNT_SAVE_FRAME
  75
  76         movq 0x38(%rsp), %rdi
  77         movq 8(%rbp), %rsi
  78         subq $MCOUNT_INSN_SIZE, %rdi
  79
  80 .globl ftrace_call
  81 ftrace_call:
  82         call ftrace_stub
  83
  84         MCOUNT_RESTORE_FRAME
  85
  86 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  87 .globl ftrace_graph_call
  88 ftrace_graph_call:
  89         jmp ftrace_stub
  90 #endif
  91
  92 .globl ftrace_stub
  93 ftrace_stub:
  94         retq
  95 END(ftrace_caller)
  96
  97 #else /* ! CONFIG_DYNAMIC_FTRACE */
  98 ENTRY(mcount)
  99         cmpl $0, function_trace_stop
 100         jne  ftrace_stub
 101
 102         cmpq $ftrace_stub, ftrace_trace_function
 103         jnz trace
 104
 105 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 106         cmpq $ftrace_stub, ftrace_graph_return
 107         jnz ftrace_graph_caller
 108
 109         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 110         jnz ftrace_graph_caller
 111 #endif
 112
 113 .globl ftrace_stub
 114 ftrace_stub:
 115         retq
 116
 117 trace:
 118         MCOUNT_SAVE_FRAME
 119
 120         movq 0x38(%rsp), %rdi
 121         movq 8(%rbp), %rsi
 122         subq $MCOUNT_INSN_SIZE, %rdi
 123
 124         call   *ftrace_trace_function
 125
 126         MCOUNT_RESTORE_FRAME
 127
 128         jmp ftrace_stub
 129 END(mcount)
 130 #endif /* CONFIG_DYNAMIC_FTRACE */
 131 #endif /* CONFIG_FUNCTION_TRACER */
 132
 133 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 134 ENTRY(ftrace_graph_caller)
 135         cmpl $0, function_trace_stop
 136         jne ftrace_stub
 137
 138         MCOUNT_SAVE_FRAME
 139
 140         leaq 8(%rbp), %rdi
 141         movq 0x38(%rsp), %rsi
 142         subq $MCOUNT_INSN_SIZE, %rsi
 143
 144         call    prepare_ftrace_return
 145
 146         MCOUNT_RESTORE_FRAME
 147
 148         retq
 149 END(ftrace_graph_caller)
 150
 151
 152 .globl return_to_handler
 153 return_to_handler:
 154         subq  $80, %rsp
 155
 156         movq %rax, (%rsp)
 157         movq %rcx, 8(%rsp)
 158         movq %rdx, 16(%rsp)
 159         movq %rsi, 24(%rsp)
 160         movq %rdi, 32(%rsp)
 161         movq %r8, 40(%rsp)
 162         movq %r9, 48(%rsp)
 163         movq %r10, 56(%rsp)
 164         movq %r11, 64(%rsp)
 165
 166         call ftrace_return_to_handler
 167
 168         movq %rax, 72(%rsp)
 169         movq 64(%rsp), %r11
 170         movq 56(%rsp), %r10
 171         movq 48(%rsp), %r9
 172         movq 40(%rsp), %r8
 173         movq 32(%rsp), %rdi
 174         movq 24(%rsp), %rsi
 175         movq 16(%rsp), %rdx
 176         movq 8(%rsp), %rcx
 177         movq (%rsp), %rax
 178         addq $72, %rsp
 179         retq
 180 #endif
 181
 182
 183 #ifndef CONFIG_PREEMPT
 184 #define retint_kernel retint_restore_args
 185 #endif
 186
 187 #ifdef CONFIG_PARAVIRT
 188 ENTRY(native_usergs_sysret64)
 189         swapgs
 190         sysretq
 191 #endif /* CONFIG_PARAVIRT */
 192
 193
 194 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 195 #ifdef CONFIG_TRACE_IRQFLAGS
 196         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 197         jnc  1f
 198         TRACE_IRQS_ON
 199 1:
 200 #endif
 201 .endm
 202
 203 /*
 204  * C code is not supposed to know about undefined top of stack. Every time
 205  * a C function with an pt_regs argument is called from the SYSCALL based
 206  * fast path FIXUP_TOP_OF_STACK is needed.
 207  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 208  * manipulation.
 209  */
 210
 211         /* %rsp:at FRAMEEND */
 212         .macro FIXUP_TOP_OF_STACK tmp offset=0
 213         movq PER_CPU_VAR(old_rsp),\tmp
 214         movq \tmp,RSP+\offset(%rsp)
 215         movq $__USER_DS,SS+\offset(%rsp)
 216         movq $__USER_CS,CS+\offset(%rsp)
 217         movq $-1,RCX+\offset(%rsp)
 218         movq R11+\offset(%rsp),\tmp  /* get eflags */
 219         movq \tmp,EFLAGS+\offset(%rsp)
 220         .endm
 221
 222         .macro RESTORE_TOP_OF_STACK tmp offset=0
 223         movq RSP+\offset(%rsp),\tmp
 224         movq \tmp,PER_CPU_VAR(old_rsp)
 225         movq EFLAGS+\offset(%rsp),\tmp
 226         movq \tmp,R11+\offset(%rsp)
 227         .endm
 228
 229         .macro FAKE_STACK_FRAME child_rip
 230         /* push in order ss, rsp, eflags, cs, rip */
 231         xorl %eax, %eax
 232         pushq $__KERNEL_DS /* ss */
 233         CFI_ADJUST_CFA_OFFSET   8
 234         /*CFI_REL_OFFSET        ss,0*/
 235         pushq %rax /* rsp */
 236         CFI_ADJUST_CFA_OFFSET   8
 237         CFI_REL_OFFSET  rsp,0
 238         pushq $X86_EFLAGS_IF /* eflags - interrupts on */
 239         CFI_ADJUST_CFA_OFFSET   8
 240         /*CFI_REL_OFFSET        rflags,0*/
 241         pushq $__KERNEL_CS /* cs */
 242         CFI_ADJUST_CFA_OFFSET   8
 243         /*CFI_REL_OFFSET        cs,0*/
 244         pushq \child_rip /* rip */
 245         CFI_ADJUST_CFA_OFFSET   8
 246         CFI_REL_OFFSET  rip,0
 247         pushq   %rax /* orig rax */
 248         CFI_ADJUST_CFA_OFFSET   8
 249         .endm
 250
 251         .macro UNFAKE_STACK_FRAME
 252         addq $8*6, %rsp
 253         CFI_ADJUST_CFA_OFFSET   -(6*8)
 254         .endm
 255
 256 /*
 257  * initial frame state for interrupts (and exceptions without error code)
 258  */
 259         .macro EMPTY_FRAME start=1 offset=0
 260         .if \start
 261         CFI_STARTPROC simple
 262         CFI_SIGNAL_FRAME
 263         CFI_DEF_CFA rsp,8+\offset
 264         .else
 265         CFI_DEF_CFA_OFFSET 8+\offset
 266         .endif
 267         .endm
 268
 269 /*
 270  * initial frame state for interrupts (and exceptions without error code)
 271  */
 272         .macro INTR_FRAME start=1 offset=0
 273         EMPTY_FRAME \start, SS+8+\offset-RIP
 274         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 275         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 276         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 277         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 278         CFI_REL_OFFSET rip, RIP+\offset-RIP
 279         .endm
 280
 281 /*
 282  * initial frame state for exceptions with error code (and interrupts
 283  * with vector already pushed)
 284  */
 285         .macro XCPT_FRAME start=1 offset=0
 286         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 287         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 288         .endm
 289
 290 /*
 291  * frame that enables calling into C.
 292  */
 293         .macro PARTIAL_FRAME start=1 offset=0
 294         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 295         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 296         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 297         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 298         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 299         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 300         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 301         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 302         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 303         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 304         .endm
 305
 306 /*
 307  * frame that enables passing a complete pt_regs to a C function.
 308  */
 309         .macro DEFAULT_FRAME start=1 offset=0
 310         PARTIAL_FRAME \start, R11+\offset-R15
 311         CFI_REL_OFFSET rbx, RBX+\offset
 312         CFI_REL_OFFSET rbp, RBP+\offset
 313         CFI_REL_OFFSET r12, R12+\offset
 314         CFI_REL_OFFSET r13, R13+\offset
 315         CFI_REL_OFFSET r14, R14+\offset
 316         CFI_REL_OFFSET r15, R15+\offset
 317         .endm
 318
 319 /* save partial stack frame */
 320 ENTRY(save_args)
 321         XCPT_FRAME
 322         cld
 323         movq_cfi rdi, RDI+16-ARGOFFSET
 324         movq_cfi rsi, RSI+16-ARGOFFSET
 325         movq_cfi rdx, RDX+16-ARGOFFSET
 326         movq_cfi rcx, RCX+16-ARGOFFSET
 327         movq_cfi rax, RAX+16-ARGOFFSET
 328         movq_cfi  r8,  R8+16-ARGOFFSET
 329         movq_cfi  r9,  R9+16-ARGOFFSET
 330         movq_cfi r10, R10+16-ARGOFFSET
 331         movq_cfi r11, R11+16-ARGOFFSET
 332
 333         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
 334         movq_cfi rbp, 8         /* push %rbp */
 335         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 336         testl $3, CS(%rdi)
 337         je 1f
 338         SWAPGS
 339         /*
 340          * irq_count is used to check if a CPU is already on an interrupt stack
 341          * or not. While this is essentially redundant with preempt_count it is
 342          * a little cheaper to use a separate counter in the PDA (short of
 343          * moving irq_enter into assembly, which would be too much work)
 344          */
 345 1:      incl PER_CPU_VAR(irq_count)
 346         jne 2f
 347         popq_cfi %rax                   /* move return address... */
 348         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 349         EMPTY_FRAME 0
 350         pushq_cfi %rbp                  /* backlink for unwinder */
 351         pushq_cfi %rax                  /* ... to the new stack */
 352         /*
 353          * We entered an interrupt context - irqs are off:
 354          */
 355 2:      TRACE_IRQS_OFF
 356         ret
 357         CFI_ENDPROC
 358 END(save_args)
 359
 360 ENTRY(save_rest)
 361         PARTIAL_FRAME 1 REST_SKIP+8
 362         movq 5*8+16(%rsp), %r11 /* save return address */
 363         movq_cfi rbx, RBX+16
 364         movq_cfi rbp, RBP+16
 365         movq_cfi r12, R12+16
 366         movq_cfi r13, R13+16
 367         movq_cfi r14, R14+16
 368         movq_cfi r15, R15+16
 369         movq %r11, 8(%rsp)      /* return address */
 370         FIXUP_TOP_OF_STACK %r11, 16
 371         ret
 372         CFI_ENDPROC
 373 END(save_rest)
 374
 375 /* save complete stack frame */
 376 ENTRY(save_paranoid)
 377         XCPT_FRAME 1 RDI+8
 378         cld
 379         movq_cfi rdi, RDI+8
 380         movq_cfi rsi, RSI+8
 381         movq_cfi rdx, RDX+8
 382         movq_cfi rcx, RCX+8
 383         movq_cfi rax, RAX+8
 384         movq_cfi r8, R8+8
 385         movq_cfi r9, R9+8
 386         movq_cfi r10, R10+8
 387         movq_cfi r11, R11+8
 388         movq_cfi rbx, RBX+8
 389         movq_cfi rbp, RBP+8
 390         movq_cfi r12, R12+8
 391         movq_cfi r13, R13+8
 392         movq_cfi r14, R14+8
 393         movq_cfi r15, R15+8
 394         movl $1,%ebx
 395         movl $MSR_GS_BASE,%ecx
 396         rdmsr
 397         testl %edx,%edx
 398         js 1f   /* negative -> in kernel */
 399         SWAPGS
 400         xorl %ebx,%ebx
 401 1:      ret
 402         CFI_ENDPROC
 403 END(save_paranoid)
 404
 405 /*
 406  * A newly forked process directly context switches into this address.
 407  *
 408  * rdi: prev task we switched from
 409  */
 410 ENTRY(ret_from_fork)
 411         DEFAULT_FRAME
 412
 413         push kernel_eflags(%rip)
 414         CFI_ADJUST_CFA_OFFSET 8
 415         popf                                    # reset kernel eflags
 416         CFI_ADJUST_CFA_OFFSET -8
 417
 418         call schedule_tail                      # rdi: 'prev' task parameter
 419
 420         GET_THREAD_INFO(%rcx)
 421
 422         CFI_REMEMBER_STATE
 423         RESTORE_REST
 424
 425         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 426         je   int_ret_from_sys_call
 427
 428         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 429         jnz  int_ret_from_sys_call
 430
 431         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 432         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 433
 434         CFI_RESTORE_STATE
 435         CFI_ENDPROC
 436 END(ret_from_fork)
 437
 438 /*
 439  * System call entry. Upto 6 arguments in registers are supported.
 440  *
 441  * SYSCALL does not save anything on the stack and does not change the
 442  * stack pointer.
 443  */
 444
 445 /*
 446  * Register setup:
 447  * rax  system call number
 448  * rdi  arg0
 449  * rcx  return address for syscall/sysret, C arg3
 450  * rsi  arg1
 451  * rdx  arg2
 452  * r10  arg3    (--> moved to rcx for C)
 453  * r8   arg4
 454  * r9   arg5
 455  * r11  eflags for syscall/sysret, temporary for C
 456  * r12-r15,rbp,rbx saved by C code, not touched.
 457  *
 458  * Interrupts are off on entry.
 459  * Only called from user space.
 460  *
 461  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 462  *      and report it properly in ps. Unfortunately we haven't.
 463  *
 464  * When user can change the frames always force IRET. That is because
 465  * it deals with uncanonical addresses better. SYSRET has trouble
 466  * with them due to bugs in both AMD and Intel CPUs.
 467  */
 468
 469 ENTRY(system_call)
 470         CFI_STARTPROC   simple
 471         CFI_SIGNAL_FRAME
 472         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 473         CFI_REGISTER    rip,rcx
 474         /*CFI_REGISTER  rflags,r11*/
 475         SWAPGS_UNSAFE_STACK
 476         /*
 477          * A hypervisor implementation might want to use a label
 478          * after the swapgs, so that it can do the swapgs
 479          * for the guest and jump here on syscall.
 480          */
 481 ENTRY(system_call_after_swapgs)
 482
 483         movq    %rsp,PER_CPU_VAR(old_rsp)
 484         movq    PER_CPU_VAR(kernel_stack),%rsp
 485         /*
 486          * No need to follow this irqs off/on section - it's straight
 487          * and short:
 488          */
 489         ENABLE_INTERRUPTS(CLBR_NONE)
 490         SAVE_ARGS 8,1
 491         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 492         movq  %rcx,RIP-ARGOFFSET(%rsp)
 493         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 494         GET_THREAD_INFO(%rcx)
 495         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 496         jnz tracesys
 497 system_call_fastpath:
 498         cmpq $__NR_syscall_max,%rax
 499         ja badsys
 500         movq %r10,%rcx
 501         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 502         movq %rax,RAX-ARGOFFSET(%rsp)
 503 /*
 504  * Syscall return path ending with SYSRET (fast path)
 505  * Has incomplete stack frame and undefined top of stack.
 506  */
 507 ret_from_sys_call:
 508         movl $_TIF_ALLWORK_MASK,%edi
 509         /* edi: flagmask */
 510 sysret_check:
 511         LOCKDEP_SYS_EXIT
 512         GET_THREAD_INFO(%rcx)
 513         DISABLE_INTERRUPTS(CLBR_NONE)
 514         TRACE_IRQS_OFF
 515         movl TI_flags(%rcx),%edx
 516         andl %edi,%edx
 517         jnz  sysret_careful
 518         CFI_REMEMBER_STATE
 519         /*
 520          * sysretq will re-enable interrupts:
 521          */
 522         TRACE_IRQS_ON
 523         movq RIP-ARGOFFSET(%rsp),%rcx
 524         CFI_REGISTER    rip,rcx
 525         RESTORE_ARGS 0,-ARG_SKIP,1
 526         /*CFI_REGISTER  rflags,r11*/
 527         movq    PER_CPU_VAR(old_rsp), %rsp
 528         USERGS_SYSRET64
 529
 530         CFI_RESTORE_STATE
 531         /* Handle reschedules */
 532         /* edx: work, edi: workmask */
 533 sysret_careful:
 534         bt $TIF_NEED_RESCHED,%edx
 535         jnc sysret_signal
 536         TRACE_IRQS_ON
 537         ENABLE_INTERRUPTS(CLBR_NONE)
 538         pushq %rdi
 539         CFI_ADJUST_CFA_OFFSET 8
 540         call schedule
 541         popq  %rdi
 542         CFI_ADJUST_CFA_OFFSET -8
 543         jmp sysret_check
 544
 545         /* Handle a signal */
 546 sysret_signal:
 547         TRACE_IRQS_ON
 548         ENABLE_INTERRUPTS(CLBR_NONE)
 549 #ifdef CONFIG_AUDITSYSCALL
 550         bt $TIF_SYSCALL_AUDIT,%edx
 551         jc sysret_audit
 552 #endif
 553         /* edx: work flags (arg3) */
 554         leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
 555         xorl %esi,%esi # oldset -> arg2
 556         SAVE_REST
 557         FIXUP_TOP_OF_STACK %r11
 558         call do_notify_resume
 559         RESTORE_TOP_OF_STACK %r11
 560         RESTORE_REST
 561         movl $_TIF_WORK_MASK,%edi
 562         /* Use IRET because user could have changed frame. This
 563            works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
 564         DISABLE_INTERRUPTS(CLBR_NONE)
 565         TRACE_IRQS_OFF
 566         jmp int_with_check
 567
 568 badsys:
 569         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 570         jmp ret_from_sys_call
 571
 572 #ifdef CONFIG_AUDITSYSCALL
 573         /*
 574          * Fast path for syscall audit without full syscall trace.
 575          * We just call audit_syscall_entry() directly, and then
 576          * jump back to the normal fast path.
 577          */
 578 auditsys:
 579         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 580         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 581         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 582         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 583         movq %rax,%rsi                  /* 2nd arg: syscall number */
 584         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 585         call audit_syscall_entry
 586         LOAD_ARGS 0             /* reload call-clobbered registers */
 587         jmp system_call_fastpath
 588
 589         /*
 590          * Return fast path for syscall audit.  Call audit_syscall_exit()
 591          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 592          * masked off.
 593          */
 594 sysret_audit:
 595         movq %rax,%rsi          /* second arg, syscall return value */
 596         cmpq $0,%rax            /* is it < 0? */
 597         setl %al                /* 1 if so, 0 if not */
 598         movzbl %al,%edi         /* zero-extend that into %edi */
 599         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 600         call audit_syscall_exit
 601         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 602         jmp sysret_check
 603 #endif  /* CONFIG_AUDITSYSCALL */
 604
 605         /* Do syscall tracing */
 606 tracesys:
 607 #ifdef CONFIG_AUDITSYSCALL
 608         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 609         jz auditsys
 610 #endif
 611         SAVE_REST
 612         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 613         FIXUP_TOP_OF_STACK %rdi
 614         movq %rsp,%rdi
 615         call syscall_trace_enter
 616         /*
 617          * Reload arg registers from stack in case ptrace changed them.
 618          * We don't reload %rax because syscall_trace_enter() returned
 619          * the value it wants us to use in the table lookup.
 620          */
 621         LOAD_ARGS ARGOFFSET, 1
 622         RESTORE_REST
 623         cmpq $__NR_syscall_max,%rax
 624         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 625         movq %r10,%rcx  /* fixup for C */
 626         call *sys_call_table(,%rax,8)
 627         movq %rax,RAX-ARGOFFSET(%rsp)
 628         /* Use IRET because user could have changed frame */
 629
 630 /*
 631  * Syscall return path ending with IRET.
 632  * Has correct top of stack, but partial stack frame.
 633  */
 634         .globl int_ret_from_sys_call
 635         .globl int_with_check
 636 int_ret_from_sys_call:
 637         DISABLE_INTERRUPTS(CLBR_NONE)
 638         TRACE_IRQS_OFF
 639         testl $3,CS-ARGOFFSET(%rsp)
 640         je retint_restore_args
 641         movl $_TIF_ALLWORK_MASK,%edi
 642         /* edi: mask to check */
 643 int_with_check:
 644         LOCKDEP_SYS_EXIT_IRQ
 645         GET_THREAD_INFO(%rcx)
 646         movl TI_flags(%rcx),%edx
 647         andl %edi,%edx
 648         jnz   int_careful
 649         andl    $~TS_COMPAT,TI_status(%rcx)
 650         jmp   retint_swapgs
 651
 652         /* Either reschedule or signal or syscall exit tracking needed. */
 653         /* First do a reschedule test. */
 654         /* edx: work, edi: workmask */
 655 int_careful:
 656         bt $TIF_NEED_RESCHED,%edx
 657         jnc  int_very_careful
 658         TRACE_IRQS_ON
 659         ENABLE_INTERRUPTS(CLBR_NONE)
 660         pushq %rdi
 661         CFI_ADJUST_CFA_OFFSET 8
 662         call schedule
 663         popq %rdi
 664         CFI_ADJUST_CFA_OFFSET -8
 665         DISABLE_INTERRUPTS(CLBR_NONE)
 666         TRACE_IRQS_OFF
 667         jmp int_with_check
 668
 669         /* handle signals and tracing -- both require a full stack frame */
 670 int_very_careful:
 671         TRACE_IRQS_ON
 672         ENABLE_INTERRUPTS(CLBR_NONE)
 673         SAVE_REST
 674         /* Check for syscall exit trace */
 675         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 676         jz int_signal
 677         pushq %rdi
 678         CFI_ADJUST_CFA_OFFSET 8
 679         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 680         call syscall_trace_leave
 681         popq %rdi
 682         CFI_ADJUST_CFA_OFFSET -8
 683         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 684         jmp int_restore_rest
 685
 686 int_signal:
 687         testl $_TIF_DO_NOTIFY_MASK,%edx
 688         jz 1f
 689         movq %rsp,%rdi          # &ptregs -> arg1
 690         xorl %esi,%esi          # oldset -> arg2
 691         call do_notify_resume
 692 1:      movl $_TIF_WORK_MASK,%edi
 693 int_restore_rest:
 694         RESTORE_REST
 695         DISABLE_INTERRUPTS(CLBR_NONE)
 696         TRACE_IRQS_OFF
 697         jmp int_with_check
 698         CFI_ENDPROC
 699 END(system_call)
 700
 701 /*
 702  * Certain special system calls that need to save a complete full stack frame.
 703  */
 704         .macro PTREGSCALL label,func,arg
 705 ENTRY(\label)
 706         PARTIAL_FRAME 1 8               /* offset 8: return address */
 707         subq $REST_SKIP, %rsp
 708         CFI_ADJUST_CFA_OFFSET REST_SKIP
 709         call save_rest
 710         DEFAULT_FRAME 0 8               /* offset 8: return address */
 711         leaq 8(%rsp), \arg      /* pt_regs pointer */
 712         call \func
 713         jmp ptregscall_common
 714         CFI_ENDPROC
 715 END(\label)
 716         .endm
 717
 718         PTREGSCALL stub_clone, sys_clone, %r8
 719         PTREGSCALL stub_fork, sys_fork, %rdi
 720         PTREGSCALL stub_vfork, sys_vfork, %rdi
 721         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 722         PTREGSCALL stub_iopl, sys_iopl, %rsi
 723
 724 ENTRY(ptregscall_common)
 725         DEFAULT_FRAME 1 8       /* offset 8: return address */
 726         RESTORE_TOP_OF_STACK %r11, 8
 727         movq_cfi_restore R15+8, r15
 728         movq_cfi_restore R14+8, r14
 729         movq_cfi_restore R13+8, r13
 730         movq_cfi_restore R12+8, r12
 731         movq_cfi_restore RBP+8, rbp
 732         movq_cfi_restore RBX+8, rbx
 733         ret $REST_SKIP          /* pop extended registers */
 734         CFI_ENDPROC
 735 END(ptregscall_common)
 736
 737 ENTRY(stub_execve)
 738         CFI_STARTPROC
 739         popq %r11
 740         CFI_ADJUST_CFA_OFFSET -8
 741         CFI_REGISTER rip, r11
 742         SAVE_REST
 743         FIXUP_TOP_OF_STACK %r11
 744         movq %rsp, %rcx
 745         call sys_execve
 746         RESTORE_TOP_OF_STACK %r11
 747         movq %rax,RAX(%rsp)
 748         RESTORE_REST
 749         jmp int_ret_from_sys_call
 750         CFI_ENDPROC
 751 END(stub_execve)
 752
 753 /*
 754  * sigreturn is special because it needs to restore all registers on return.
 755  * This cannot be done with SYSRET, so use the IRET return path instead.
 756  */
 757 ENTRY(stub_rt_sigreturn)
 758         CFI_STARTPROC
 759         addq $8, %rsp
 760         CFI_ADJUST_CFA_OFFSET   -8
 761         SAVE_REST
 762         movq %rsp,%rdi
 763         FIXUP_TOP_OF_STACK %r11
 764         call sys_rt_sigreturn
 765         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 766         RESTORE_REST
 767         jmp int_ret_from_sys_call
 768         CFI_ENDPROC
 769 END(stub_rt_sigreturn)
 770
 771 /*
 772  * Build the entry stubs and pointer table with some assembler magic.
 773  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 774  * single cache line on all modern x86 implementations.
 775  */
 776         .section .init.rodata,"a"
 777 ENTRY(interrupt)
 778         .text
 779         .p2align 5
 780         .p2align CONFIG_X86_L1_CACHE_SHIFT
 781 ENTRY(irq_entries_start)
 782         INTR_FRAME
 783 vector=FIRST_EXTERNAL_VECTOR
 784 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 785         .balign 32
 786   .rept 7
 787     .if vector < NR_VECTORS
 788       .if vector <> FIRST_EXTERNAL_VECTOR
 789         CFI_ADJUST_CFA_OFFSET -8
 790       .endif
 791 1:      pushq $(~vector+0x80)   /* Note: always in signed byte range */
 792         CFI_ADJUST_CFA_OFFSET 8
 793       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 794         jmp 2f
 795       .endif
 796       .previous
 797         .quad 1b
 798       .text
 799 vector=vector+1
 800     .endif
 801   .endr
 802 2:      jmp common_interrupt
 803 .endr
 804         CFI_ENDPROC
 805 END(irq_entries_start)
 806
 807 .previous
 808 END(interrupt)
 809 .previous
 810
 811 /*
 812  * Interrupt entry/exit.
 813  *
 814  * Interrupt entry points save only callee clobbered registers in fast path.
 815  *
 816  * Entry runs with interrupts off.
 817  */
 818
 819 /* 0(%rsp): ~(interrupt number) */
 820         .macro interrupt func
 821         subq $10*8, %rsp
 822         CFI_ADJUST_CFA_OFFSET 10*8
 823         call save_args
 824         PARTIAL_FRAME 0
 825         call \func
 826         .endm
 827
 828         /*
 829          * The interrupt stubs push (~vector+0x80) onto the stack and
 830          * then jump to common_interrupt.
 831          */
 832         .p2align CONFIG_X86_L1_CACHE_SHIFT
 833 common_interrupt:
 834         XCPT_FRAME
 835         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 836         interrupt do_IRQ
 837         /* 0(%rsp): old_rsp-ARGOFFSET */
 838 ret_from_intr:
 839         DISABLE_INTERRUPTS(CLBR_NONE)
 840         TRACE_IRQS_OFF
 841         decl PER_CPU_VAR(irq_count)
 842         leaveq
 843         CFI_DEF_CFA_REGISTER    rsp
 844         CFI_ADJUST_CFA_OFFSET   -8
 845 exit_intr:
 846         GET_THREAD_INFO(%rcx)
 847         testl $3,CS-ARGOFFSET(%rsp)
 848         je retint_kernel
 849
 850         /* Interrupt came from user space */
 851         /*
 852          * Has a correct top of stack, but a partial stack frame
 853          * %rcx: thread info. Interrupts off.
 854          */
 855 retint_with_reschedule:
 856         movl $_TIF_WORK_MASK,%edi
 857 retint_check:
 858         LOCKDEP_SYS_EXIT_IRQ
 859         movl TI_flags(%rcx),%edx
 860         andl %edi,%edx
 861         CFI_REMEMBER_STATE
 862         jnz  retint_careful
 863
 864 retint_swapgs:          /* return to user-space */
 865         /*
 866          * The iretq could re-enable interrupts:
 867          */
 868         DISABLE_INTERRUPTS(CLBR_ANY)
 869         TRACE_IRQS_IRETQ
 870         SWAPGS
 871         jmp restore_args
 872
 873 retint_restore_args:    /* return to kernel space */
 874         DISABLE_INTERRUPTS(CLBR_ANY)
 875         /*
 876          * The iretq could re-enable interrupts:
 877          */
 878         TRACE_IRQS_IRETQ
 879 restore_args:
 880         RESTORE_ARGS 0,8,0
 881
 882 irq_return:
 883         INTERRUPT_RETURN
 884
 885         .section __ex_table, "a"
 886         .quad irq_return, bad_iret
 887         .previous
 888
 889 #ifdef CONFIG_PARAVIRT
 890 ENTRY(native_iret)
 891         iretq
 892
 893         .section __ex_table,"a"
 894         .quad native_iret, bad_iret
 895         .previous
 896 #endif
 897
 898         .section .fixup,"ax"
 899 bad_iret:
 900         /*
 901          * The iret traps when the %cs or %ss being restored is bogus.
 902          * We've lost the original trap vector and error code.
 903          * #GPF is the most likely one to get for an invalid selector.
 904          * So pretend we completed the iret and took the #GPF in user mode.
 905          *
 906          * We are now running with the kernel GS after exception recovery.
 907          * But error_entry expects us to have user GS to match the user %cs,
 908          * so swap back.
 909          */
 910         pushq $0
 911
 912         SWAPGS
 913         jmp general_protection
 914
 915         .previous
 916
 917         /* edi: workmask, edx: work */
 918 retint_careful:
 919         CFI_RESTORE_STATE
 920         bt    $TIF_NEED_RESCHED,%edx
 921         jnc   retint_signal
 922         TRACE_IRQS_ON
 923         ENABLE_INTERRUPTS(CLBR_NONE)
 924         pushq %rdi
 925         CFI_ADJUST_CFA_OFFSET   8
 926         call  schedule
 927         popq %rdi
 928         CFI_ADJUST_CFA_OFFSET   -8
 929         GET_THREAD_INFO(%rcx)
 930         DISABLE_INTERRUPTS(CLBR_NONE)
 931         TRACE_IRQS_OFF
 932         jmp retint_check
 933
 934 retint_signal:
 935         testl $_TIF_DO_NOTIFY_MASK,%edx
 936         jz    retint_swapgs
 937         TRACE_IRQS_ON
 938         ENABLE_INTERRUPTS(CLBR_NONE)
 939         SAVE_REST
 940         movq $-1,ORIG_RAX(%rsp)
 941         xorl %esi,%esi          # oldset
 942         movq %rsp,%rdi          # &pt_regs
 943         call do_notify_resume
 944         RESTORE_REST
 945         DISABLE_INTERRUPTS(CLBR_NONE)
 946         TRACE_IRQS_OFF
 947         GET_THREAD_INFO(%rcx)
 948         jmp retint_with_reschedule
 949
 950 #ifdef CONFIG_PREEMPT
 951         /* Returning to kernel space. Check if we need preemption */
 952         /* rcx:  threadinfo. interrupts off. */
 953 ENTRY(retint_kernel)
 954         cmpl $0,TI_preempt_count(%rcx)
 955         jnz  retint_restore_args
 956         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 957         jnc  retint_restore_args
 958         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 959         jnc  retint_restore_args
 960         call preempt_schedule_irq
 961         jmp exit_intr
 962 #endif
 963
 964         CFI_ENDPROC
 965 END(common_interrupt)
 966
 967 /*
 968  * APIC interrupts.
 969  */
 970 .macro apicinterrupt num sym do_sym
 971 ENTRY(\sym)
 972         INTR_FRAME
 973         pushq $~(\num)
 974         CFI_ADJUST_CFA_OFFSET 8
 975         interrupt \do_sym
 976         jmp ret_from_intr
 977         CFI_ENDPROC
 978 END(\sym)
 979 .endm
 980
 981 #ifdef CONFIG_SMP
 982 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 983         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 984 #endif
 985
 986 #ifdef CONFIG_X86_UV
 987 apicinterrupt UV_BAU_MESSAGE \
 988         uv_bau_message_intr1 uv_bau_message_interrupt
 989 #endif
 990 apicinterrupt LOCAL_TIMER_VECTOR \
 991         apic_timer_interrupt smp_apic_timer_interrupt
 992
 993 #ifdef CONFIG_SMP
 994 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
 995         invalidate_interrupt0 smp_invalidate_interrupt
 996 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
 997         invalidate_interrupt1 smp_invalidate_interrupt
 998 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
 999         invalidate_interrupt2 smp_invalidate_interrupt
1000 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
1001         invalidate_interrupt3 smp_invalidate_interrupt
1002 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
1003         invalidate_interrupt4 smp_invalidate_interrupt
1004 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
1005         invalidate_interrupt5 smp_invalidate_interrupt
1006 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
1007         invalidate_interrupt6 smp_invalidate_interrupt
1008 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
1009         invalidate_interrupt7 smp_invalidate_interrupt
1010 #endif
1011
1012 apicinterrupt THRESHOLD_APIC_VECTOR \
1013         threshold_interrupt mce_threshold_interrupt
1014 apicinterrupt THERMAL_APIC_VECTOR \
1015         thermal_interrupt smp_thermal_interrupt
1016
1017 #ifdef CONFIG_SMP
1018 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1019         call_function_single_interrupt smp_call_function_single_interrupt
1020 apicinterrupt CALL_FUNCTION_VECTOR \
1021         call_function_interrupt smp_call_function_interrupt
1022 apicinterrupt RESCHEDULE_VECTOR \
1023         reschedule_interrupt smp_reschedule_interrupt
1024 #endif
1025
1026 apicinterrupt ERROR_APIC_VECTOR \
1027         error_interrupt smp_error_interrupt
1028 apicinterrupt SPURIOUS_APIC_VECTOR \
1029         spurious_interrupt smp_spurious_interrupt
1030
1031 #ifdef CONFIG_PERF_COUNTERS
1032 apicinterrupt LOCAL_PERF_VECTOR \
1033         perf_counter_interrupt smp_perf_counter_interrupt
1034 #endif
1035
1036 /*
1037  * Exception entry points.
1038  */
1039 .macro zeroentry sym do_sym
1040 ENTRY(\sym)
1041         INTR_FRAME
1042         PARAVIRT_ADJUST_EXCEPTION_FRAME
1043         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1044         subq $15*8,%rsp
1045         CFI_ADJUST_CFA_OFFSET 15*8
1046         call error_entry
1047         DEFAULT_FRAME 0
1048         movq %rsp,%rdi          /* pt_regs pointer */
1049         xorl %esi,%esi          /* no error code */
1050         call \do_sym
1051         jmp error_exit          /* %ebx: no swapgs flag */
1052         CFI_ENDPROC
1053 END(\sym)
1054 .endm
1055
1056 .macro paranoidzeroentry sym do_sym
1057 ENTRY(\sym)
1058         INTR_FRAME
1059         PARAVIRT_ADJUST_EXCEPTION_FRAME
1060         pushq $-1               /* ORIG_RAX: no syscall to restart */
1061         CFI_ADJUST_CFA_OFFSET 8
1062         subq $15*8, %rsp
1063         call save_paranoid
1064         TRACE_IRQS_OFF
1065         movq %rsp,%rdi          /* pt_regs pointer */
1066         xorl %esi,%esi          /* no error code */
1067         call \do_sym
1068         jmp paranoid_exit       /* %ebx: no swapgs flag */
1069         CFI_ENDPROC
1070 END(\sym)
1071 .endm
1072
1073 .macro paranoidzeroentry_ist sym do_sym ist
1074 ENTRY(\sym)
1075         INTR_FRAME
1076         PARAVIRT_ADJUST_EXCEPTION_FRAME
1077         pushq $-1               /* ORIG_RAX: no syscall to restart */
1078         CFI_ADJUST_CFA_OFFSET 8
1079         subq $15*8, %rsp
1080         call save_paranoid
1081         TRACE_IRQS_OFF
1082         movq %rsp,%rdi          /* pt_regs pointer */
1083         xorl %esi,%esi          /* no error code */
1084         PER_CPU(init_tss, %rbp)
1085         subq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1086         call \do_sym
1087         addq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1088         jmp paranoid_exit       /* %ebx: no swapgs flag */
1089         CFI_ENDPROC
1090 END(\sym)
1091 .endm
1092
1093 .macro errorentry sym do_sym
1094 ENTRY(\sym)
1095         XCPT_FRAME
1096         PARAVIRT_ADJUST_EXCEPTION_FRAME
1097         subq $15*8,%rsp
1098         CFI_ADJUST_CFA_OFFSET 15*8
1099         call error_entry
1100         DEFAULT_FRAME 0
1101         movq %rsp,%rdi                  /* pt_regs pointer */
1102         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1103         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1104         call \do_sym
1105         jmp error_exit                  /* %ebx: no swapgs flag */
1106         CFI_ENDPROC
1107 END(\sym)
1108 .endm
1109
1110         /* error code is on the stack already */
1111 .macro paranoiderrorentry sym do_sym
1112 ENTRY(\sym)
1113         XCPT_FRAME
1114         PARAVIRT_ADJUST_EXCEPTION_FRAME
1115         subq $15*8,%rsp
1116         CFI_ADJUST_CFA_OFFSET 15*8
1117         call save_paranoid
1118         DEFAULT_FRAME 0
1119         TRACE_IRQS_OFF
1120         movq %rsp,%rdi                  /* pt_regs pointer */
1121         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1122         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1123         call \do_sym
1124         jmp paranoid_exit               /* %ebx: no swapgs flag */
1125         CFI_ENDPROC
1126 END(\sym)
1127 .endm
1128
1129 zeroentry divide_error do_divide_error
1130 zeroentry overflow do_overflow
1131 zeroentry bounds do_bounds
1132 zeroentry invalid_op do_invalid_op
1133 zeroentry device_not_available do_device_not_available
1134 paranoiderrorentry double_fault do_double_fault
1135 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1136 errorentry invalid_TSS do_invalid_TSS
1137 errorentry segment_not_present do_segment_not_present
1138 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1139 zeroentry coprocessor_error do_coprocessor_error
1140 errorentry alignment_check do_alignment_check
1141 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1142
1143         /* Reload gs selector with exception handling */
1144         /* edi:  new selector */
1145 ENTRY(native_load_gs_index)
1146         CFI_STARTPROC
1147         pushf
1148         CFI_ADJUST_CFA_OFFSET 8
1149         DISABLE_INTERRUPTS(CLBR_ANY | ~(CLBR_RDI))
1150         SWAPGS
1151 gs_change:
1152         movl %edi,%gs
1153 2:      mfence          /* workaround */
1154         SWAPGS
1155         popf
1156         CFI_ADJUST_CFA_OFFSET -8
1157         ret
1158         CFI_ENDPROC
1159 END(native_load_gs_index)
1160
1161         .section __ex_table,"a"
1162         .align 8
1163         .quad gs_change,bad_gs
1164         .previous
1165         .section .fixup,"ax"
1166         /* running with kernelgs */
1167 bad_gs:
1168         SWAPGS                  /* switch back to user gs */
1169         xorl %eax,%eax
1170         movl %eax,%gs
1171         jmp  2b
1172         .previous
1173
1174 /*
1175  * Create a kernel thread.
1176  *
1177  * C extern interface:
1178  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1179  *
1180  * asm input arguments:
1181  *      rdi: fn, rsi: arg, rdx: flags
1182  */
1183 ENTRY(kernel_thread)
1184         CFI_STARTPROC
1185         FAKE_STACK_FRAME $child_rip
1186         SAVE_ALL
1187
1188         # rdi: flags, rsi: usp, rdx: will be &pt_regs
1189         movq %rdx,%rdi
1190         orq  kernel_thread_flags(%rip),%rdi
1191         movq $-1, %rsi
1192         movq %rsp, %rdx
1193
1194         xorl %r8d,%r8d
1195         xorl %r9d,%r9d
1196
1197         # clone now
1198         call do_fork
1199         movq %rax,RAX(%rsp)
1200         xorl %edi,%edi
1201
1202         /*
1203          * It isn't worth to check for reschedule here,
1204          * so internally to the x86_64 port you can rely on kernel_thread()
1205          * not to reschedule the child before returning, this avoids the need
1206          * of hacks for example to fork off the per-CPU idle tasks.
1207          * [Hopefully no generic code relies on the reschedule -AK]
1208          */
1209         RESTORE_ALL
1210         UNFAKE_STACK_FRAME
1211         ret
1212         CFI_ENDPROC
1213 END(kernel_thread)
1214
1215 ENTRY(child_rip)
1216         pushq $0                # fake return address
1217         CFI_STARTPROC
1218         /*
1219          * Here we are in the child and the registers are set as they were
1220          * at kernel_thread() invocation in the parent.
1221          */
1222         movq %rdi, %rax
1223         movq %rsi, %rdi
1224         call *%rax
1225         # exit
1226         mov %eax, %edi
1227         call do_exit
1228         ud2                     # padding for call trace
1229         CFI_ENDPROC
1230 END(child_rip)
1231
1232 /*
1233  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1234  *
1235  * C extern interface:
1236  *       extern long execve(char *name, char **argv, char **envp)
1237  *
1238  * asm input arguments:
1239  *      rdi: name, rsi: argv, rdx: envp
1240  *
1241  * We want to fallback into:
1242  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1243  *
1244  * do_sys_execve asm fallback arguments:
1245  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1246  */
1247 ENTRY(kernel_execve)
1248         CFI_STARTPROC
1249         FAKE_STACK_FRAME $0
1250         SAVE_ALL
1251         movq %rsp,%rcx
1252         call sys_execve
1253         movq %rax, RAX(%rsp)
1254         RESTORE_REST
1255         testq %rax,%rax
1256         je int_ret_from_sys_call
1257         RESTORE_ARGS
1258         UNFAKE_STACK_FRAME
1259         ret
1260         CFI_ENDPROC
1261 END(kernel_execve)
1262
1263 /* Call softirq on interrupt stack. Interrupts are off. */
1264 ENTRY(call_softirq)
1265         CFI_STARTPROC
1266         push %rbp
1267         CFI_ADJUST_CFA_OFFSET   8
1268         CFI_REL_OFFSET rbp,0
1269         mov  %rsp,%rbp
1270         CFI_DEF_CFA_REGISTER rbp
1271         incl PER_CPU_VAR(irq_count)
1272         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1273         push  %rbp                      # backlink for old unwinder
1274         call __do_softirq
1275         leaveq
1276         CFI_DEF_CFA_REGISTER    rsp
1277         CFI_ADJUST_CFA_OFFSET   -8
1278         decl PER_CPU_VAR(irq_count)
1279         ret
1280         CFI_ENDPROC
1281 END(call_softirq)
1282
1283 #ifdef CONFIG_XEN
1284 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1285
1286 /*
1287  * A note on the "critical region" in our callback handler.
1288  * We want to avoid stacking callback handlers due to events occurring
1289  * during handling of the last event. To do this, we keep events disabled
1290  * until we've done all processing. HOWEVER, we must enable events before
1291  * popping the stack frame (can't be done atomically) and so it would still
1292  * be possible to get enough handler activations to overflow the stack.
1293  * Although unlikely, bugs of that kind are hard to track down, so we'd
1294  * like to avoid the possibility.
1295  * So, on entry to the handler we detect whether we interrupted an
1296  * existing activation in its critical region -- if so, we pop the current
1297  * activation and restart the handler using the previous one.
1298  */
1299 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1300         CFI_STARTPROC
1301 /*
1302  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1303  * see the correct pointer to the pt_regs
1304  */
1305         movq %rdi, %rsp            # we don't return, adjust the stack frame
1306         CFI_ENDPROC
1307         DEFAULT_FRAME
1308 11:     incl PER_CPU_VAR(irq_count)
1309         movq %rsp,%rbp
1310         CFI_DEF_CFA_REGISTER rbp
1311         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1312         pushq %rbp                      # backlink for old unwinder
1313         call xen_evtchn_do_upcall
1314         popq %rsp
1315         CFI_DEF_CFA_REGISTER rsp
1316         decl PER_CPU_VAR(irq_count)
1317         jmp  error_exit
1318         CFI_ENDPROC
1319 END(do_hypervisor_callback)
1320
1321 /*
1322  * Hypervisor uses this for application faults while it executes.
1323  * We get here for two reasons:
1324  *  1. Fault while reloading DS, ES, FS or GS
1325  *  2. Fault while executing IRET
1326  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1327  * registers that could be reloaded and zeroed the others.
1328  * Category 2 we fix up by killing the current process. We cannot use the
1329  * normal Linux return path in this case because if we use the IRET hypercall
1330  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1331  * We distinguish between categories by comparing each saved segment register
1332  * with its current contents: any discrepancy means we in category 1.
1333  */
1334 ENTRY(xen_failsafe_callback)
1335         INTR_FRAME 1 (6*8)
1336         /*CFI_REL_OFFSET gs,GS*/
1337         /*CFI_REL_OFFSET fs,FS*/
1338         /*CFI_REL_OFFSET es,ES*/
1339         /*CFI_REL_OFFSET ds,DS*/
1340         CFI_REL_OFFSET r11,8
1341         CFI_REL_OFFSET rcx,0
1342         movw %ds,%cx
1343         cmpw %cx,0x10(%rsp)
1344         CFI_REMEMBER_STATE
1345         jne 1f
1346         movw %es,%cx
1347         cmpw %cx,0x18(%rsp)
1348         jne 1f
1349         movw %fs,%cx
1350         cmpw %cx,0x20(%rsp)
1351         jne 1f
1352         movw %gs,%cx
1353         cmpw %cx,0x28(%rsp)
1354         jne 1f
1355         /* All segments match their saved values => Category 2 (Bad IRET). */
1356         movq (%rsp),%rcx
1357         CFI_RESTORE rcx
1358         movq 8(%rsp),%r11
1359         CFI_RESTORE r11
1360         addq $0x30,%rsp
1361         CFI_ADJUST_CFA_OFFSET -0x30
1362         pushq_cfi $0    /* RIP */
1363         pushq_cfi %r11
1364         pushq_cfi %rcx
1365         jmp general_protection
1366         CFI_RESTORE_STATE
1367 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1368         movq (%rsp),%rcx
1369         CFI_RESTORE rcx
1370         movq 8(%rsp),%r11
1371         CFI_RESTORE r11
1372         addq $0x30,%rsp
1373         CFI_ADJUST_CFA_OFFSET -0x30
1374         pushq_cfi $0
1375         SAVE_ALL
1376         jmp error_exit
1377         CFI_ENDPROC
1378 END(xen_failsafe_callback)
1379
1380 #endif /* CONFIG_XEN */
1381
1382 /*
1383  * Some functions should be protected against kprobes
1384  */
1385         .pushsection .kprobes.text, "ax"
1386
1387 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1388 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1389 paranoiderrorentry stack_segment do_stack_segment
1390 errorentry general_protection do_general_protection
1391 errorentry page_fault do_page_fault
1392 #ifdef CONFIG_X86_MCE
1393 paranoidzeroentry machine_check do_machine_check
1394 #endif
1395
1396         /*
1397          * "Paranoid" exit path from exception stack.
1398          * Paranoid because this is used by NMIs and cannot take
1399          * any kernel state for granted.
1400          * We don't do kernel preemption checks here, because only
1401          * NMI should be common and it does not enable IRQs and
1402          * cannot get reschedule ticks.
1403          *
1404          * "trace" is 0 for the NMI handler only, because irq-tracing
1405          * is fundamentally NMI-unsafe. (we cannot change the soft and
1406          * hard flags at once, atomically)
1407          */
1408
1409         /* ebx: no swapgs flag */
1410 ENTRY(paranoid_exit)
1411         INTR_FRAME
1412         DISABLE_INTERRUPTS(CLBR_NONE)
1413         TRACE_IRQS_OFF
1414         testl %ebx,%ebx                         /* swapgs needed? */
1415         jnz paranoid_restore
1416         testl $3,CS(%rsp)
1417         jnz   paranoid_userspace
1418 paranoid_swapgs:
1419         TRACE_IRQS_IRETQ 0
1420         SWAPGS_UNSAFE_STACK
1421 paranoid_restore:
1422         RESTORE_ALL 8
1423         jmp irq_return
1424 paranoid_userspace:
1425         GET_THREAD_INFO(%rcx)
1426         movl TI_flags(%rcx),%ebx
1427         andl $_TIF_WORK_MASK,%ebx
1428         jz paranoid_swapgs
1429         movq %rsp,%rdi                  /* &pt_regs */
1430         call sync_regs
1431         movq %rax,%rsp                  /* switch stack for scheduling */
1432         testl $_TIF_NEED_RESCHED,%ebx
1433         jnz paranoid_schedule
1434         movl %ebx,%edx                  /* arg3: thread flags */
1435         TRACE_IRQS_ON
1436         ENABLE_INTERRUPTS(CLBR_NONE)
1437         xorl %esi,%esi                  /* arg2: oldset */
1438         movq %rsp,%rdi                  /* arg1: &pt_regs */
1439         call do_notify_resume
1440         DISABLE_INTERRUPTS(CLBR_NONE)
1441         TRACE_IRQS_OFF
1442         jmp paranoid_userspace
1443 paranoid_schedule:
1444         TRACE_IRQS_ON
1445         ENABLE_INTERRUPTS(CLBR_ANY)
1446         call schedule
1447         DISABLE_INTERRUPTS(CLBR_ANY)
1448         TRACE_IRQS_OFF
1449         jmp paranoid_userspace
1450         CFI_ENDPROC
1451 END(paranoid_exit)
1452
1453 /*
1454  * Exception entry point. This expects an error code/orig_rax on the stack.
1455  * returns in "no swapgs flag" in %ebx.
1456  */
1457 ENTRY(error_entry)
1458         XCPT_FRAME
1459         CFI_ADJUST_CFA_OFFSET 15*8
1460         /* oldrax contains error code */
1461         cld
1462         movq_cfi rdi, RDI+8
1463         movq_cfi rsi, RSI+8
1464         movq_cfi rdx, RDX+8
1465         movq_cfi rcx, RCX+8
1466         movq_cfi rax, RAX+8
1467         movq_cfi  r8,  R8+8
1468         movq_cfi  r9,  R9+8
1469         movq_cfi r10, R10+8
1470         movq_cfi r11, R11+8
1471         movq_cfi rbx, RBX+8
1472         movq_cfi rbp, RBP+8
1473         movq_cfi r12, R12+8
1474         movq_cfi r13, R13+8
1475         movq_cfi r14, R14+8
1476         movq_cfi r15, R15+8
1477         xorl %ebx,%ebx
1478         testl $3,CS+8(%rsp)
1479         je error_kernelspace
1480 error_swapgs:
1481         SWAPGS
1482 error_sti:
1483         TRACE_IRQS_OFF
1484         ret
1485         CFI_ENDPROC
1486
1487 /*
1488  * There are two places in the kernel that can potentially fault with
1489  * usergs. Handle them here. The exception handlers after iret run with
1490  * kernel gs again, so don't set the user space flag. B stepping K8s
1491  * sometimes report an truncated RIP for IRET exceptions returning to
1492  * compat mode. Check for these here too.
1493  */
1494 error_kernelspace:
1495         incl %ebx
1496         leaq irq_return(%rip),%rcx
1497         cmpq %rcx,RIP+8(%rsp)
1498         je error_swapgs
1499         movl %ecx,%ecx  /* zero extend */
1500         cmpq %rcx,RIP+8(%rsp)
1501         je error_swapgs
1502         cmpq $gs_change,RIP+8(%rsp)
1503         je error_swapgs
1504         jmp error_sti
1505 END(error_entry)
1506
1507
1508 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1509 ENTRY(error_exit)
1510         DEFAULT_FRAME
1511         movl %ebx,%eax
1512         RESTORE_REST
1513         DISABLE_INTERRUPTS(CLBR_NONE)
1514         TRACE_IRQS_OFF
1515         GET_THREAD_INFO(%rcx)
1516         testl %eax,%eax
1517         jne retint_kernel
1518         LOCKDEP_SYS_EXIT_IRQ
1519         movl TI_flags(%rcx),%edx
1520         movl $_TIF_WORK_MASK,%edi
1521         andl %edi,%edx
1522         jnz retint_careful
1523         jmp retint_swapgs
1524         CFI_ENDPROC
1525 END(error_exit)
1526
1527
1528         /* runs on exception stack */
1529 ENTRY(nmi)
1530         INTR_FRAME
1531         PARAVIRT_ADJUST_EXCEPTION_FRAME
1532         pushq_cfi $-1
1533         subq $15*8, %rsp
1534         CFI_ADJUST_CFA_OFFSET 15*8
1535         call save_paranoid
1536         DEFAULT_FRAME 0
1537         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1538         movq %rsp,%rdi
1539         movq $-1,%rsi
1540         call do_nmi
1541 #ifdef CONFIG_TRACE_IRQFLAGS
1542         /* paranoidexit; without TRACE_IRQS_OFF */
1543         /* ebx: no swapgs flag */
1544         DISABLE_INTERRUPTS(CLBR_NONE)
1545         testl %ebx,%ebx                         /* swapgs needed? */
1546         jnz nmi_restore
1547         testl $3,CS(%rsp)
1548         jnz nmi_userspace
1549 nmi_swapgs:
1550         SWAPGS_UNSAFE_STACK
1551 nmi_restore:
1552         RESTORE_ALL 8
1553         jmp irq_return
1554 nmi_userspace:
1555         GET_THREAD_INFO(%rcx)
1556         movl TI_flags(%rcx),%ebx
1557         andl $_TIF_WORK_MASK,%ebx
1558         jz nmi_swapgs
1559         movq %rsp,%rdi                  /* &pt_regs */
1560         call sync_regs
1561         movq %rax,%rsp                  /* switch stack for scheduling */
1562         testl $_TIF_NEED_RESCHED,%ebx
1563         jnz nmi_schedule
1564         movl %ebx,%edx                  /* arg3: thread flags */
1565         ENABLE_INTERRUPTS(CLBR_NONE)
1566         xorl %esi,%esi                  /* arg2: oldset */
1567         movq %rsp,%rdi                  /* arg1: &pt_regs */
1568         call do_notify_resume
1569         DISABLE_INTERRUPTS(CLBR_NONE)
1570         jmp nmi_userspace
1571 nmi_schedule:
1572         ENABLE_INTERRUPTS(CLBR_ANY)
1573         call schedule
1574         DISABLE_INTERRUPTS(CLBR_ANY)
1575         jmp nmi_userspace
1576         CFI_ENDPROC
1577 #else
1578         jmp paranoid_exit
1579         CFI_ENDPROC
1580 #endif
1581 END(nmi)
1582
1583 ENTRY(ignore_sysret)
1584         CFI_STARTPROC
1585         mov $-ENOSYS,%eax
1586         sysret
1587         CFI_ENDPROC
1588 END(ignore_sysret)
1589
1590 /*
1591  * End of kprobes section
1592  */
1593         .popsection