SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/sh/kernel/vmlinux.lds.S

   1 /*
   2  * ld script to make SuperH Linux kernel
   3  * Written by Niibe Yutaka and Paul Mundt
   4  */
   5 #ifdef CONFIG_SUPERH64
   6 #define LOAD_OFFSET     PAGE_OFFSET
   7 #define MEMORY_OFFSET   __MEMORY_START
   8 OUTPUT_ARCH(sh:sh5)
   9 #else
  10 #define LOAD_OFFSET     0
  11 #define MEMORY_OFFSET   0
  12 OUTPUT_ARCH(sh)
  13 #endif
  14
  15 #include <asm/thread_info.h>
  16 #include <asm/cache.h>
  17 #include <asm/vmlinux.lds.h>
  18
  19 ENTRY(_start)
  20 SECTIONS
  21 {
  22         . = PAGE_OFFSET + MEMORY_OFFSET + CONFIG_ZERO_PAGE_OFFSET;
  23
  24         _text = .;              /* Text and read-only data */
  25
  26         .empty_zero_page : AT(ADDR(.empty_zero_page) - LOAD_OFFSET) {
  27                 *(.empty_zero_page)
  28         } = 0
  29
  30         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  31                 HEAD_TEXT
  32                 TEXT_TEXT
  33                 EXTRA_TEXT
  34                 SCHED_TEXT
  35                 LOCK_TEXT
  36                 KPROBES_TEXT
  37                 IRQENTRY_TEXT
  38                 *(.fixup)
  39                 *(.gnu.warning)
  40                 _etext = .;             /* End of text section */
  41         } = 0x0009
  42
  43         EXCEPTION_TABLE(16)
  44         NOTES
  45
  46         _sdata = .;
  47         RO_DATA(PAGE_SIZE)
  48         RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
  49         _edata = .;
  50
  51         DWARF_EH_FRAME
  52
  53         . = ALIGN(PAGE_SIZE);           /* Init code and data */
  54         __init_begin = .;
  55         INIT_TEXT_SECTION(PAGE_SIZE)
  56         INIT_DATA_SECTION(16)
  57
  58         . = ALIGN(4);
  59         .machvec.init : AT(ADDR(.machvec.init) - LOAD_OFFSET) {
  60                 __machvec_start = .;
  61                 *(.machvec.init)
  62                 __machvec_end = .;
  63         }
  64
  65         PERCPU(PAGE_SIZE)
  66
  67         /*
  68          * .exit.text is discarded at runtime, not link time, to deal with
  69          * references from __bug_table
  70          */
  71         .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { EXIT_TEXT }
  72         .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { EXIT_DATA }
  73
  74         . = ALIGN(PAGE_SIZE);
  75         __init_end = .;
  76         BSS_SECTION(0, PAGE_SIZE, 4)
  77         _ebss = .;                      /* uClinux MTD sucks */
  78         _end = . ;
  79
  80         STABS_DEBUG
  81         DWARF_DEBUG
  82
  83         DISCARDS
  84 }