SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/microblaze/kernel/head.S

   1 /*
   2  * Copyright (C) 2007-2009 Michal Simek <monstr@monstr.eu>
   3  * Copyright (C) 2007-2009 PetaLogix
   4  * Copyright (C) 2006 Atmark Techno, Inc.
   5  *
   6  * MMU code derived from arch/ppc/kernel/head_4xx.S:
   7  *    Copyright (c) 1995-1996 Gary Thomas <gdt@linuxppc.org>
   8  *      Initial PowerPC version.
   9  *    Copyright (c) 1996 Cort Dougan <cort@cs.nmt.edu>
  10  *      Rewritten for PReP
  11  *    Copyright (c) 1996 Paul Mackerras <paulus@cs.anu.edu.au>
  12  *      Low-level exception handers, MMU support, and rewrite.
  13  *    Copyright (c) 1997 Dan Malek <dmalek@jlc.net>
  14  *      PowerPC 8xx modifications.
  15  *    Copyright (c) 1998-1999 TiVo, Inc.
  16  *      PowerPC 403GCX modifications.
  17  *    Copyright (c) 1999 Grant Erickson <grant@lcse.umn.edu>
  18  *      PowerPC 403GCX/405GP modifications.
  19  *    Copyright 2000 MontaVista Software Inc.
  20  *      PPC405 modifications
  21  *      PowerPC 403GCX/405GP modifications.
  22  *      Author: MontaVista Software, Inc.
  23  *              frank_rowand@mvista.com or source@mvista.com
  24  *              debbie_chu@mvista.com
  25  *
  26  * This file is subject to the terms and conditions of the GNU General Public
  27  * License. See the file "COPYING" in the main directory of this archive
  28  * for more details.
  29  */
  30
  31 #include <linux/linkage.h>
  32 #include <asm/thread_info.h>
  33 #include <asm/page.h>
  34 #include <asm/prom.h>           /* for OF_DT_HEADER */
  35
  36 #ifdef CONFIG_MMU
  37 #include <asm/setup.h> /* COMMAND_LINE_SIZE */
  38 #include <asm/mmu.h>
  39 #include <asm/processor.h>
  40
  41 .data
  42 .global empty_zero_page
  43 .align 12
  44 empty_zero_page:
  45         .space  4096
  46 .global swapper_pg_dir
  47 swapper_pg_dir:
  48         .space  4096
  49
  50 #endif /* CONFIG_MMU */
  51
  52         .text
  53 ENTRY(_start)
  54         mfs     r1, rmsr
  55         andi    r1, r1, ~2
  56         mts     rmsr, r1
  57
  58 /*
  59  * Here is checking mechanism which check if Microblaze has msr instructions
  60  * We load msr and compare it with previous r1 value - if is the same,
  61  * msr instructions works if not - cpu don't have them.
  62  */
  63         or      r8, r0, r0 /* 0 - I have msr instr, 1 - I don't have */
  64         or      r12, r0, r0
  65         msrset  r12, 0  /* set nothing - just read msr for test */
  66         cmpu    r12, r12, r1
  67         beqi    r12, 1f
  68         ori     r8, r0, 1 /* I don't have msr */
  69 1:
  70
  71 /* r7 may point to an FDT, or there may be one linked in.
  72    if it's in r7, we've got to save it away ASAP.
  73    We ensure r7 points to a valid FDT, just in case the bootloader
  74    is broken or non-existent */
  75         beqi    r7, no_fdt_arg                  /* NULL pointer?  don't copy */
  76         lw      r11, r0, r7                     /* Does r7 point to a */
  77         rsubi   r11, r11, OF_DT_HEADER          /* valid FDT? */
  78         beqi    r11, _prepare_copy_fdt
  79         or      r7, r0, r0              /* clear R7 when not valid DTB */
  80         bnei    r11, no_fdt_arg                 /* No - get out of here */
  81 _prepare_copy_fdt:
  82         or      r11, r0, r0 /* incremment */
  83         ori     r4, r0, TOPHYS(_fdt_start)
  84         ori     r3, r0, (0x4000 - 4)
  85 _copy_fdt:
  86         lw      r12, r7, r11 /* r12 = r7 + r11 */
  87         sw      r12, r4, r11 /* addr[r4 + r11] = r12 */
  88         addik   r11, r11, 4 /* increment counting */
  89         bgtid   r3, _copy_fdt /* loop for all entries */
  90         addik   r3, r3, -4 /* descrement loop */
  91 no_fdt_arg:
  92
  93 #ifdef CONFIG_MMU
  94
  95 #ifndef CONFIG_CMDLINE_BOOL
  96 /*
  97  * handling command line
  98  * copy command line to __init_end. There is space for storing command line.
  99  */
 100         or      r6, r0, r0              /* incremment */
 101         ori     r4, r0, __init_end      /* load address of command line */
 102         tophys(r4,r4)                   /* convert to phys address */
 103         ori     r3, r0, COMMAND_LINE_SIZE - 1 /* number of loops */
 104 _copy_command_line:
 105         lbu     r7, r5, r6 /* r7=r5+r6 - r5 contain pointer to command line */
 106         sb      r7, r4, r6              /* addr[r4+r6]= r7*/
 107         addik   r6, r6, 1               /* increment counting */
 108         bgtid   r3, _copy_command_line  /* loop for all entries       */
 109         addik   r3, r3, -1              /* descrement loop */
 110         addik   r5, r4, 0               /* add new space for command line */
 111         tovirt(r5,r5)
 112 #endif /* CONFIG_CMDLINE_BOOL */
 113
 114 #ifdef NOT_COMPILE
 115 /* save bram context */
 116         or      r6, r0, r0                              /* incremment */
 117         ori     r4, r0, TOPHYS(_bram_load_start)        /* save bram context */
 118         ori     r3, r0, (LMB_SIZE - 4)
 119 _copy_bram:
 120         lw      r7, r0, r6              /* r7 = r0 + r6 */
 121         sw      r7, r4, r6              /* addr[r4 + r6] = r7*/
 122         addik   r6, r6, 4               /* increment counting */
 123         bgtid   r3, _copy_bram          /* loop for all entries */
 124         addik   r3, r3, -4              /* descrement loop */
 125 #endif
 126         /* We have to turn on the MMU right away. */
 127
 128         /*
 129          * Set up the initial MMU state so we can do the first level of
 130          * kernel initialization.  This maps the first 16 MBytes of memory 1:1
 131          * virtual to physical.
 132          */
 133         nop
 134         addik   r3, r0, 63              /* Invalidate all TLB entries */
 135 _invalidate:
 136         mts     rtlbx, r3
 137         mts     rtlbhi, r0                      /* flush: ensure V is clear   */
 138         bgtid   r3, _invalidate         /* loop for all entries       */
 139         addik   r3, r3, -1
 140         /* sync */
 141
 142         /*
 143          * We should still be executing code at physical address area
 144          * RAM_BASEADDR at this point. However, kernel code is at
 145          * a virtual address. So, set up a TLB mapping to cover this once
 146          * translation is enabled.
 147          */
 148
 149         addik   r3,r0, CONFIG_KERNEL_START /* Load the kernel virtual address */
 150         tophys(r4,r3)                   /* Load the kernel physical address */
 151
 152         mts     rpid,r0                 /* Load the kernel PID */
 153         nop
 154         bri     4
 155
 156         /*
 157          * Configure and load two entries into TLB slots 0 and 1.
 158          * In case we are pinning TLBs, these are reserved in by the
 159          * other TLB functions.  If not reserving, then it doesn't
 160          * matter where they are loaded.
 161          */
 162         andi    r4,r4,0xfffffc00        /* Mask off the real page number */
 163         ori     r4,r4,(TLB_WR | TLB_EX) /* Set the write and execute bits */
 164
 165         andi    r3,r3,0xfffffc00        /* Mask off the effective page number */
 166         ori     r3,r3,(TLB_VALID | TLB_PAGESZ(PAGESZ_16M))
 167
 168         mts     rtlbx,r0                /* TLB slow 0 */
 169
 170         mts     rtlblo,r4               /* Load the data portion of the entry */
 171         mts     rtlbhi,r3               /* Load the tag portion of the entry */
 172
 173         addik   r4, r4, 0x01000000      /* Map next 16 M entries */
 174         addik   r3, r3, 0x01000000
 175
 176         ori     r6,r0,1                 /* TLB slot 1 */
 177         mts     rtlbx,r6
 178
 179         mts     rtlblo,r4               /* Load the data portion of the entry */
 180         mts     rtlbhi,r3               /* Load the tag portion of the entry */
 181
 182         /*
 183          * Load a TLB entry for LMB, since we need access to
 184          * the exception vectors, using a 4k real==virtual mapping.
 185          */
 186         ori     r6,r0,3                 /* TLB slot 3 */
 187         mts     rtlbx,r6
 188
 189         ori     r4,r0,(TLB_WR | TLB_EX)
 190         ori     r3,r0,(TLB_VALID | TLB_PAGESZ(PAGESZ_4K))
 191
 192         mts     rtlblo,r4               /* Load the data portion of the entry */
 193         mts     rtlbhi,r3               /* Load the tag portion of the entry */
 194
 195         /*
 196          * We now have the lower 16 Meg of RAM mapped into TLB entries, and the
 197          * caches ready to work.
 198          */
 199 turn_on_mmu:
 200         ori     r15,r0,start_here
 201         ori     r4,r0,MSR_KERNEL_VMS
 202         mts     rmsr,r4
 203         nop
 204         rted    r15,0                   /* enables MMU */
 205         nop
 206
 207 start_here:
 208 #endif /* CONFIG_MMU */
 209
 210         /* Initialize small data anchors */
 211         la      r13, r0, _KERNEL_SDA_BASE_
 212         la      r2, r0, _KERNEL_SDA2_BASE_
 213
 214         /* Initialize stack pointer */
 215         la      r1, r0, init_thread_union + THREAD_SIZE - 4
 216
 217         /* Initialize r31 with current task address */
 218         la      r31, r0, init_task
 219
 220         /*
 221          * Call platform dependent initialize function.
 222          * Please see $(ARCH)/mach-$(SUBARCH)/setup.c for
 223          * the function.
 224          */
 225         la      r9, r0, machine_early_init
 226         brald   r15, r9
 227         nop
 228
 229 #ifndef CONFIG_MMU
 230         la      r15, r0, machine_halt
 231         braid   start_kernel
 232         nop
 233 #else
 234         /*
 235          * Initialize the MMU.
 236          */
 237         bralid  r15, mmu_init
 238         nop
 239
 240         /* Go back to running unmapped so we can load up new values
 241          * and change to using our exception vectors.
 242          * On the MicroBlaze, all we invalidate the used TLB entries to clear
 243          * the old 16M byte TLB mappings.
 244          */
 245         ori     r15,r0,TOPHYS(kernel_load_context)
 246         ori     r4,r0,MSR_KERNEL
 247         mts     rmsr,r4
 248         nop
 249         bri     4
 250         rted    r15,0
 251         nop
 252
 253         /* Load up the kernel context */
 254 kernel_load_context:
 255         # Keep entry 0 and 1 valid. Entry 3 mapped to LMB can go away.
 256         ori     r5,r0,3
 257         mts     rtlbx,r5
 258         nop
 259         mts     rtlbhi,r0
 260         nop
 261         addi    r15, r0, machine_halt
 262         ori     r17, r0, start_kernel
 263         ori     r4, r0, MSR_KERNEL_VMS
 264         mts     rmsr, r4
 265         nop
 266         rted    r17, 0          /* enable MMU and jump to start_kernel */
 267         nop
 268 #endif /* CONFIG_MMU */