SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/powerpc/kernel/head_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *
   5  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   6  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   7  *  Adapted for Power Macintosh by Paul Mackerras.
   8  *  Low-level exception handlers and MMU support
   9  *  rewritten by Paul Mackerras.
  10  *    Copyright (C) 1996 Paul Mackerras.
  11  *
  12  *  Adapted for 64bit PowerPC by Dave Engebretsen, Peter Bergner, and
  13  *    Mike Corrigan {engebret|bergner|mikejc}@us.ibm.com
  14  *
  15  *  This file contains the entry point for the 64-bit kernel along
  16  *  with some early initialization code common to all 64-bit powerpc
  17  *  variants.
  18  *
  19  *  This program is free software; you can redistribute it and/or
  20  *  modify it under the terms of the GNU General Public License
  21  *  as published by the Free Software Foundation; either version
  22  *  2 of the License, or (at your option) any later version.
  23  */
  24
  25 #include <linux/threads.h>
  26 #include <asm/reg.h>
  27 #include <asm/page.h>
  28 #include <asm/mmu.h>
  29 #include <asm/ppc_asm.h>
  30 #include <asm/asm-offsets.h>
  31 #include <asm/bug.h>
  32 #include <asm/cputable.h>
  33 #include <asm/setup.h>
  34 #include <asm/hvcall.h>
  35 #include <asm/iseries/lpar_map.h>
  36 #include <asm/thread_info.h>
  37 #include <asm/firmware.h>
  38 #include <asm/page_64.h>
  39 #include <asm/irqflags.h>
  40 #include <asm/kvm_book3s_64_asm.h>
  41
  42 /* The physical memory is layed out such that the secondary processor
  43  * spin code sits at 0x0000...0x00ff. On server, the vectors follow
  44  * using the layout described in exceptions-64s.S
  45  */
  46
  47 /*
  48  * Entering into this code we make the following assumptions:
  49  *
  50  *  For pSeries or server processors:
  51  *   1. The MMU is off & open firmware is running in real mode.
  52  *   2. The kernel is entered at __start
  53  *
  54  *  For iSeries:
  55  *   1. The MMU is on (as it always is for iSeries)
  56  *   2. The kernel is entered at system_reset_iSeries
  57  *
  58  *  For Book3E processors:
  59  *   1. The MMU is on running in AS0 in a state defined in ePAPR
  60  *   2. The kernel is entered at __start
  61  */
  62
  63         .text
  64         .globl  _stext
  65 _stext:
  66 _GLOBAL(__start)
  67         /* NOP this out unconditionally */
  68 BEGIN_FTR_SECTION
  69         b       .__start_initialization_multiplatform
  70 END_FTR_SECTION(0, 1)
  71
  72         /* Catch branch to 0 in real mode */
  73         trap
  74
  75         /* Secondary processors spin on this value until it becomes nonzero.
  76          * When it does it contains the real address of the descriptor
  77          * of the function that the cpu should jump to to continue
  78          * initialization.
  79          */
  80         .globl  __secondary_hold_spinloop
  81 __secondary_hold_spinloop:
  82         .llong  0x0
  83
  84         /* Secondary processors write this value with their cpu # */
  85         /* after they enter the spin loop immediately below.      */
  86         .globl  __secondary_hold_acknowledge
  87 __secondary_hold_acknowledge:
  88         .llong  0x0
  89
  90 #ifdef CONFIG_PPC_ISERIES
  91         /*
  92          * At offset 0x20, there is a pointer to iSeries LPAR data.
  93          * This is required by the hypervisor
  94          */
  95         . = 0x20
  96         .llong hvReleaseData-KERNELBASE
  97 #endif /* CONFIG_PPC_ISERIES */
  98
  99 #ifdef CONFIG_CRASH_DUMP
 100         /* This flag is set to 1 by a loader if the kernel should run
 101          * at the loaded address instead of the linked address.  This
 102          * is used by kexec-tools to keep the the kdump kernel in the
 103          * crash_kernel region.  The loader is responsible for
 104          * observing the alignment requirement.
 105          */
 106         /* Do not move this variable as kexec-tools knows about it. */
 107         . = 0x5c
 108         .globl  __run_at_load
 109 __run_at_load:
 110         .long   0x72756e30      /* "run0" -- relocate to 0 by default */
 111 #endif
 112
 113         . = 0x60
 114 /*
 115  * The following code is used to hold secondary processors
 116  * in a spin loop after they have entered the kernel, but
 117  * before the bulk of the kernel has been relocated.  This code
 118  * is relocated to physical address 0x60 before prom_init is run.
 119  * All of it must fit below the first exception vector at 0x100.
 120  * Use .globl here not _GLOBAL because we want __secondary_hold
 121  * to be the actual text address, not a descriptor.
 122  */
 123         .globl  __secondary_hold
 124 __secondary_hold:
 125 #ifndef CONFIG_PPC_BOOK3E
 126         mfmsr   r24
 127         ori     r24,r24,MSR_RI
 128         mtmsrd  r24                     /* RI on */
 129 #endif
 130         /* Grab our physical cpu number */
 131         mr      r24,r3
 132
 133         /* Tell the master cpu we're here */
 134         /* Relocation is off & we are located at an address less */
 135         /* than 0x100, so only need to grab low order offset.    */
 136         std     r24,__secondary_hold_acknowledge-_stext(0)
 137         sync
 138
 139         /* All secondary cpus wait here until told to start. */
 140 100:    ld      r4,__secondary_hold_spinloop-_stext(0)
 141         cmpdi   0,r4,0
 142         beq     100b
 143
 144 #if defined(CONFIG_SMP) || defined(CONFIG_KEXEC)
 145         ld      r4,0(r4)                /* deref function descriptor */
 146         mtctr   r4
 147         mr      r3,r24
 148         li      r4,0
 149         bctr
 150 #else
 151         BUG_OPCODE
 152 #endif
 153
 154 /* This value is used to mark exception frames on the stack. */
 155         .section ".toc","aw"
 156 exception_marker:
 157         .tc     ID_72656773_68657265[TC],0x7265677368657265
 158         .text
 159
 160 /*
 161  * On server, we include the exception vectors code here as it
 162  * relies on absolute addressing which is only possible within
 163  * this compilation unit
 164  */
 165 #ifdef CONFIG_PPC_BOOK3S
 166 #include "exceptions-64s.S"
 167 #endif
 168
 169 /* KVM trampoline code needs to be close to the interrupt handlers */
 170
 171 #ifdef CONFIG_KVM_BOOK3S_64_HANDLER
 172 #include "../kvm/book3s_64_rmhandlers.S"
 173 #endif
 174
 175 _GLOBAL(generic_secondary_thread_init)
 176         mr      r24,r3
 177
 178         /* turn on 64-bit mode */
 179         bl      .enable_64b_mode
 180
 181         /* get a valid TOC pointer, wherever we're mapped at */
 182         bl      .relative_toc
 183
 184 #ifdef CONFIG_PPC_BOOK3E
 185         /* Book3E initialization */
 186         mr      r3,r24
 187         bl      .book3e_secondary_thread_init
 188 #endif
 189         b       generic_secondary_common_init
 190
 191 /*
 192  * On pSeries and most other platforms, secondary processors spin
 193  * in the following code.
 194  * At entry, r3 = this processor's number (physical cpu id)
 195  *
 196  * On Book3E, r4 = 1 to indicate that the initial TLB entry for
 197  * this core already exists (setup via some other mechanism such
 198  * as SCOM before entry).
 199  */
 200 _GLOBAL(generic_secondary_smp_init)
 201         mr      r24,r3
 202         mr      r25,r4
 203
 204         /* turn on 64-bit mode */
 205         bl      .enable_64b_mode
 206
 207         /* get a valid TOC pointer, wherever we're mapped at */
 208         bl      .relative_toc
 209
 210 #ifdef CONFIG_PPC_BOOK3E
 211         /* Book3E initialization */
 212         mr      r3,r24
 213         mr      r4,r25
 214         bl      .book3e_secondary_core_init
 215 #endif
 216
 217 generic_secondary_common_init:
 218         /* Set up a paca value for this processor. Since we have the
 219          * physical cpu id in r24, we need to search the pacas to find
 220          * which logical id maps to our physical one.
 221          */
 222         LOAD_REG_ADDR(r13, paca)        /* Get base vaddr of paca array  */
 223         li      r5,0                    /* logical cpu id                */
 224 1:      lhz     r6,PACAHWCPUID(r13)     /* Load HW procid from paca      */
 225         cmpw    r6,r24                  /* Compare to our id             */
 226         beq     2f
 227         addi    r13,r13,PACA_SIZE       /* Loop to next PACA on miss     */
 228         addi    r5,r5,1
 229         cmpwi   r5,NR_CPUS
 230         blt     1b
 231
 232         mr      r3,r24                  /* not found, copy phys to r3    */
 233         b       .kexec_wait             /* next kernel might do better   */
 234
 235 2:      mtspr   SPRN_SPRG_PACA,r13      /* Save vaddr of paca in an SPRG */
 236 #ifdef CONFIG_PPC_BOOK3E
 237         addi    r12,r13,PACA_EXTLB      /* and TLB exc frame in another  */
 238         mtspr   SPRN_SPRG_TLB_EXFRAME,r12
 239 #endif
 240
 241         /* From now on, r24 is expected to be logical cpuid */
 242         mr      r24,r5
 243 3:      HMT_LOW
 244         lbz     r23,PACAPROCSTART(r13)  /* Test if this processor should */
 245                                         /* start.                        */
 246
 247 #ifndef CONFIG_SMP
 248         b       3b                      /* Never go on non-SMP           */
 249 #else
 250         cmpwi   0,r23,0
 251         beq     3b                      /* Loop until told to go         */
 252
 253         sync                            /* order paca.run and cur_cpu_spec */
 254
 255         /* See if we need to call a cpu state restore handler */
 256         LOAD_REG_ADDR(r23, cur_cpu_spec)
 257         ld      r23,0(r23)
 258         ld      r23,CPU_SPEC_RESTORE(r23)
 259         cmpdi   0,r23,0
 260         beq     4f
 261         ld      r23,0(r23)
 262         mtctr   r23
 263         bctrl
 264
 265 4:      /* Create a temp kernel stack for use before relocation is on.  */
 266         ld      r1,PACAEMERGSP(r13)
 267         subi    r1,r1,STACK_FRAME_OVERHEAD
 268
 269         b       __secondary_start
 270 #endif
 271
 272 /*
 273  * Turn the MMU off.
 274  * Assumes we're mapped EA == RA if the MMU is on.
 275  */
 276 #ifdef CONFIG_PPC_BOOK3S
 277 _STATIC(__mmu_off)
 278         mfmsr   r3
 279         andi.   r0,r3,MSR_IR|MSR_DR
 280         beqlr
 281         mflr    r4
 282         andc    r3,r3,r0
 283         mtspr   SPRN_SRR0,r4
 284         mtspr   SPRN_SRR1,r3
 285         sync
 286         rfid
 287         b       .       /* prevent speculative execution */
 288 #endif
 289
 290
 291 /*
 292  * Here is our main kernel entry point. We support currently 2 kind of entries
 293  * depending on the value of r5.
 294  *
 295  *   r5 != NULL -> OF entry, we go to prom_init, "legacy" parameter content
 296  *                 in r3...r7
 297  *
 298  *   r5 == NULL -> kexec style entry. r3 is a physical pointer to the
 299  *                 DT block, r4 is a physical pointer to the kernel itself
 300  *
 301  */
 302 _GLOBAL(__start_initialization_multiplatform)
 303         /* Make sure we are running in 64 bits mode */
 304         bl      .enable_64b_mode
 305
 306         /* Get TOC pointer (current runtime address) */
 307         bl      .relative_toc
 308
 309         /* find out where we are now */
 310         bcl     20,31,$+4
 311 0:      mflr    r26                     /* r26 = runtime addr here */
 312         addis   r26,r26,(_stext - 0b)@ha
 313         addi    r26,r26,(_stext - 0b)@l /* current runtime base addr */
 314
 315         /*
 316          * Are we booted from a PROM Of-type client-interface ?
 317          */
 318         cmpldi  cr0,r5,0
 319         beq     1f
 320         b       .__boot_from_prom               /* yes -> prom */
 321 1:
 322         /* Save parameters */
 323         mr      r31,r3
 324         mr      r30,r4
 325
 326 #ifdef CONFIG_PPC_BOOK3E
 327         bl      .start_initialization_book3e
 328         b       .__after_prom_start
 329 #else
 330         /* Setup some critical 970 SPRs before switching MMU off */
 331         mfspr   r0,SPRN_PVR
 332         srwi    r0,r0,16
 333         cmpwi   r0,0x39         /* 970 */
 334         beq     1f
 335         cmpwi   r0,0x3c         /* 970FX */
 336         beq     1f
 337         cmpwi   r0,0x44         /* 970MP */
 338         beq     1f
 339         cmpwi   r0,0x45         /* 970GX */
 340         bne     2f
 341 1:      bl      .__cpu_preinit_ppc970
 342 2:
 343
 344         /* Switch off MMU if not already off */
 345         bl      .__mmu_off
 346         b       .__after_prom_start
 347 #endif /* CONFIG_PPC_BOOK3E */
 348
 349 _INIT_STATIC(__boot_from_prom)
 350 #ifdef CONFIG_PPC_OF_BOOT_TRAMPOLINE
 351         /* Save parameters */
 352         mr      r31,r3
 353         mr      r30,r4
 354         mr      r29,r5
 355         mr      r28,r6
 356         mr      r27,r7
 357
 358         /*
 359          * Align the stack to 16-byte boundary
 360          * Depending on the size and layout of the ELF sections in the initial
 361          * boot binary, the stack pointer may be unaligned on PowerMac
 362          */
 363         rldicr  r1,r1,0,59
 364
 365 #ifdef CONFIG_RELOCATABLE
 366         /* Relocate code for where we are now */
 367         mr      r3,r26
 368         bl      .relocate
 369 #endif
 370
 371         /* Restore parameters */
 372         mr      r3,r31
 373         mr      r4,r30
 374         mr      r5,r29
 375         mr      r6,r28
 376         mr      r7,r27
 377
 378         /* Do all of the interaction with OF client interface */
 379         mr      r8,r26
 380         bl      .prom_init
 381 #endif /* #CONFIG_PPC_OF_BOOT_TRAMPOLINE */
 382
 383         /* We never return. We also hit that trap if trying to boot
 384          * from OF while CONFIG_PPC_OF_BOOT_TRAMPOLINE isn't selected */
 385         trap
 386
 387 _STATIC(__after_prom_start)
 388 #ifdef CONFIG_RELOCATABLE
 389         /* process relocations for the final address of the kernel */
 390         lis     r25,PAGE_OFFSET@highest /* compute virtual base of kernel */
 391         sldi    r25,r25,32
 392 #ifdef CONFIG_CRASH_DUMP
 393         lwz     r7,__run_at_load-_stext(r26)
 394         cmplwi  cr0,r7,1        /* kdump kernel ? - stay where we are */
 395         bne     1f
 396         add     r25,r25,r26
 397 #endif
 398 1:      mr      r3,r25
 399         bl      .relocate
 400 #endif
 401
 402 /*
 403  * We need to run with _stext at physical address PHYSICAL_START.
 404  * This will leave some code in the first 256B of
 405  * real memory, which are reserved for software use.
 406  *
 407  * Note: This process overwrites the OF exception vectors.
 408  */
 409         li      r3,0                    /* target addr */
 410 #ifdef CONFIG_PPC_BOOK3E
 411         tovirt(r3,r3)                   /* on booke, we already run at PAGE_OFFSET */
 412 #endif
 413         mr.     r4,r26                  /* In some cases the loader may  */
 414         beq     9f                      /* have already put us at zero */
 415         li      r6,0x100                /* Start offset, the first 0x100 */
 416                                         /* bytes were copied earlier.    */
 417 #ifdef CONFIG_PPC_BOOK3E
 418         tovirt(r6,r6)                   /* on booke, we already run at PAGE_OFFSET */
 419 #endif
 420
 421 #ifdef CONFIG_CRASH_DUMP
 422 /*
 423  * Check if the kernel has to be running as relocatable kernel based on the
 424  * variable __run_at_load, if it is set the kernel is treated as relocatable
 425  * kernel, otherwise it will be moved to PHYSICAL_START
 426  */
 427         lwz     r7,__run_at_load-_stext(r26)
 428         cmplwi  cr0,r7,1
 429         bne     3f
 430
 431         li      r5,__end_interrupts - _stext    /* just copy interrupts */
 432         b       5f
 433 3:
 434 #endif
 435         lis     r5,(copy_to_here - _stext)@ha
 436         addi    r5,r5,(copy_to_here - _stext)@l /* # bytes of memory to copy */
 437
 438         bl      .copy_and_flush         /* copy the first n bytes        */
 439                                         /* this includes the code being  */
 440                                         /* executed here.                */
 441         addis   r8,r3,(4f - _stext)@ha  /* Jump to the copy of this code */
 442         addi    r8,r8,(4f - _stext)@l   /* that we just made */
 443         mtctr   r8
 444         bctr
 445
 446 p_end:  .llong  _end - _stext
 447
 448 4:      /* Now copy the rest of the kernel up to _end */
 449         addis   r5,r26,(p_end - _stext)@ha
 450         ld      r5,(p_end - _stext)@l(r5)       /* get _end */
 451 5:      bl      .copy_and_flush         /* copy the rest */
 452
 453 9:      b       .start_here_multiplatform
 454
 455 /*
 456  * Copy routine used to copy the kernel to start at physical address 0
 457  * and flush and invalidate the caches as needed.
 458  * r3 = dest addr, r4 = source addr, r5 = copy limit, r6 = start offset
 459  * on exit, r3, r4, r5 are unchanged, r6 is updated to be >= r5.
 460  *
 461  * Note: this routine *only* clobbers r0, r6 and lr
 462  */
 463 _GLOBAL(copy_and_flush)
 464         addi    r5,r5,-8
 465         addi    r6,r6,-8
 466 4:      li      r0,8                    /* Use the smallest common      */
 467                                         /* denominator cache line       */
 468                                         /* size.  This results in       */
 469                                         /* extra cache line flushes     */
 470                                         /* but operation is correct.    */
 471                                         /* Can't get cache line size    */
 472                                         /* from NACA as it is being     */
 473                                         /* moved too.                   */
 474
 475         mtctr   r0                      /* put # words/line in ctr      */
 476 3:      addi    r6,r6,8                 /* copy a cache line            */
 477         ldx     r0,r6,r4
 478         stdx    r0,r6,r3
 479         bdnz    3b
 480         dcbst   r6,r3                   /* write it to memory           */
 481         sync
 482         icbi    r6,r3                   /* flush the icache line        */
 483         cmpld   0,r6,r5
 484         blt     4b
 485         sync
 486         addi    r5,r5,8
 487         addi    r6,r6,8
 488         blr
 489
 490 .align 8
 491 copy_to_here:
 492
 493 #ifdef CONFIG_SMP
 494 #ifdef CONFIG_PPC_PMAC
 495 /*
 496  * On PowerMac, secondary processors starts from the reset vector, which
 497  * is temporarily turned into a call to one of the functions below.
 498  */
 499         .section ".text";
 500         .align 2 ;
 501
 502         .globl  __secondary_start_pmac_0
 503 __secondary_start_pmac_0:
 504         /* NB the entries for cpus 0, 1, 2 must each occupy 8 bytes. */
 505         li      r24,0
 506         b       1f
 507         li      r24,1
 508         b       1f
 509         li      r24,2
 510         b       1f
 511         li      r24,3
 512 1:
 513
 514 _GLOBAL(pmac_secondary_start)
 515         /* turn on 64-bit mode */
 516         bl      .enable_64b_mode
 517
 518         li      r0,0
 519         mfspr   r3,SPRN_HID4
 520         rldimi  r3,r0,40,23     /* clear bit 23 (rm_ci) */
 521         sync
 522         mtspr   SPRN_HID4,r3
 523         isync
 524         sync
 525         slbia
 526
 527         /* get TOC pointer (real address) */
 528         bl      .relative_toc
 529
 530         /* Copy some CPU settings from CPU 0 */
 531         bl      .__restore_cpu_ppc970
 532
 533         /* pSeries do that early though I don't think we really need it */
 534         mfmsr   r3
 535         ori     r3,r3,MSR_RI
 536         mtmsrd  r3                      /* RI on */
 537
 538         /* Set up a paca value for this processor. */
 539         LOAD_REG_ADDR(r4,paca)          /* Get base vaddr of paca array */
 540         mulli   r13,r24,PACA_SIZE       /* Calculate vaddr of right paca */
 541         add     r13,r13,r4              /* for this processor.          */
 542         mtspr   SPRN_SPRG_PACA,r13      /* Save vaddr of paca in an SPRG*/
 543
 544         /* Create a temp kernel stack for use before relocation is on.  */
 545         ld      r1,PACAEMERGSP(r13)
 546         subi    r1,r1,STACK_FRAME_OVERHEAD
 547
 548         b       __secondary_start
 549
 550 #endif /* CONFIG_PPC_PMAC */
 551
 552 /*
 553  * This function is called after the master CPU has released the
 554  * secondary processors.  The execution environment is relocation off.
 555  * The paca for this processor has the following fields initialized at
 556  * this point:
 557  *   1. Processor number
 558  *   2. Segment table pointer (virtual address)
 559  * On entry the following are set:
 560  *   r1        = stack pointer.  vaddr for iSeries, raddr (temp stack) for pSeries
 561  *   r24       = cpu# (in Linux terms)
 562  *   r13       = paca virtual address
 563  *   SPRG_PACA = paca virtual address
 564  */
 565         .section ".text";
 566         .align 2 ;
 567
 568         .globl  __secondary_start
 569 __secondary_start:
 570         /* Set thread priority to MEDIUM */
 571         HMT_MEDIUM
 572
 573         /* Do early setup for that CPU (stab, slb, hash table pointer) */
 574         bl      .early_setup_secondary
 575
 576         /* Initialize the kernel stack.  Just a repeat for iSeries.      */
 577         LOAD_REG_ADDR(r3, current_set)
 578         sldi    r28,r24,3               /* get current_set[cpu#]         */
 579         ldx     r1,r3,r28
 580         addi    r1,r1,THREAD_SIZE-STACK_FRAME_OVERHEAD
 581         std     r1,PACAKSAVE(r13)
 582
 583         /* Clear backchain so we get nice backtraces */
 584         li      r7,0
 585         mtlr    r7
 586
 587         /* enable MMU and jump to start_secondary */
 588         LOAD_REG_ADDR(r3, .start_secondary_prolog)
 589         LOAD_REG_IMMEDIATE(r4, MSR_KERNEL)
 590 #ifdef CONFIG_PPC_ISERIES
 591 BEGIN_FW_FTR_SECTION
 592         ori     r4,r4,MSR_EE
 593         li      r8,1
 594         stb     r8,PACAHARDIRQEN(r13)
 595 END_FW_FTR_SECTION_IFSET(FW_FEATURE_ISERIES)
 596 #endif
 597 BEGIN_FW_FTR_SECTION
 598         stb     r7,PACAHARDIRQEN(r13)
 599 END_FW_FTR_SECTION_IFCLR(FW_FEATURE_ISERIES)
 600         stb     r7,PACASOFTIRQEN(r13)
 601
 602         mtspr   SPRN_SRR0,r3
 603         mtspr   SPRN_SRR1,r4
 604         RFI
 605         b       .       /* prevent speculative execution */
 606
 607 /*
 608  * Running with relocation on at this point.  All we want to do is
 609  * zero the stack back-chain pointer and get the TOC virtual address
 610  * before going into C code.
 611  */
 612 _GLOBAL(start_secondary_prolog)
 613         ld      r2,PACATOC(r13)
 614         li      r3,0
 615         std     r3,0(r1)                /* Zero the stack frame pointer */
 616         bl      .start_secondary
 617         b       .
 618 #endif
 619
 620 /*
 621  * This subroutine clobbers r11 and r12
 622  */
 623 _GLOBAL(enable_64b_mode)
 624         mfmsr   r11                     /* grab the current MSR */
 625 #ifdef CONFIG_PPC_BOOK3E
 626         oris    r11,r11,0x8000          /* CM bit set, we'll set ICM later */
 627         mtmsr   r11
 628 #else /* CONFIG_PPC_BOOK3E */
 629         li      r12,(MSR_SF | MSR_ISF)@highest
 630         sldi    r12,r12,48
 631         or      r11,r11,r12
 632         mtmsrd  r11
 633         isync
 634 #endif
 635         blr
 636
 637 /*
 638  * This puts the TOC pointer into r2, offset by 0x8000 (as expected
 639  * by the toolchain).  It computes the correct value for wherever we
 640  * are running at the moment, using position-independent code.
 641  */
 642 _GLOBAL(relative_toc)
 643         mflr    r0
 644         bcl     20,31,$+4
 645 0:      mflr    r9
 646         ld      r2,(p_toc - 0b)(r9)
 647         add     r2,r2,r9
 648         mtlr    r0
 649         blr
 650
 651 p_toc:  .llong  __toc_start + 0x8000 - 0b
 652
 653 /*
 654  * This is where the main kernel code starts.
 655  */
 656 _INIT_STATIC(start_here_multiplatform)
 657         /* set up the TOC (real address) */
 658         bl      .relative_toc
 659
 660         /* Clear out the BSS. It may have been done in prom_init,
 661          * already but that's irrelevant since prom_init will soon
 662          * be detached from the kernel completely. Besides, we need
 663          * to clear it now for kexec-style entry.
 664          */
 665         LOAD_REG_ADDR(r11,__bss_stop)
 666         LOAD_REG_ADDR(r8,__bss_start)
 667         sub     r11,r11,r8              /* bss size                     */
 668         addi    r11,r11,7               /* round up to an even double word */
 669         srdi.   r11,r11,3               /* shift right by 3             */
 670         beq     4f
 671         addi    r8,r8,-8
 672         li      r0,0
 673         mtctr   r11                     /* zero this many doublewords   */
 674 3:      stdu    r0,8(r8)
 675         bdnz    3b
 676 4:
 677
 678 #ifndef CONFIG_PPC_BOOK3E
 679         mfmsr   r6
 680         ori     r6,r6,MSR_RI
 681         mtmsrd  r6                      /* RI on */
 682 #endif
 683
 684 #ifdef CONFIG_RELOCATABLE
 685         /* Save the physical address we're running at in kernstart_addr */
 686         LOAD_REG_ADDR(r4, kernstart_addr)
 687         clrldi  r0,r25,2
 688         std     r0,0(r4)
 689 #endif
 690
 691         /* The following gets the stack set up with the regs */
 692         /* pointing to the real addr of the kernel stack.  This is   */
 693         /* all done to support the C function call below which sets  */
 694         /* up the htab.  This is done because we have relocated the  */
 695         /* kernel but are still running in real mode. */
 696
 697         LOAD_REG_ADDR(r3,init_thread_union)
 698
 699         /* set up a stack pointer */
 700         addi    r1,r3,THREAD_SIZE
 701         li      r0,0
 702         stdu    r0,-STACK_FRAME_OVERHEAD(r1)
 703
 704         /* Do very early kernel initializations, including initial hash table,
 705          * stab and slb setup before we turn on relocation.     */
 706
 707         /* Restore parameters passed from prom_init/kexec */
 708         mr      r3,r31
 709         bl      .early_setup            /* also sets r13 and SPRG_PACA */
 710
 711         LOAD_REG_ADDR(r3, .start_here_common)
 712         ld      r4,PACAKMSR(r13)
 713         mtspr   SPRN_SRR0,r3
 714         mtspr   SPRN_SRR1,r4
 715         RFI
 716         b       .       /* prevent speculative execution */
 717
 718         /* This is where all platforms converge execution */
 719 _INIT_GLOBAL(start_here_common)
 720         /* relocation is on at this point */
 721         std     r1,PACAKSAVE(r13)
 722
 723         /* Load the TOC (virtual address) */
 724         ld      r2,PACATOC(r13)
 725
 726         bl      .setup_system
 727
 728         /* Load up the kernel context */
 729 5:
 730         li      r5,0
 731         stb     r5,PACASOFTIRQEN(r13)   /* Soft Disabled */
 732 #ifdef CONFIG_PPC_ISERIES
 733 BEGIN_FW_FTR_SECTION
 734         mfmsr   r5
 735         ori     r5,r5,MSR_EE            /* Hard Enabled on iSeries*/
 736         mtmsrd  r5
 737         li      r5,1
 738 END_FW_FTR_SECTION_IFSET(FW_FEATURE_ISERIES)
 739 #endif
 740         stb     r5,PACAHARDIRQEN(r13)   /* Hard Disabled on others */
 741
 742         bl      .start_kernel
 743
 744         /* Not reached */
 745         BUG_OPCODE
 746
 747 /*
 748  * We put a few things here that have to be page-aligned.
 749  * This stuff goes at the beginning of the bss, which is page-aligned.
 750  */
 751         .section ".bss"
 752
 753         .align  PAGE_SHIFT
 754
 755         .globl  empty_zero_page
 756 empty_zero_page:
 757         .space  PAGE_SIZE
 758
 759         .globl  swapper_pg_dir
 760 swapper_pg_dir:
 761         .space  PGD_TABLE_SIZE