SAFE public projects git trees. - safe/jmp/linux-2.6/blob - arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/thread_info.h>
   8 #include <asm/memory.h>
   9
  10 OUTPUT_ARCH(arm)
  11 ENTRY(stext)
  12
  13 #ifndef __ARMEB__
  14 jiffies = jiffies_64;
  15 #else
  16 jiffies = jiffies_64 + 4;
  17 #endif
  18
  19 SECTIONS
  20 {
  21 #ifdef CONFIG_XIP_KERNEL
  22         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  23 #else
  24         . = PAGE_OFFSET + TEXT_OFFSET;
  25 #endif
  26         .text.head : {
  27                 _stext = .;
  28                 _sinittext = .;
  29                 *(.text.head)
  30         }
  31
  32         .init : {                       /* Init code and data           */
  33                         INIT_TEXT
  34                 _einittext = .;
  35                 __proc_info_begin = .;
  36                         *(.proc.info.init)
  37                 __proc_info_end = .;
  38                 __arch_info_begin = .;
  39                         *(.arch.info.init)
  40                 __arch_info_end = .;
  41                 __tagtable_begin = .;
  42                         *(.taglist.init)
  43                 __tagtable_end = .;
  44                 . = ALIGN(16);
  45                 __setup_start = .;
  46                         *(.init.setup)
  47                 __setup_end = .;
  48                 __early_begin = .;
  49                         *(.early_param.init)
  50                 __early_end = .;
  51                 __initcall_start = .;
  52                         INITCALLS
  53                 __initcall_end = .;
  54                 __con_initcall_start = .;
  55                         *(.con_initcall.init)
  56                 __con_initcall_end = .;
  57                 __security_initcall_start = .;
  58                         *(.security_initcall.init)
  59                 __security_initcall_end = .;
  60 #ifdef CONFIG_BLK_DEV_INITRD
  61                 . = ALIGN(32);
  62                 __initramfs_start = .;
  63                         usr/built-in.o(.init.ramfs)
  64                 __initramfs_end = .;
  65 #endif
  66                 . = ALIGN(4096);
  67                 __per_cpu_start = .;
  68                         *(.data.percpu.page_aligned)
  69                         *(.data.percpu)
  70                         *(.data.percpu.shared_aligned)
  71                 __per_cpu_end = .;
  72 #ifndef CONFIG_XIP_KERNEL
  73                 __init_begin = _stext;
  74                 INIT_DATA
  75                 . = ALIGN(4096);
  76                 __init_end = .;
  77 #endif
  78         }
  79
  80         /DISCARD/ : {                   /* Exit code and data           */
  81                 EXIT_TEXT
  82                 EXIT_DATA
  83                 *(.exitcall.exit)
  84 #ifndef CONFIG_MMU
  85                 *(.fixup)
  86                 *(__ex_table)
  87 #endif
  88         }
  89
  90         .text : {                       /* Real text segment            */
  91                 _text = .;              /* Text and read-only data      */
  92                         __exception_text_start = .;
  93                         *(.exception.text)
  94                         __exception_text_end = .;
  95                         TEXT_TEXT
  96                         SCHED_TEXT
  97                         LOCK_TEXT
  98                         KPROBES_TEXT
  99 #ifdef CONFIG_MMU
 100                         *(.fixup)
 101 #endif
 102                         *(.gnu.warning)
 103                         *(.rodata)
 104                         *(.rodata.*)
 105                         *(.glue_7)
 106                         *(.glue_7t)
 107                 *(.got)                 /* Global offset table          */
 108         }
 109
 110         RODATA
 111
 112         _etext = .;                     /* End of text and rodata section */
 113
 114 #ifdef CONFIG_XIP_KERNEL
 115         __data_loc = ALIGN(4);          /* location in binary */
 116         . = PAGE_OFFSET + TEXT_OFFSET;
 117 #else
 118         . = ALIGN(THREAD_SIZE);
 119         __data_loc = .;
 120 #endif
 121
 122         .data : AT(__data_loc) {
 123                 _data = .;              /* address in memory */
 124
 125                 /*
 126                  * first, the init task union, aligned
 127                  * to an 8192 byte boundary.
 128                  */
 129                 *(.data.init_task)
 130
 131 #ifdef CONFIG_XIP_KERNEL
 132                 . = ALIGN(4096);
 133                 __init_begin = .;
 134                 INIT_DATA
 135                 . = ALIGN(4096);
 136                 __init_end = .;
 137 #endif
 138
 139                 . = ALIGN(4096);
 140                 __nosave_begin = .;
 141                 *(.data.nosave)
 142                 . = ALIGN(4096);
 143                 __nosave_end = .;
 144
 145                 /*
 146                  * then the cacheline aligned data
 147                  */
 148                 . = ALIGN(32);
 149                 *(.data.cacheline_aligned)
 150
 151                 /*
 152                  * The exception fixup table (might need resorting at runtime)
 153                  */
 154                 . = ALIGN(32);
 155                 __start___ex_table = .;
 156 #ifdef CONFIG_MMU
 157                 *(__ex_table)
 158 #endif
 159                 __stop___ex_table = .;
 160
 161                 /*
 162                  * and the usual data section
 163                  */
 164                 DATA_DATA
 165                 CONSTRUCTORS
 166
 167                 _edata = .;
 168         }
 169         _edata_loc = __data_loc + SIZEOF(.data);
 170
 171         .bss : {
 172                 __bss_start = .;        /* BSS                          */
 173                 *(.bss)
 174                 *(COMMON)
 175                 _end = .;
 176         }
 177                                         /* Stabs debugging sections.    */
 178         .stab 0 : { *(.stab) }
 179         .stabstr 0 : { *(.stabstr) }
 180         .stab.excl 0 : { *(.stab.excl) }
 181         .stab.exclstr 0 : { *(.stab.exclstr) }
 182         .stab.index 0 : { *(.stab.index) }
 183         .stab.indexstr 0 : { *(.stab.indexstr) }
 184         .comment 0 : { *(.comment) }
 185 }
 186
 187 /*
 188  * These must never be empty
 189  * If you have to comment these two assert statements out, your
 190  * binutils is too old (for other reasons as well)
 191  */
 192 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 193 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")